Prepare for PYTHON_ABI-versioned Boost Python libraries in Boost 1.48. Patch by Arfrever.

(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

4 files changed, 103 insertions, 8 deletions

diff --git a/dev-python/visual/ChangeLog b/dev-python/visual/ChangeLog
index b42f44776ac6..2dec238dfcda 100644
--- a/dev-python/visual/ChangeLog
+++ b/dev-python/visual/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/visual
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/visual/ChangeLog,v 1.49 2012/01/05 17:37:14 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/visual/ChangeLog,v 1.50 2012/01/28 19:58:09 floppym Exp $
+
+*visual-5.72-r1 (28 Jan 2012)
+
+  28 Jan 2012; Mike Gilbert <floppym@gentoo.org> +visual-5.72-r1.ebuild,
+  visual-5.4.ebuild, visual-5.72.ebuild:
+  Prepare for PYTHON_ABI-versioned Boost Python libraries in Boost 1.48. Patch
+  by Arfrever.
 
 *visual-5.72 (05 Jan 2012)
 
diff --git a/dev-python/visual/visual-5.4.ebuild b/dev-python/visual/visual-5.4.ebuild
index 9f6d967f51c0..ef12c8ae01e8 100644
--- a/dev-python/visual/visual-5.4.ebuild
+++ b/dev-python/visual/visual-5.4.ebuild
@@ -1,11 +1,11 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/visual/visual-5.4.ebuild,v 1.4 2011/01/15 15:41:39 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/visual/visual-5.4.ebuild,v 1.5 2012/01/28 19:58:09 floppym Exp $
 
 EAPI="3"
 PYTHON_DEPEND="2"
 SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="3.* *-jython"
+RESTRICT_PYTHON_ABIS="3.* *-jython *-pypy-*"
 PYTHON_EXPORT_PHASE_FUNCTIONS="1"
 
 inherit flag-o-matic python versionator
@@ -21,7 +21,7 @@ SLOT="0"
 KEYWORDS="amd64 ppc x86"
 LICENSE="visual"
 
-RDEPEND=">=dev-libs/boost-1.41.0[python]
+RDEPEND="<dev-libs/boost-1.48[python]
 	dev-cpp/libglademm
 	>=dev-cpp/gtkglextmm-1.2
 	dev-python/numpy"
diff --git a/dev-python/visual/visual-5.72-r1.ebuild b/dev-python/visual/visual-5.72-r1.ebuild
new file mode 100644
index 000000000000..d763ce276f99
--- /dev/null
+++ b/dev-python/visual/visual-5.72-r1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/visual/visual-5.72-r1.ebuild,v 1.1 2012/01/28 19:58:09 floppym Exp $
+
+EAPI="4"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="*-jython *-pypy-*"
+PYTHON_EXPORT_PHASE_FUNCTIONS="1"
+
+inherit flag-o-matic python versionator
+
+MY_P="${PN}-$(delete_version_separator 2)_release"
+
+DESCRIPTION="Real-time 3D graphics library for Python"
+HOMEPAGE="http://www.vpython.org/"
+SRC_URI="http://www.vpython.org/contents/download/${MY_P}.tar.bz2"
+
+LICENSE="visual"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples"
+
+RDEPEND=">=dev-cpp/gtkglextmm-1.2
+	dev-cpp/libglademm
+	>=dev-libs/boost-1.48[python]
+	dev-python/numpy
+	dev-python/polygon
+	dev-python/ttfquery"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# Delete redundant file, which causes compilation failure.
+	rm -f src/gtk2/random_device.cpp
+	sed -e "s/ random_device.l\?o//" -i src/Makefile.in src/gtk2/makefile || die "sed failed"
+
+	# Verbose build.
+	sed -e 's/2\?>>[[:space:]]*\$(LOGFILE).*//' -i src/Makefile.in || die "sed failed"
+
+	python_clean_py-compile_files
+	python_src_prepare
+
+	preparation() {
+		sed \
+			-e "s/-lboost_python/-lboost_python-${PYTHON_ABI}/" \
+			-e "s/libboost_python/libboost_python-${PYTHON_ABI}/" \
+			-i src/Makefile.in src/gtk2/makefile
+	}
+	python_execute_function -s preparation
+}
+
+src_configure() {
+	BOOST_PKG="$(best_version ">=dev-libs/boost-1.48")"
+	BOOST_VER="$(get_version_component_range 1-2 "${BOOST_PKG/*boost-/}")"
+	BOOST_VER="$(replace_all_version_separators _ "${BOOST_VER}")"
+	BOOST_INC="${EPREFIX}/usr/include/boost-${BOOST_VER}"
+	BOOST_LIB="${EPREFIX}/usr/$(get_libdir)/boost-${BOOST_VER}"
+
+	# Specify the include and lib directory for Boost.
+	append-cxxflags -I${BOOST_INC}
+	append-ldflags -L${BOOST_LIB}
+
+	python_src_configure \
+		--with-example-dir="${EPREFIX}/usr/share/doc/${PF}/examples" \
+		--with-html-dir="${EPREFIX}/usr/share/doc/${PF}/html" \
+		$(use_enable doc docs) \
+		$(use_enable examples)
+}
+
+src_install() {
+	python_src_install
+	python_clean_installation_image
+
+	dodoc authors.txt HACKING.txt NEWS.txt
+
+	# Don't install useless vpython script.
+	rm -fr "${ED}usr/bin"
+}
+
+pkg_postinst() {
+	python_mod_optimize vis visual
+}
+
+pkg_postrm() {
+	python_mod_cleanup vis visual
+}
diff --git a/dev-python/visual/visual-5.72.ebuild b/dev-python/visual/visual-5.72.ebuild
index e6acf8772668..f3a6a27b2f32 100644
--- a/dev-python/visual/visual-5.72.ebuild
+++ b/dev-python/visual/visual-5.72.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/visual/visual-5.72.ebuild,v 1.1 2012/01/05 17:37:14 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/visual/visual-5.72.ebuild,v 1.2 2012/01/28 19:58:09 floppym Exp $
 
 EAPI="3"
-PYTHON_DEPEND="2"
 SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="*-jython *-pypy-*"
 PYTHON_EXPORT_PHASE_FUNCTIONS="1"
 
 inherit flag-o-matic python versionator
@@ -20,7 +20,7 @@ SLOT="0"
 KEYWORDS="~amd64 ~x86"
 LICENSE="visual"
 
-RDEPEND=">=dev-libs/boost-1.41.0[python]
+RDEPEND="<dev-libs/boost-1.48[python]
 	dev-cpp/libglademm
 	>=dev-cpp/gtkglextmm-1.2
 	dev-python/numpy