From d0ddc91546c36b27accc2133f52bd703556adbcf Mon Sep 17 00:00:00 2001
From: Sergey Popov <pinkbyte@gentoo.org>
Date: Wed, 10 Jul 2013 20:29:20 +0000
Subject: Initial commit, wrt bug #437072, thanks to Jakub Paluszak <paluszak
 AT gmail.com> for initial ebuild

(Portage version: 2.2.0_alpha184/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)
---
 sys-process/procexp/ChangeLog              | 11 +++++
 sys-process/procexp/metadata.xml           |  9 ++++
 sys-process/procexp/procexp-1.5.277.ebuild | 72 ++++++++++++++++++++++++++++++
 3 files changed, 92 insertions(+)
 create mode 100644 sys-process/procexp/ChangeLog
 create mode 100644 sys-process/procexp/metadata.xml
 create mode 100644 sys-process/procexp/procexp-1.5.277.ebuild

(limited to 'sys-process/procexp')

diff --git a/sys-process/procexp/ChangeLog b/sys-process/procexp/ChangeLog
new file mode 100644
index 000000000000..2a5c2d8515e0
--- /dev/null
+++ b/sys-process/procexp/ChangeLog
@@ -0,0 +1,11 @@
+# ChangeLog for sys-process/procexp
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-process/procexp/ChangeLog,v 1.1 2013/07/10 20:29:20 pinkbyte Exp $
+
+*procexp-1.5.277 (10 Jul 2013)
+
+  10 Jul 2013; Sergey Popov <pinkbyte@gentoo.org> +procexp-1.5.277.ebuild,
+  +metadata.xml:
+  Initial commit, wrt bug #437072, thanks to Jakub Paluszak <paluszak AT
+  gmail.com> for initial ebuild
+
diff --git a/sys-process/procexp/metadata.xml b/sys-process/procexp/metadata.xml
new file mode 100644
index 000000000000..c532d95d45a6
--- /dev/null
+++ b/sys-process/procexp/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>python</herd>
+	<maintainer>
+		<email>pinkbyte@gentoo.org</email>
+		<name>Sergey Popov</name>
+	</maintainer>
+</pkgmetadata>
diff --git a/sys-process/procexp/procexp-1.5.277.ebuild b/sys-process/procexp/procexp-1.5.277.ebuild
new file mode 100644
index 000000000000..188c7aa97be0
--- /dev/null
+++ b/sys-process/procexp/procexp-1.5.277.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-process/procexp/procexp-1.5.277.ebuild,v 1.1 2013/07/10 20:29:20 pinkbyte Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_{6,7} )
+inherit eutils gnome2-utils multilib python-single-r1 rpm versionator
+
+MY_P="process_explorer-$(replace_version_separator 2 '-')"
+
+DESCRIPTION="Graphical process explorer"
+HOMEPAGE="http://sourceforge.net/apps/mediawiki/procexp/index.php?title=Main_Page"
+SRC_URI="mirror://sourceforge/project/procexp/${MY_P}.noarch.rpm"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	dev-python/PyQt4[X,${PYTHON_USEDEP}]
+	dev-python/configobj[${PYTHON_USEDEP}]
+	dev-python/pyqwt[${PYTHON_USEDEP}]
+	sys-auth/polkit"
+
+S="${WORKDIR}/opt/${MY_P}/${PN}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# No build system provided by upstream
+# https://sourceforge.net/tracker/?func=detail&aid=3573774&group_id=309156&atid=1301952
+
+src_prepare() {
+	# Removing unnecessary svn cruft
+	esvn_clean
+
+	rm make_rpm.py process_explorer.spec ${PN}.desktop ${PN}.sh || die 'remove unneeded files failed'
+
+	epatch_user
+
+	python_fix_shebang .
+}
+
+src_install() {
+	newicon -s 48 icon.png ${PN}.png
+	rm icon.png || die
+
+	insinto "/usr/share/polkit-1/actions"
+	doins com.procexp.pkexec.policy
+	rm com.procexp.pkexec.policy || die
+
+	insinto "/usr/$(get_libdir)/${PN}"
+	doins -r *
+	fperms +x "/usr/$(get_libdir)/${PN}/procexp.py"
+	fperms +x "/usr/$(get_libdir)/${PN}/rootproxy/procroot.py"
+
+	dosym "/usr/$(get_libdir)/${PN}/procexp.py" /usr/bin/procexp
+	make_desktop_entry ${PN} "Linux Process Explorer" ${PN} "System;Utility;"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
-- 
cgit v1.2.3-65-gdbad