# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

EGIT_REPO_URI="git://code.stapelberg.de/i3"
EGIT_BRANCH="tree"

inherit eutils git-2 toolchain-funcs

DESCRIPTION="An improved dynamic tiling window manager"
HOMEPAGE="http://i3wm.org/"
SRC_URI=""

LICENSE="BSD"
SLOT="0"
KEYWORDS=""
IUSE="doc"

CDEPEND="dev-libs/libev
	dev-libs/yajl
	x11-libs/libxcb
	x11-libs/libX11
	x11-libs/xcb-util"
DEPEND="${CDEPEND}
	sys-devel/flex
	sys-devel/bison
	app-text/asciidoc
	app-text/xmlto
	app-text/docbook-xml-dtd
	x11-proto/xcb-proto"
RDEPEND="${CDEPEND}
	x11-apps/xmessage"

pkg_setup() {
	tc-export CC
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-build.patch
	sed	-e "/SILENT/d" -e "/DEBUG=/d" \
		-e '/ifeq ($(DEBUG),1)/,/endif/d' \
		-i common.mk || die
	sed -e '/echo "\([[:upper:]]\)/d' \
		-i Makefile i3-{msg,nagbar,config-wizard}/Makefile || die
}

src_compile() {
	emake || die
	emake -C man || die
	use doc && { emake -C docs || die ; }
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc GOALS TODO CMDMODE RELEASE-*
	doman man/*.1
	if use doc; then
		dohtml -r docs/*.html
	fi
}