dev-db/pgadmin4: 4.17 version bump, python3_8

Patch taken from Arch, thanks.

Package-Manager: Portage-2.3.87, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

3 files changed, 119 insertions, 0 deletions

diff --git a/dev-db/pgadmin4/Manifest b/dev-db/pgadmin4/Manifest
index d8c0c3afb414..6a07a9896d2d 100644
--- a/dev-db/pgadmin4/Manifest
+++ b/dev-db/pgadmin4/Manifest
@@ -1 +1,2 @@
 DIST pgadmin4-4.13.tar.gz 25077107 BLAKE2B afbf0b6fba2f4cbbc1f47ac6c7867b7f131e5698de265a9dda53b79968f237ac591c5ff4da94dde0b74479cac1158ec825f42b14fc01aee13982043822c04443 SHA512 7eca41047e41f7bdce2dfe992260e8c2ab40f985dd232eb240ea9c0024f551f011653717aa0d5e4ccdccd4ef4936102cde1f97a32852d8382dcc222fadce7707
+DIST pgadmin4-4.17.tar.gz 28007097 BLAKE2B d296f2b9372c23067db899fa82e1b8e732837b01a6172dd2d70520f815aafde161715eea9d9d53e7507a6a715dbfdaabf001a10d143c1aa0505237b2b138e334 SHA512 f9e292ba7ff1e5edaa8738188eb01744d69d0eb134700feb0623806425c998e7f298f74cd498a09f2d9a073a9a349c82f7a3f617e1da3c8dd757cc982d941c9f
diff --git a/dev-db/pgadmin4/files/pgadmin4-4.17-python-3.8.patch b/dev-db/pgadmin4/files/pgadmin4-4.17-python-3.8.patch
new file mode 100644
index 000000000000..fbf2f7be4a9b
--- /dev/null
+++ b/dev-db/pgadmin4/files/pgadmin4-4.17-python-3.8.patch
@@ -0,0 +1,12 @@
+diff -uprb pgadmin4-4.13.orig/runtime/pgAdmin4.pro pgadmin4-4.13/runtime/pgAdmin4.pro
+--- a/runtime/pgAdmin4.pro	2019-10-16 10:07:59.000000000 +0300
++++ b/runtime/pgAdmin4.pro	2019-11-05 18:33:18.524516120 +0200
+@@ -75,7 +75,7 @@ else {
+ 
+     QMAKE_CXXFLAGS += $$system($$PYTHON_CONFIG --includes)
+     QMAKE_LFLAGS += $$system($$PYTHON_CONFIG --ldflags)
+-    LIBS += $$system($$PYTHON_CONFIG --libs)
++    LIBS += $$system(PYTHON_LIBS=`$$PYTHON_CONFIG --libs --embed` || PYTHON_LIBS=`$$PYTHON_CONFIG --libs`; echo $PYTHON_LIBS)
+ 
+     contains( LIBS, -lpython2.* ) {
+        DEFINES += PYTHON2
diff --git a/dev-db/pgadmin4/pgadmin4-4.17.ebuild b/dev-db/pgadmin4/pgadmin4-4.17.ebuild
new file mode 100644
index 000000000000..626795b4964c
--- /dev/null
+++ b/dev-db/pgadmin4/pgadmin4-4.17.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite"
+inherit python-single-r1 qmake-utils
+
+DESCRIPTION="GUI administration and development platform for PostgreSQL"
+HOMEPAGE="https://www.pgadmin.org/"
+SRC_URI="https://ftp.postgresql.org/pub/pgadmin/${PN}/v${PV}/source/${P}.tar.gz"
+
+LICENSE="POSTGRESQL"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="test"
+
+# libsodium dep added because of 689678
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-libs/libsodium[-minimal]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtwidgets:5
+"
+DEPEND="${COMMON_DEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=app-text/htmlmin-0.1.12[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.4[${PYTHON_USEDEP}]
+	>=dev-python/flask-1.0.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-gravatar-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-htmlmin-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-login-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-mail-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-migrate-2.4.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-paranoid-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-principal-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-security-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-sqlalchemy-2.3.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-wtf-0.14.2[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.5.1[${PYTHON_USEDEP}]
+	>=dev-python/psycopg-2.8[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-sqlparse-0.2.4[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2018.9[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-3.16.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+	>=dev-python/speaklater-1.3[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.2.18[${PYTHON_USEDEP}]
+	>=dev-python/sshtunnel-0.1.4[${PYTHON_USEDEP}]
+	>=dev-python/wtforms-2.2.1[${PYTHON_USEDEP}]
+"
+
+PATCHES=( "${FILESDIR}"/${P}-python-3.8.patch )
+
+S="${WORKDIR}"/${P}/runtime
+
+src_prepare() {
+	cd "${WORKDIR}"/${P} || die
+	default
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_compile() {
+	default
+	use doc && emake -C "${WORKDIR}"/${P} docs
+}
+
+src_install() {
+	dobin pgAdmin4
+
+	cd "${WORKDIR}"/${P} || die
+
+	local APP_DIR=/usr/share/${PN}/web
+	insinto "${APP_DIR}"
+	doins -r web/.
+	newins - config_local.py <<-EOF
+		SERVER_MODE = False
+		UPGRADE_CHECK_ENABLED = False
+	EOF
+	python_optimize "${D}${APP_DIR}"
+
+	insinto /etc/xdg/pgadmin
+	newins - pgadmin4.conf <<-EOF
+		[General]
+		ApplicationPath=${APP_DIR}
+		PythonPath=$(python_get_sitedir)
+	EOF
+
+	if use doc; then
+		rm -r docs/en_US/_build/html/_sources || die
+		insinto /usr/share/${PN}/docs/en_US/_build
+		doins -r docs/en_US/_build/html
+	fi
+}