From ffbcb31f92556eda4d99affa2afefdb814d0ee10 Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Sat, 4 Dec 2010 18:08:10 +0000
Subject: Revision bump to fix intltoolize broken file and allowing people to
 not build gdict-applet if they don't want bonobo on their systems. Remove
 old.

(Portage version: 2.1.9.25/cvs/Linux x86_64)
---
 gnome-extra/gnome-utils/ChangeLog                  |  9 ++-
 .../gnome-utils/gnome-utils-2.32.0-r1.ebuild       | 76 ++++++++++++++++++++++
 gnome-extra/gnome-utils/gnome-utils-2.32.0.ebuild  | 71 --------------------
 gnome-extra/gnome-utils/metadata.xml               |  4 ++
 4 files changed, 88 insertions(+), 72 deletions(-)
 create mode 100644 gnome-extra/gnome-utils/gnome-utils-2.32.0-r1.ebuild
 delete mode 100644 gnome-extra/gnome-utils/gnome-utils-2.32.0.ebuild

(limited to 'gnome-extra/gnome-utils')

diff --git a/gnome-extra/gnome-utils/ChangeLog b/gnome-extra/gnome-utils/ChangeLog
index 26cce812dd3b..c40b0250d550 100644
--- a/gnome-extra/gnome-utils/ChangeLog
+++ b/gnome-extra/gnome-utils/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/gnome-utils
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-utils/ChangeLog,v 1.208 2010/10/22 20:59:30 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-utils/ChangeLog,v 1.209 2010/12/04 18:08:10 pacho Exp $
+
+*gnome-utils-2.32.0-r1 (04 Dec 2010)
+
+  04 Dec 2010; Pacho Ramos <pacho@gentoo.org> -gnome-utils-2.32.0.ebuild,
+  +gnome-utils-2.32.0-r1.ebuild, metadata.xml:
+  Revision bump to fix intltoolize broken file and allowing people to not build
+  gdict-applet if they don't want bonobo on their systems. Remove old.
 
 *gnome-utils-2.32.0 (22 Oct 2010)
 
