# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/scotch/scotch-5.1.11.ebuild,v 1.2 2011/03/15 16:58:35 bicatali Exp $

EAPI=4

inherit eutils toolchain-funcs versionator alternatives-2

# use esmumps version to allow linking with mumps
MYP="${PN}_${PV}_esmumps"
# download id on gforge changes every goddamn release
DID=28044

DESCRIPTION="Software for graph, mesh and hypergraph partitioning"
HOMEPAGE="http://www.labri.u-bordeaux.fr/perso/pelegrin/scotch/"
SRC_URI="http://gforge.inria.fr/frs/download.php/${DID}/${MYP}.tgz"

LICENSE="CeCILL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples mpi static-libs tools"

DEPEND="sys-devel/bison
	sys-libs/zlib
	mpi? ( virtual/mpi )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MYP}"

make_shared_lib() {
	local libstatic=${1}
	local soname=$(basename "${1%.a}").so.$(get_major_version)
	shift
	einfo "Making ${soname}"
	${LINK:-$(tc-getCC)} ${LDFLAGS}  \
		-shared -Wl,-soname="${soname}" \
		-Wl,--whole-archive "${libstatic}" -Wl,--no-whole-archive \
		"$@" -o $(dirname "${libstatic}")/"${soname}" || die "${soname} failed"
	ln -s "${soname}" $(dirname "${libstatic}")/"${soname%.*}"
}

src_prepare() {
	epatch "${FILESDIR}"/metis-header.patch
	epatch "${FILESDIR}"/respect-ldflags.patch
	sed -e "s/@CFLAGS@/${CFLAGS}/" \
		-e "s/@CC@/$(tc-getCC)/" \
		-e "s/@AR@/$(tc-getAR)/" \
		-e "s/@RANLIB@/$(tc-getRANLIB)/" \
		"${FILESDIR}"/Makefile.inc.in > src/Makefile.inc || die
}

src_compile() {
	emake -C src PICFLAGS=-fPIC
	make_shared_lib lib/libscotcherr.a
	make_shared_lib lib/libscotcherrexit.a
	make_shared_lib lib/libscotch.a -Llib -lscotcherr -lz -lm -lrt
	make_shared_lib lib/libesmumps.a -Llib -lscotch
	make_shared_lib lib/libscotchmetis.a -Llib -lscotch

	if use mpi; then
		emake -C src PICFLAGS=-fPIC ptscotch
		export LINK=mpicc
		make_shared_lib lib/libptscotcherr.a
		make_shared_lib lib/libptscotcherrexit.a
		make_shared_lib lib/libptscotch.a -Llib -lptscotcherr -lz -lm -lrt
		make_shared_lib lib/libptesmumps.a -Llib -lptscotch
		make_shared_lib lib/libptscotchparmetis.a -Llib -lptscotch
	fi
	if use static-libs; then
		emake -C src clean
		emake -C src
		use mpi && emake -C src ptscotch
	fi
}

src_install() {
	dolib.so lib/*.so*
	use static-libs && dolib.a lib/*.a

	insinto /usr/include/scotch
	doins include/*

	cat <<-EOF > scotchmetis.pc
		prefix=${EPREFIX}/usr
		libdir=\${prefix}/$(get_libdir)
		includedir=\${prefix}/include
		Name: ptscotch
		Description: ${DESCRIPTION}
		Version: ${PV}
		URL: ${HOMEPAGE}
		Libs: -L\${libdir} -lscotchmetis -lscotcherr -lscotch
		Private: -lm -lz -lrt
		Cflags: -I\${includedir}/scotch
	EOF
	insinto /usr/$(get_libdir)/pkgconfig
	doins scotchmetis.pc
	alternatives_for metis scotch 0 \
		"/usr/$(get_libdir)/pkgconfig/metis.pc" "scotchmetis.pc"
	cat <<-EOF > ptscotchparmetis.pc
		prefix=${EPREFIX}/usr
		libdir=\${prefix}/$(get_libdir)
		includedir=\${prefix}/include
		Name: ptscotch
		Description: ${DESCRIPTION}
		Version: ${PV}
		URL: ${HOMEPAGE}
		Libs: -L\${libdir} -lptscotchparmetis -lscotchmetis -lptscotcherr -lptscotch
		Private: -lm -lz -lrt
		Cflags: -I\${includedir}/scotch
	EOF
	insinto /usr/$(get_libdir)/pkgconfig
	doins ptscotchparmetis.pc
	alternatives_for metis-mpi scotch 0 \
		"/usr/$(get_libdir)/pkgconfig/metis-mpi.pc" "ptscotchparmetis.pc"

	dodoc README.txt

	if use tools; then
		local b m
		pushd bin > /dev/null
		for b in *; do
			newbin ${b} scotch_${b}
		done
		popd

		pushd man/man1 > /dev/null
		for m in *; do
			newman ${m} scotch_${m}
		done
		popd > /dev/null
	fi

	use doc && dodoc doc/*.pdf

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins -r examples/* tgt grf
	fi
}