New patch set.

(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 0x08C170DE55EC123A)

2 files changed, 136 insertions, 1 deletions

diff --git a/media-plugins/mythplugins/ChangeLog b/media-plugins/mythplugins/ChangeLog
index 9d7c5699d6d6..34ee65683575 100644
--- a/media-plugins/mythplugins/ChangeLog
+++ b/media-plugins/mythplugins/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/mythplugins
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/mythplugins/ChangeLog,v 1.20 2013/08/03 11:42:37 rich0 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/mythplugins/ChangeLog,v 1.21 2013/09/23 11:51:02 rich0 Exp $
+
+*mythplugins-0.26.0_p20130922 (23 Sep 2013)
+
+  23 Sep 2013; Richard Freeman <rich0@gentoo.org>
+  +mythplugins-0.26.0_p20130922.ebuild:
+  New patch set.
 
   03 Aug 2013; Richard Freeman <rich0@gentoo.org>
   -mythplugins-0.26.0_p20130121.ebuild, -mythplugins-0.26.0_p20130207.ebuild:
diff --git a/media-plugins/mythplugins/mythplugins-0.26.0_p20130922.ebuild b/media-plugins/mythplugins/mythplugins-0.26.0_p20130922.ebuild
new file mode 100644
index 000000000000..1c4eebddb74f
--- /dev/null
+++ b/media-plugins/mythplugins/mythplugins-0.26.0_p20130922.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/mythplugins/mythplugins-0.26.0_p20130922.ebuild,v 1.1 2013/09/23 11:51:02 rich0 Exp $
+
+EAPI=5
+
+PYTHON_DEPEND="2:2.6"
+BACKPORTS="9fd7c6102b2cd1a3760337663803b110446c6ea7"
+MY_P=${P%_p*}
+
+inherit eutils python
+
+DESCRIPTION="Official MythTV plugins"
+HOMEPAGE="http://www.mythtv.org"
+SRC_URI="ftp://ftp.osuosl.org/pub/mythtv/${MY_P}.tar.bz2
+	${BACKPORTS:+http://dev.gentoo.org/~rich0/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+MYTHPLUGINS="mytharchive mythbrowser mythgallery mythgame \
+mythmusic mythnetvision mythnews mythweather mythzoneminder"
+
+IUSE="${MYTHPLUGINS} cdda cdr exif fftw raw"
+
+DEPEND="!media-plugins/mytharchive
+	!media-plugins/mythbrowser
+	!media-plugins/mythgallery
+	!media-plugins/mythgame
+	!media-plugins/mythmovies
+	!media-plugins/mythmusic
+	!media-plugins/mythnetvision
+	!media-plugins/mythnews
+	!media-plugins/mythweather
+	=media-tv/mythtv-${PV}*:=[python]
+	mytharchive? (
+		app-cdr/dvd+rw-tools
+		virtual/python-imaging:=
+		media-video/dvdauthor
+		media-video/mjpegtools[png]
+		media-video/transcode
+		virtual/cdrtools
+	)
+	mythgallery? (
+		media-libs/tiff:=
+		virtual/opengl
+		exif? ( >media-libs/libexif-0.6.9:= )
+		raw? ( media-gfx/dcraw )
+	)
+	mythmusic? (
+		>=media-libs/flac-1.1.2:=
+		>=media-libs/libvorbis-1.0:=
+		>=media-libs/taglib-1.6:=
+		media-sound/lame
+		virtual/opengl
+		cdda? (
+			dev-libs/libcdio:=
+			cdr? ( virtual/cdrtools )
+		)
+		fftw? ( sci-libs/fftw:= )
+	)
+	mythnetvision? (
+		=dev-lang/python-2*:=[xml]
+		dev-python/lxml:=
+		dev-python/mysql-python:=
+		dev-python/oauth:=
+		dev-python/pycurl:=
+	)
+	mythweather? (
+		dev-perl/DateManip
+		dev-perl/DateTime-Format-ISO8601
+		dev-perl/ImageSize
+		dev-perl/JSON
+		dev-perl/SOAP-Lite
+		dev-perl/XML-Simple
+		dev-perl/XML-Parser
+		dev-perl/XML-SAX
+		dev-perl/XML-XPath
+	)"
+RDEPEND="${DEPEND}"
+
+REQUIRED_USE="
+	cdda? ( mythmusic )
+	cdr? ( mythmusic cdda )
+	exif? ( mythgallery )
+	fftw? ( mythmusic )
+	mythnews? ( mythbrowser )
+	raw? ( mythgallery )"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	[[ -n ${BACKPORTS} ]] && \
+		EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
+			epatch
+
+	epatch_user
+}
+
+src_configure() {
+	./configure \
+		--prefix=/usr \
+		--python=python2 \
+		--enable-opengl \
+		$(use_enable mythzoneminder) \
+		$(use_enable mytharchive) \
+		$(use_enable mythbrowser) \
+		$(use_enable mythgallery) \
+		$(use_enable mythgame) \
+		$(use_enable mythmusic) \
+		$(use_enable mythnetvision) \
+		$(use_enable mythnews) \
+		$(use_enable mythweather) \
+		$(use_enable cdda cdio) \
+		$(use_enable exif) \
+		$(use_enable exif new-exif) \
+		$(use_enable raw dcraw) \
+		|| die "configure failed"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install || die "make install failed"
+}