diff --git a/gnome-extra/gnome-utils/gnome-utils-2.32.0-r1.ebuild b/gnome-extra/gnome-utils/gnome-utils-2.32.0-r1.ebuild
new file mode 100644
index 000000000000..e1213b73fb02
--- /dev/null
+++ b/gnome-extra/gnome-utils/gnome-utils-2.32.0-r1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-utils/gnome-utils-2.32.0-r1.ebuild,v 1.1 2010/12/04 18:08:10 pacho Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+
+inherit gnome2
+
+DESCRIPTION="Utilities for the Gnome2 desktop"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
+IUSE="bonobo doc ipv6 test"
+
+RDEPEND=">=dev-libs/glib-2.20:2
+	>=x11-libs/gtk+-2.20:2
+	>=gnome-base/gnome-panel-2.13.4
+	>=gnome-base/libgtop-2.12
+	>=gnome-base/gconf-2
+	>=media-libs/libcanberra-0.4[gtk]
+	x11-libs/libXext
+	x11-libs/libX11
+	bonobo? ( || ( gnome-base/gnome-panel[bonobo] <gnome-base/gnome-panel-2.32 ) )"
+
+DEPEND="${RDEPEND}
+	x11-proto/xextproto
+	app-text/gnome-doc-utils
+	app-text/scrollkeeper
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.9
+	doc? ( >=dev-util/gtk-doc-1.10 )"
+
+pkg_setup() {
+	if ! use debug; then
+		G2CONF="${G2CONF} --enable-debug=minimum"
+	fi
+
+	G2CONF="${G2CONF}
+		$(use_enable ipv6)
+		$(use_enable bonobo gdict-applet)
+		--disable-maintainer-flags
+		--enable-zlib
+		--disable-static
+		--disable-schemas-install
+		--disable-scrollkeeper"
+	DOCS="AUTHORS ChangeLog NEWS README THANKS"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Remove idiotic -D.*DISABLE_DEPRECATED cflags
+	# This method is kinda prone to breakage. Recheck carefully with next bump.
+	# bug 339074
+	find . -iname 'Makefile.am' -exec \
+		sed -e '/-D[A-Z_]*DISABLE_DEPRECATED/d' -i {} + || die "sed 1 failed"
+	# Do Makefile.in after Makefile.am to avoid automake maintainer-mode
+	find . -iname 'Makefile.in' -exec \
+		sed -e '/-D[A-Z_]*DISABLE_DEPRECATED/d' -i {} + || die "sed 1 failed"
+
+	if ! use test ; then
+		sed -e 's/ tests//' -i logview/Makefile.{am,in} || die "sed 2 failed"
+	fi
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
+		|| die "sed failed"
+}
+
+src_install() {
+	gnome2_src_install
+	find "${ED}" -name "*.la" -delete || die "remove of la files failed"
+}
diff --git a/gnome-extra/gnome-utils/gnome-utils-2.32.0.ebuild b/gnome-extra/gnome-utils/gnome-utils-2.32.0.ebuild
deleted file mode 100644
index b92511ba430d..000000000000
--- a/gnome-extra/gnome-utils/gnome-utils-2.32.0.ebuild
+++ /dev/null
@@ -1,71 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-utils/gnome-utils-2.32.0.ebuild,v 1.1 2010/10/22 20:59:30 eva Exp $
-
-EAPI="3"
-GCONF_DEBUG="yes"
-
-inherit gnome2
-
-DESCRIPTION="Utilities for the Gnome2 desktop"
-HOMEPAGE="http://www.gnome.org/"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
-IUSE="doc ipv6 test"
-
-RDEPEND=">=dev-libs/glib-2.20:2
-	>=x11-libs/gtk+-2.20:2
-	>=gnome-base/gnome-panel-2.13.4
-	>=gnome-base/libgtop-2.12
-	>=gnome-base/gconf-2
-	>=media-libs/libcanberra-0.4[gtk]
-	x11-libs/libXext
-	x11-libs/libX11"
-
-DEPEND="${RDEPEND}
-	x11-proto/xextproto
-	app-text/gnome-doc-utils
-	app-text/scrollkeeper
-	>=dev-util/intltool-0.40
-	>=dev-util/pkgconfig-0.9
-	doc? ( >=dev-util/gtk-doc-1.10 )"
-
-DOCS="AUTHORS ChangeLog NEWS README THANKS"
-
-pkg_setup() {
-	if ! use debug; then
-		G2CONF="${G2CONF} --enable-debug=minimum"
-	fi
-
-	G2CONF="${G2CONF}
-		$(use_enable ipv6)
-		--disable-maintainer-flags
-		--enable-zlib
-		--disable-static
-		--disable-schemas-install
-		--disable-scrollkeeper"
-}
-
-src_prepare() {
-	gnome2_src_prepare
-
-	# Remove idiotic -D.*DISABLE_DEPRECATED cflags
-	# This method is kinda prone to breakage. Recheck carefully with next bump.
-	# bug 339074
-	find . -iname 'Makefile.am' -exec \
-		sed -e '/-D[A-Z_]*DISABLE_DEPRECATED/d' -i {} + || die "sed 1 failed"
-	# Do Makefile.in after Makefile.am to avoid automake maintainer-mode
-	find . -iname 'Makefile.in' -exec \
-		sed -e '/-D[A-Z_]*DISABLE_DEPRECATED/d' -i {} + || die "sed 1 failed"
-
-	if ! use test ; then
-		sed -e 's/ tests//' -i logview/Makefile.{am,in} || die "sed 2 failed"
-	fi
-}
-
-src_install() {
-	gnome2_src_install
-	find "${ED}" -name "*.la" -delete || die "remove of la files failed"
-}
diff --git a/gnome-extra/gnome-utils/metadata.xml b/gnome-extra/gnome-utils/metadata.xml
index da6fd63d0085..b1fd14e1d978 100644
--- a/gnome-extra/gnome-utils/metadata.xml
+++ b/gnome-extra/gnome-utils/metadata.xml
@@ -2,4 +2,8 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>gnome</herd>
+<use>
+	<flag name="bonobo">Enable applets (gdict one) still not ported to
+	DBUS, requiring	deprecated bonobo support in gnome-panel.</flag>
+</use>
 </pkgmetadata>
-- 
cgit v1.2.3-65-gdbad