Version bump. Update to EAPI 4, add debug use flag, add warmstarts use flag (bug #440286 by Sean McGovern), add support for epatch_user.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

4 files changed, 82 insertions, 21 deletions

diff --git a/net-nds/rpcbind/ChangeLog b/net-nds/rpcbind/ChangeLog
index 0627b28c9cc5..2dd58f1fb92a 100644
--- a/net-nds/rpcbind/ChangeLog
+++ b/net-nds/rpcbind/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-nds/rpcbind
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nds/rpcbind/ChangeLog,v 1.34 2014/01/18 04:53:00 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nds/rpcbind/ChangeLog,v 1.35 2014/01/30 05:10:36 radhermit Exp $
+
+*rpcbind-0.2.1 (30 Jan 2014)
+
+  30 Jan 2014; Tim Harder <radhermit@gentoo.org> +rpcbind-0.2.1.ebuild,
+  rpcbind-9999.ebuild, metadata.xml:
+  Version bump. Update to EAPI 4, add debug use flag, add warmstarts use flag
+  (bug #440286 by Sean McGovern), add support for epatch_user.
 
   18 Jan 2014; Mike Frysinger <vapier@gentoo.org> rpcbind-0.2.0-r1.ebuild,
   rpcbind-9999.ebuild:
diff --git a/net-nds/rpcbind/metadata.xml b/net-nds/rpcbind/metadata.xml
index ca66751dee2f..3966ec84ddc5 100644
--- a/net-nds/rpcbind/metadata.xml
+++ b/net-nds/rpcbind/metadata.xml
@@ -2,4 +2,7 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>net-fs</herd>
+<use>
+	<flag name="warmstarts">Enables rpcbind to cache configuration for warm restarts</flag>
+</use>
 </pkgmetadata>
diff --git a/net-nds/rpcbind/rpcbind-0.2.1.ebuild b/net-nds/rpcbind/rpcbind-0.2.1.ebuild
new file mode 100644
index 000000000000..193dfd0bc972
--- /dev/null
+++ b/net-nds/rpcbind/rpcbind-0.2.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-nds/rpcbind/rpcbind-0.2.1.ebuild,v 1.1 2014/01/30 05:10:36 radhermit Exp $
+
+EAPI="4"
+
+inherit eutils systemd
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://git.infradead.org/~steved/rpcbind.git"
+	inherit autotools git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="portmap replacement which supports RPC over various protocols"
+HOMEPAGE="http://sourceforge.net/projects/rpcbind/"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="debug selinux tcpd warmstarts"
+
+RDEPEND=">=net-libs/libtirpc-0.2.3
+	selinux? ( sec-policy/selinux-rpcbind )
+	tcpd? ( sys-apps/tcp-wrappers )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	[[ ${PV} == "9999" ]] && eautoreconf
+	epatch_user
+}
+
+src_configure() {
+	econf \
+		--bindir="${EPREFIX}"/sbin \
+		--with-statedir="${EPREFIX}"/run/${PN} \
+		$(use_enable tcpd libwrap) \
+		$(use_enable debug) \
+		$(use_enable warmstarts)
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+
+	systemd_dounit "${FILESDIR}"/${PN}.service
+}
diff --git a/net-nds/rpcbind/rpcbind-9999.ebuild b/net-nds/rpcbind/rpcbind-9999.ebuild
index d069413ad51e..0799ad1ea4fd 100644
--- a/net-nds/rpcbind/rpcbind-9999.ebuild
+++ b/net-nds/rpcbind/rpcbind-9999.ebuild
@@ -1,14 +1,14 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-nds/rpcbind/rpcbind-9999.ebuild,v 1.9 2014/01/18 04:53:00 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nds/rpcbind/rpcbind-9999.ebuild,v 1.10 2014/01/30 05:10:36 radhermit Exp $
 
-EAPI="2"
+EAPI="4"
+
+inherit eutils systemd
 
 if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="git://git.infradead.org/~steved/rpcbind.git"
-	inherit autotools git-2
-	SRC_URI=""
-	#KEYWORDS=""
+	inherit autotools git-r3
 else
 	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
 	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
@@ -19,33 +19,33 @@ HOMEPAGE="http://sourceforge.net/projects/rpcbind/"
 
 LICENSE="BSD"
 SLOT="0"
-IUSE="selinux tcpd"
+IUSE="debug selinux tcpd warmstarts"
 
-RDEPEND="net-libs/libtirpc
+RDEPEND=">=net-libs/libtirpc-0.2.3
 	selinux? ( sec-policy/selinux-rpcbind )
 	tcpd? ( sys-apps/tcp-wrappers )"
 DEPEND="${RDEPEND}
 	virtual/pkgconfig"
 
 src_prepare() {
-	if [[ ${PV} == "9999" ]] ; then
-		eautoreconf
-	else
-		# fix busted timestamps
-		find . -type f -print0 | xargs -0 touch -r .
-	fi
+	[[ ${PV} == "9999" ]] && eautoreconf
+	epatch_user
 }
 
 src_configure() {
 	econf \
-		--bindir=/sbin \
-		$(use_enable tcpd libwrap)
+		--bindir="${EPREFIX}"/sbin \
+		--with-statedir="${EPREFIX}"/run/${PN} \
+		$(use_enable tcpd libwrap) \
+		$(use_enable debug) \
+		$(use_enable warmstarts)
 }
 
 src_install() {
-	emake DESTDIR="${D}" install || die
-	doman man/rpc{bind,info}.8
-	dodoc AUTHORS ChangeLog NEWS README
-	newinitd "${FILESDIR}"/rpcbind.initd rpcbind || die
-	newconfd "${FILESDIR}"/rpcbind.confd rpcbind || die
+	default
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+
+	systemd_dounit "${FILESDIR}"/${PN}.service
 }