1 files changed, 0 insertions, 91 deletions
diff --git a/kde-base/kdebindings-ruby/kdebindings-ruby-4.5.2.ebuild b/kde-base/kdebindings-ruby/kdebindings-ruby-4.5.2.ebuild
deleted file mode 100644
index eb051287e37b..000000000000
--- a/kde-base/kdebindings-ruby/kdebindings-ruby-4.5.2.ebuild
+++ /dev/null
@@ -1,91 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebindings-ruby/kdebindings-ruby-4.5.2.ebuild,v 1.2 2010/10/21 22:25:26 dilfridge Exp $
-
-EAPI="2"
-
-KMNAME="kdebindings"
-KMMODULE="ruby"
-WEBKIT_REQUIRED="optional"
-
-USE_RUBY="ruby18"
-# No ruby19 for three reasons:
-# 1) it does not build (yet) - will likely be solved soon
-# 2) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
-# 3) the ebuild can only be installed for one ruby variant, otherwise the compiled
-#    files with identical path+name will overwrite each other - difficult :(
-
-inherit kde4-meta ruby-ng
-
-DESCRIPTION="KDE Ruby bindings"
-KEYWORDS="~amd64 ~ppc ~x86"
-IUSE="akonadi debug okular phonon plasma qscintilla qwt semantic-desktop"
-
-DEPEND="
-	$(add_kdebase_dep smoke 'akonadi?,okular?,phonon?,qscintilla?,qwt?,semantic-desktop?,webkit?')
-"
-
-ruby_add_bdepend virtual/rubygems
-
-RDEPEND="${DEPEND}
-	!dev-ruby/qt4-qtruby
-"
-
-# Merged with kdebindings-ruby after 4.4.80
-add_blocker krossruby
-
-pkg_setup() {
-	ruby-ng_pkg_setup
-	kde4-meta_pkg_setup
-}
-
-src_unpack() {
-	kde4-meta_src_unpack
-
-	cd "${WORKDIR}"
-	mkdir all
-	mv ${P} all/ || die "Could not move sources"
-}
-
-all_ruby_prepare() {
-	kde4-meta_src_prepare
-
-	sed -i -e "s#smoke/smoke.h#smoke.h#" \
-		ruby/qtruby/src/handlers.cpp \
-		ruby/qtruby/src/marshall.h \
-		ruby/qtruby/src/marshall_types.h \
-		ruby/qtruby/src/Qt.cpp \
-		ruby/qtruby/src/qtruby.cpp \
-		ruby/qtruby/src/qtruby.h \
-		ruby/qtruby/src/smokeruby.h || die
-}
-
-each_ruby_configure() {
-	CMAKE_USE_DIR=${S}
-	mycmakeargs=(
-		-DRUBY_LIBRARY=$(ruby_get_libruby)
-		-DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
-		-DRUBY_EXECUTABLE=${RUBY}
-		$(cmake-utils_use_with akonadi)
-		$(cmake-utils_use_with akonadi KdepimLibs)
-		$(cmake-utils_use_with okular)
-		$(cmake-utils_use_with phonon)
-		$(cmake-utils_use_with plasma)
-		$(cmake-utils_use_with qscintilla QScintilla)
-		$(cmake-utils_use_with qwt Qwt)
-		$(cmake-utils_use_with semantic-desktop Nepomuk)
-		$(cmake-utils_use_with semantic-desktop Soprano)
-		$(cmake-utils_use_disable webkit QtWebKit)
-	)
-	kde4-meta_src_configure
-}
-
-each_ruby_compile() {
-	CMAKE_USE_DIR=${S}
-	kde4-meta_src_compile
-}
-
-each_ruby_install() {
-	CMAKE_USE_DIR=${S}
-	kde4-meta_src_install
-}