dev-db/pgadmin4: Bump to 3.5

Package-Manager: Portage-2.3.51, Repoman-2.3.11
Signed-off-by: Aaron Swenson <titanofold@gentoo.org>

2 files changed, 125 insertions, 0 deletions

diff --git a/dev-db/pgadmin4/Manifest b/dev-db/pgadmin4/Manifest
index b5eadc7f54b4..4ac163ad400a 100644
--- a/dev-db/pgadmin4/Manifest
+++ b/dev-db/pgadmin4/Manifest
@@ -1,2 +1,3 @@
 DIST pgadmin4-3.0.tar.gz 28915010 BLAKE2B 7e6dccd91f082f7b5514f5d3abdf4653a9961b4efc706e10ce58d817785d514508233e25068762fe0e4bca4c1a3cf10a2515afa38e6f9ba3c99b4af3fa32f3d2 SHA512 5921340176e6748ef13112d906061f195d4bb2f73917d762371bbaeb44ef66cf8e0edcd1cd241eb78dae46ed0b3af014c749468a930fb0c0983b38b2c54dfc3a
 DIST pgadmin4-3.4.tar.gz 30743447 BLAKE2B 4476989dc9bd672810ced56f4c3e6b87f27ec28d693ab6a909b1cdd4ddc0ae51552fe7ac5a3db4382ccded433b1dab239de01697c0709474381c117460a45163 SHA512 57160827a7577b89029a3a621653f2fec9f3b5379a554ea8bcaf80225f32f1ed93e4560ce5d5b499aff2091589e641bdfe82987be46b6155bca3fb072cf2c5e2
+DIST pgadmin4-3.5.tar.gz 31501977 BLAKE2B fbb1ab4ffde62f6a62ff74088d32cfbdb147c5599d713eae46b3ff50972aab7c6aa48ef108d360001dcca8d999cdd0526c6db5f8bfe260bda52dfa4b41678a87 SHA512 6971c003a39fdd2f279fa7a652a32e1554d17d1794fa0b84c4aa3394ab128efbb44299890bd69b07a0ca926d918668fba124f99f3d7271c60ee70616eedd6d1c
diff --git a/dev-db/pgadmin4/pgadmin4-3.5.ebuild b/dev-db/pgadmin4/pgadmin4-3.5.ebuild
new file mode 100644
index 000000000000..f0db6c595531
--- /dev/null
+++ b/dev-db/pgadmin4/pgadmin4-3.5.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+PYTHON_REQ_USE="sqlite"
+
+inherit python-single-r1 qmake-utils
+
+DESCRIPTION="GUI administration and development platform for PostgreSQL"
+HOMEPAGE="https://www.pgadmin.org/"
+SRC_URI="mirror://postgresql/pgadmin/${PN}/v${PV}/source/${P}.tar.gz"
+
+LICENSE="POSTGRESQL"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="doc"
+
+RESTRICT="test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+"
+
+DEPEND="${COMMON_DEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	>=app-text/htmlmin-0.1.12[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+	>=dev-python/beautifulsoup-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.4[${PYTHON_USEDEP}]
+	>=dev-python/click-6.6[${PYTHON_USEDEP}]
+	>=dev-python/extras-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-0.12.4[${PYTHON_USEDEP}]
+	>=dev-python/flask-babel-0.11.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-babelex-0.9.3[${PYTHON_USEDEP}]
+	>=dev-python/flask-gravatar-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-htmlmin-1.3.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-login-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-mail-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-migrate-2.1.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-paranoid-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-principal-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-security-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-sqlalchemy-2.3.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-wtf-0.14.2[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-0.24[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.7.3[${PYTHON_USEDEP}]
+	>=dev-python/linecache2-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-0.23[${PYTHON_USEDEP}]
+	>=dev-python/mimeparse-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/pbr-3.1.1[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.4.7[${PYTHON_USEDEP}]
+	>=dev-python/psycopg-2.7.4[${PYTHON_USEDEP}]
+	>=dev-python/pycrypto-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/pyrsistent-0.14.2[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.7.1[${PYTHON_USEDEP}]
+	>=dev-python/python-sqlparse-0.2.4[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2018.3[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-3.13.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11.0[${PYTHON_USEDEP}]
+	>=dev-python/speaklater-1.3[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.2.5[${PYTHON_USEDEP}]
+	>=dev-python/sshtunnel-0.1.3[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.9.6[${PYTHON_USEDEP}]
+	>=dev-python/wtforms-2.1[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}"/${P}/runtime
+
+src_prepare() {
+	cd "${WORKDIR}"/${P} || die
+	default
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_compile() {
+	default
+	if use doc; then
+		cd "${WORKDIR}"/${P} || die
+		emake docs
+	fi
+}
+
+src_install() {
+	dobin pgAdmin4
+
+	cd "${WORKDIR}"/${P} || die
+
+	local APP_DIR=/usr/share/${PN}/web
+	insinto "${APP_DIR}"
+	doins -r web/*
+	cat > "${D}${APP_DIR}"/config_local.py <<-EOF
+		SERVER_MODE = False
+		UPGRADE_CHECK_ENABLED = False
+	EOF
+	python_optimize "${D}${APP_DIR}"
+
+	local CONFIG_DIR="/etc/xdg/pgadmin"
+	dodir "${CONFIG_DIR}"
+	cat > "${D}${CONFIG_DIR}"/pgadmin4.conf <<-EOF
+		[General]
+		ApplicationPath=${APP_DIR}
+		PythonPath=$(python_get_sitedir)
+	EOF
+
+	if use doc; then
+		rm -r docs/en_US/_build/html/_sources || die
+		insinto /usr/share/${PN}/docs/en_US/_build
+		doins -r docs/en_US/_build/html
+	fi
+}