1 files changed, 40 insertions, 0 deletions
diff --git a/sys-apps/the_silver_searcher/the_silver_searcher-0.27.0.ebuild b/sys-apps/the_silver_searcher/the_silver_searcher-0.27.0.ebuild
new file mode 100644
index 000000000000..9a4d44552352
--- /dev/null
+++ b/sys-apps/the_silver_searcher/the_silver_searcher-0.27.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/the_silver_searcher/the_silver_searcher-0.27.0.ebuild,v 1.1 2014/11/21 15:22:28 radhermit Exp $
+
+EAPI=5
+inherit autotools bash-completion-r1
+
+DESCRIPTION="A code-searching tool similar to ack, but faster"
+HOMEPAGE="http://github.com/ggreer/the_silver_searcher"
+SRC_URI="https://github.com/ggreer/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="lzma zlib"
+
+RDEPEND="dev-libs/libpcre
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS="README.md"
+
+src_prepare() {
+	sed -i '/^dist_bashcomp/d' Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable lzma) \
+		$(use_enable zlib)
+}
+
+src_install() {
+	default
+	newbashcomp ag.bashcomp.sh ag
+}