Fixed bug #267571. Fixed documentation bug. Thanks a lot to Rafael Martins.

(Portage version: 2.1.6.13/cvs/Linux i686)

2 files changed, 83 insertions, 1 deletions

diff --git a/sci-electronics/kicad/ChangeLog b/sci-electronics/kicad/ChangeLog
index 5765aaf1b58d..5a242c63046a 100644
--- a/sci-electronics/kicad/ChangeLog
+++ b/sci-electronics/kicad/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-electronics/kicad
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-electronics/kicad/ChangeLog,v 1.38 2009/04/21 21:53:16 calchan Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/kicad/ChangeLog,v 1.39 2009/05/07 15:54:31 calchan Exp $
+
+*kicad-20090320.1666-r1 (07 May 2009)
+
+  07 May 2009; Denis Dupeyron <calchan@gentoo.org>
+  +kicad-20090320.1666-r1.ebuild:
+  Fixed bug #267571. Fixed documentation bug. Thanks a lot to Rafael Martins.
 
   21 Apr 2009; Denis Dupeyron <calchan@gentoo.org> kicad-20090320.1666:
   Fixed bug #266978.
diff --git a/sci-electronics/kicad/kicad-20090320.1666-r1.ebuild b/sci-electronics/kicad/kicad-20090320.1666-r1.ebuild
new file mode 100644
index 000000000000..e64982238bbf
--- /dev/null
+++ b/sci-electronics/kicad/kicad-20090320.1666-r1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/kicad/kicad-20090320.1666-r1.ebuild,v 1.1 2009/05/07 15:54:31 calchan Exp $
+
+EAPI="2"
+WX_GTK_VER="2.8"
+
+inherit versionator wxwidgets cmake-utils
+
+MY_PV="$(get_major_version)-r$(get_after_major_version)"
+
+DESCRIPTION="Electronic Schematic and PCB design tools."
+HOMEPAGE="http://kicad.sourceforge.net"
+SRC_URI="http://dev.gentoo.org/~calchan/distfiles/${PN}-sources-${MY_PV}.tar.lzma
+	!minimal? ( http://dev.gentoo.org/~calchan/distfiles/${PN}-library-${MY_PV}.tar.lzma )
+	doc? ( http://dev.gentoo.org/~calchan/distfiles/${PN}-doc-${MY_PV}.tar.lzma )
+	examples? ( http://dev.gentoo.org/~calchan/distfiles/${PN}-examples-${MY_PV}.tar.lzma )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="doc debug examples minimal python"
+
+CDEPEND=">=dev-util/cmake-2.6.0
+	dev-libs/boost
+	x11-libs/wxGTK:2.8[X,opengl]
+	sys-libs/zlib"
+DEPEND="${CDEPEND}
+	app-arch/lzma-utils"
+RDEPEND="${CDEPEND}
+	python? ( dev-lang/python )"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	if use doc ; then
+		# Fix where kicad looks for help files
+		sed -i -e "s/subdirs.Add( wxT( \"kicad\" ) );/subdirs.Add( wxT( \"${PF}\" ) );/" \
+			-e '/subdirs.Add( _T( "help" ) );/d' common/edaappl.cpp \
+			 || die "sed failed"
+	else
+		sed -i -e '/add_subdirectory(kicad-doc)/d' CMakeLists.txt || die "sed failed"
+	fi
+	if ! use examples ; then
+		sed -i -e '/add_subdirectory(demos)/d' CMakeLists.txt || die "sed failed"
+	fi
+	if use minimal ; then
+		sed -i -e '/add_subdirectory(kicad-library)/d' CMakeLists.txt || die "sed failed"
+	fi
+}
+
+src_configure() {
+	need-wxwidgets unicode
+
+	mycmakeargs="${mycmakeargs}
+		-DKICAD_CYRILLIC=ON
+		-DwxUSE_UNICODE=ON
+		$(cmake-utils_use python KICAD_PYTHON)
+		-DKICAD_DOCS=/usr/share/doc/${P}
+		-DKICAD_HELP=/usr/share/doc/${P}"
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	if use minimal ; then
+		ewarn "If the schematic and/or board editors complain about missing libraries when you"
+		ewarn "open old projects, you will have to take one or more of the following actions :"
+		ewarn "- Install the missing libraries manually."
+		ewarn "- Remove the libraries from the 'Libs and Dir' preferences."
+		ewarn "- Fix the libraries' locations in the 'Libs and Dir' preferences."
+		ewarn "- Emerge kicad without the 'minimal' USE flag."
+		elog
+	fi
+	elog "You may want to emerge media-gfx/wings if you want to create 3D models of components."
+}