add ebuild for behave—dependence of fig

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 11A8217C!)

3 files changed, 78 insertions, 0 deletions

diff --git a/dev-python/behave/ChangeLog b/dev-python/behave/ChangeLog
new file mode 100644
index 000000000000..59c68775656d
--- /dev/null
+++ b/dev-python/behave/ChangeLog
@@ -0,0 +1,10 @@
+# ChangeLog for dev-python/behave
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/behave/ChangeLog,v 1.1 2014/10/22 01:12:16 alunduil Exp $
+
+*behave-1.2.4 (22 Oct 2014)
+
+  22 Oct 2014; Alex Brandt <alunduil@gentoo.org> +behave-1.2.4.ebuild,
+  +metadata.xml:
+  add ebuild written by me
+
diff --git a/dev-python/behave/behave-1.2.4.ebuild b/dev-python/behave/behave-1.2.4.ebuild
new file mode 100644
index 000000000000..79614d073d3a
--- /dev/null
+++ b/dev-python/behave/behave-1.2.4.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/behave/behave-1.2.4.ebuild,v 1.1 2014/10/22 01:12:16 alunduil Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+DESCRIPTION="behaviour-driven development, Python style"
+HOMEPAGE="http://github.com/behave/behave"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc test"
+
+DEPEND="
+	doc? (
+		>=dev-python/sphinx-1.2.2[${PYTHON_USEDEP}]
+		>=dev-python/sphinxcontrib-cheeseshop-0.2[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-python/mock-1.0[${PYTHON_USEDEP}]
+		>=dev-python/nose-1.1[${PYTHON_USEDEP}]
+		>=dev-python/pyhamcrest-1.8[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	>=dev-python/parse-1.6.3[${PYTHON_USEDEP}]
+	>=dev-python/parse-type-0.3.4[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests || die "nosetests failed under ${EPYTHON}"
+
+	local DISTUTILS_NO_PARALLEL_BUILD=TRUE
+
+	rm -f "${HOME}"/.pydistutils.cfg || die "Couldn't remove pydistutils.cfg"
+
+	distutils_install_for_testing
+
+	${TEST_DIR}/scripts/behave -f progress --junit --tags=~@xfail features/ || die "behave features failed under ${EPYTHON}"
+	${TEST_DIR}/scripts/behave -f progress --junit --tags=~@xfail tools/test-features/ || die "behave test-festures failed under ${EPYTHON}"
+	${TEST_DIR}/scripts/behave -f progress --junit --tags=~@xfail issue.features/ || die "behave issue.features failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( build/docs/html/. )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/behave/metadata.xml b/dev-python/behave/metadata.xml
new file mode 100644
index 000000000000..02be8c5eb78f
--- /dev/null
+++ b/dev-python/behave/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer>
+		<email>alunduil@gentoo.org</email>
+		<name>Alex Brandt</name>
+	</maintainer>
+	<longdescription lang="en">
+	</longdescription>
+</pkgmetadata>