2 files changed, 110 insertions, 1 deletions
diff --git a/sci-astronomy/stellarium/ChangeLog b/sci-astronomy/stellarium/ChangeLog
index 1110cc3c4e38..228867697636 100644
--- a/sci-astronomy/stellarium/ChangeLog
+++ b/sci-astronomy/stellarium/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-astronomy/stellarium
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/stellarium/ChangeLog,v 1.123 2014/01/22 04:58:45 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/stellarium/ChangeLog,v 1.124 2014/10/25 07:42:32 mr_bones_ Exp $
+
+*stellarium-0.13.1 (25 Oct 2014)
+
+  25 Oct 2014; Michael Sterrett <mr_bones_@gentoo.org>
+  +stellarium-0.13.1.ebuild:
+  version bump
 
   22 Jan 2014; Michael Sterrett <mr_bones_@gentoo.org>
   -stellarium-0.12.0.ebuild:
diff --git a/sci-astronomy/stellarium/stellarium-0.13.1.ebuild b/sci-astronomy/stellarium/stellarium-0.13.1.ebuild
new file mode 100644
index 000000000000..c57f5a90ce80
--- /dev/null
+++ b/sci-astronomy/stellarium/stellarium-0.13.1.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-astronomy/stellarium/stellarium-0.13.1.ebuild,v 1.1 2014/10/25 07:42:32 mr_bones_ Exp $
+
+EAPI=5
+inherit cmake-utils eutils flag-o-matic gnome2-utils
+
+DESCRIPTION="3D photo-realistic skies in real time"
+HOMEPAGE="http://www.stellarium.org/"
+SRC_URI="
+	mirror://sourceforge/stellarium/${P}.tar.gz
+	stars? (
+		mirror://sourceforge/stellarium/stars_4_1v0_0.cat
+		mirror://sourceforge/stellarium/stars_5_2v0_0.cat
+		mirror://sourceforge/stellarium/stars_6_2v0_0.cat
+		mirror://sourceforge/stellarium/stars_7_2v0_0.cat
+		mirror://sourceforge/stellarium/stars_8_2v0_0.cat
+	)"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+KEYWORDS="" # until qt5 is unmasked
+IUSE="debug nls sound stars"
+
+RESTRICT="test"
+
+RDEPEND="
+	media-fonts/dejavu
+	dev-qt/qtcore:5
+	dev-qt/qtquick1:5
+	dev-qt/qtgui:5
+	dev-qt/qtopengl:5
+	dev-qt/qtscript:5
+	virtual/opengl
+	sound? ( dev-qt/qtmultimedia:5[widgets] )"
+DEPEND="${RDEPEND}
+	dev-qt/qtconcurrent:5
+	nls? ( dev-qt/linguist-tools:5 )"
+DOCS=( AUTHORS ChangeLog README )
+
+LANGS=(
+	af ak am ar as ast az be bg bn bo br bs ca cs
+	cy da de el en en_CA en_GB en_US eo es et eu fa fi fil fr
+	ga gd gl gu he hi hr hu hy ia id is it ja ka kk kn ko ky
+	la lb lo lt lv mk ml mn mr ms mt nan nb nl nn oc pa pl pt pt_BR ro
+	ru se si sk sl sq sr sv sw ta te tg th tl tr tt uk uz vi zh
+	zh_CN zh_HK zh_TW zu
+	)
+
+for X in "${LANGS[@]}" ; do
+	IUSE="${IUSE} linguas_${X}"
+done
+
+src_prepare() {
+	if [[ -n ${LINGUAS} ]] ; then
+		sed -i \
+			-e '/aa ab ae/d' \
+			-e "/GETTEXT_CREATE_TRANSLATIONS/a \ ${LINGUAS}" \
+			po/stellarium{,-skycultures}/CMakeLists.txt || die #403647
+	fi
+	sed -i \
+		-e '/^Actions/s/Safemode;//' \
+		-e '/^OnlyShowIn/d' \
+		data/stellarium.desktop || die
+	sed -i -e '/SimpleDrawLine/s: 0 : 1 :g' CMakeLists.txt || die
+	use debug || append-cppflags -DQT_NO_DEBUG #415769
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_enable nls NLS)
+		$(cmake-utils_use_enable sound SOUND)
+	)
+	CMAKE_IN_SOURCE_BUILD=1 cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# use the more up-to-date system fonts
+	rm "${ED}"/usr/share/stellarium/data/DejaVuSans{Mono,}.ttf || die
+	dosym ../../fonts/dejavu/DejaVuSans.ttf /usr/share/stellarium/data/DejaVuSans.ttf
+	dosym ../../fonts/dejavu/DejaVuSansMono.ttf /usr/share/stellarium/data/DejaVuSansMono.ttf
+
+	if use stars ; then
+		insinto /usr/share/${PN}/stars/default
+		doins "${DISTDIR}"/stars_[45678]_[12]v0_0*.cat
+	fi
+	newicon doc/images/stellarium-logo.png ${PN}.png
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}