Version bump, update live ebuild

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 84F20B43)

4 files changed, 84 insertions, 12 deletions

diff --git a/media-sound/xnoise/ChangeLog b/media-sound/xnoise/ChangeLog
index 5eab2596ae48..f9fcf8de281a 100644
--- a/media-sound/xnoise/ChangeLog
+++ b/media-sound/xnoise/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/xnoise
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/xnoise/ChangeLog,v 1.26 2012/12/23 21:22:49 angelos Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/xnoise/ChangeLog,v 1.27 2013/01/20 10:00:24 angelos Exp $
+
+*xnoise-0.2.14 (20 Jan 2013)
+
+  20 Jan 2013;  <christoph@gentoo.org> +xnoise-0.2.14.ebuild, metadata.xml,
+  xnoise-9999.ebuild:
+  Version bump, update live ebuild
 
 *xnoise-0.2.13 (23 Dec 2012)
 
diff --git a/media-sound/xnoise/metadata.xml b/media-sound/xnoise/metadata.xml
index 737a09ceae1c..b3e227faae4b 100644
--- a/media-sound/xnoise/metadata.xml
+++ b/media-sound/xnoise/metadata.xml
@@ -11,6 +11,6 @@
 		<flag name="lyrics">Enable support for lyrics fetching</flag>
 	</use>
 	<upstream>
-		<remote-id type="google-code">xnoise</remote-id>
+		<remote-id type="bitbucket">shuerhaaken/xnoise</remote-id>
 	</upstream>
 </pkgmetadata>
diff --git a/media-sound/xnoise/xnoise-0.2.14.ebuild b/media-sound/xnoise/xnoise-0.2.14.ebuild
new file mode 100644
index 000000000000..fc7f40fa83b7
--- /dev/null
+++ b/media-sound/xnoise/xnoise-0.2.14.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/xnoise/xnoise-0.2.14.ebuild,v 1.1 2013/01/20 10:00:24 angelos Exp $
+
+EAPI=4
+inherit fdo-mime gnome2-utils
+
+DESCRIPTION="A media player for Gtk+ with a slick GUI, great speed and lots of
+features"
+HOMEPAGE="http://www.xnoise-media-player.com/"
+SRC_URI="mirror://bitbucket/shuerhaaken/${PN}/downloads/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+lastfm +lyrics"
+
+RDEPEND="x11-libs/gtk+:3
+	>=dev-libs/glib-2.30:2
+	media-libs/gstreamer:0.10
+	media-libs/gst-plugins-base:0.10
+	dev-db/sqlite:3
+	media-libs/taglib
+	x11-libs/cairo
+	x11-libs/libX11
+	lastfm? ( net-libs/libsoup:2.4 )
+	lyrics? ( net-libs/libsoup:2.4
+		dev-libs/libxml2:2 )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+DOCS=( AUTHORS README )
+
+src_configure() {
+	econf \
+		$(use_enable lyrics lyricwiki) \
+		$(use_enable lastfm) \
+		--enable-mpris \
+		--enable-soundmenu2 \
+		--enable-mediakeys \
+		$(use_enable lyrics chartlyrics) \
+		$(use_enable lyrics azlyrics) \
+		--disable-ubuntuone \
+		--enable-magnatune
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name "*.la" -delete || die
+	rm -rf "${ED}"/usr/share/${PN}/license || die
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
diff --git a/media-sound/xnoise/xnoise-9999.ebuild b/media-sound/xnoise/xnoise-9999.ebuild
index 235320dced07..7f022cafd87b 100644
--- a/media-sound/xnoise/xnoise-9999.ebuild
+++ b/media-sound/xnoise/xnoise-9999.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/xnoise/xnoise-9999.ebuild,v 1.11 2012/08/16 19:08:27 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/xnoise/xnoise-9999.ebuild,v 1.12 2013/01/20 10:00:24 angelos Exp $
 
 EAPI=4
 inherit fdo-mime gnome2-utils git-2
@@ -8,12 +8,12 @@ inherit fdo-mime gnome2-utils git-2
 DESCRIPTION="A media player for Gtk+ with a slick GUI, great speed and lots of
 features"
 HOMEPAGE="http://www.xnoise-media-player.com/"
-EGIT_REPO_URI="git://github.com/shuerhaaken/${PN}.git"
+EGIT_REPO_URI="https://bitbucket.org/shuerhaaken/${PN}.git"
 
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS=""
-IUSE="+lastfm libnotify +lyrics"
+IUSE="+lastfm +lyrics"
 
 RDEPEND="x11-libs/gtk+:3
 	>=dev-libs/glib-2.30:2
@@ -24,11 +24,10 @@ RDEPEND="x11-libs/gtk+:3
 	x11-libs/cairo
 	x11-libs/libX11
 	lastfm? ( net-libs/libsoup:2.4 )
-	libnotify? ( x11-libs/libnotify )
 	lyrics? ( net-libs/libsoup:2.4
 		dev-libs/libxml2:2 )"
 DEPEND="${RDEPEND}
-	dev-lang/vala:0.16
+	dev-lang/vala:0.18
 	dev-util/intltool
 	virtual/pkgconfig
 	gnome-base/gnome-common:3
@@ -42,17 +41,17 @@ src_prepare() {
 }
 
 src_configure() {
-	VALAC=$(type -p valac-0.16) \
+	VALAC=$(type -p valac-0.18) \
 	econf \
 		$(use_enable lyrics lyricwiki) \
 		$(use_enable lastfm) \
-		$(use_enable libnotify notifications) \
 		--enable-mpris \
 		--enable-soundmenu2 \
 		--enable-mediakeys \
 		$(use_enable lyrics chartlyrics) \
 		$(use_enable lyrics azlyrics) \
-		--disable-ubuntuone
+		--disable-ubuntuone \
+		--enable-magnatune
 }
 
 src_install() {