net-analyzer/gvm-libs: USE 'extras' → 'doc', swap LICENSE/SLOT order

Signed-off-by: Florian Schmaus <flow@gentoo.org>

1 files changed, 115 insertions, 0 deletions

diff --git a/net-analyzer/gvm-libs/gvm-libs-21.4.4-r1.ebuild b/net-analyzer/gvm-libs/gvm-libs-21.4.4-r1.ebuild
new file mode 100644
index 000000000000..54c52a6248a7
--- /dev/null
+++ b/net-analyzer/gvm-libs/gvm-libs-21.4.4-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+inherit cmake toolchain-funcs
+
+DESCRIPTION="Greenbone vulnerability management libraries, previously named openvas-libraries"
+HOMEPAGE="https://www.greenbone.net/en/ https://github.com/greenbone/gvm-libs/"
+SRC_URI="https://github.com/greenbone/gvm-libs/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ldap test radius"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	acct-group/gvm
+	acct-user/gvm
+	app-crypt/gpgme:=
+	dev-libs/glib:2
+	dev-libs/hiredis:=
+	dev-libs/libgcrypt:=
+	dev-libs/libgpg-error
+	dev-libs/libxml2:=
+	dev-perl/UUID
+	net-libs/gnutls:=
+	net-libs/libnet:1.1
+	net-libs/libssh:=
+	sys-apps/util-linux
+	sys-libs/libxcrypt:=
+	sys-libs/zlib
+	ldap? ( net-nds/openldap:= )
+	radius? ( net-dialup/freeradius-client )"
+
+RDEPEND="
+	${DEPEND}"
+
+BDEPEND="
+	dev-vcs/git
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen[dot]
+		app-doc/xmltoman
+		app-text/htmldoc
+		dev-perl/CGI
+		dev-perl/SQL-Translator
+	)
+	test? ( dev-libs/cgreen )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20.8.1-disable-automagic-dep.patch
+)
+
+src_prepare() {
+	cmake_src_prepare
+	# QA-Fix | Remove doxygen warnings for !CLANG
+	if use doc; then
+		if ! tc-is-clang; then
+		   local f
+		   for f in doc/*.in
+		   do
+			sed -i \
+				-e "s*CLANG_ASSISTED_PARSING = NO*#CLANG_ASSISTED_PARSING = NO*g" \
+				-e "s*CLANG_OPTIONS*#CLANG_OPTIONS*g" \
+				"${f}" || die "couldn't disable CLANG parsing"
+		   done
+		fi
+	fi
+
+	#Remove tests that doesn't work in the network sandbox
+	if use test; then
+		sed -i 's/add_test (networking-test networking-test)/ /g' base/CMakeLists.txt || die
+		sed -i 's/add_test (util-test util-test)/ /g' boreas/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"-DLOCALSTATEDIR=${EPREFIX}/var"
+		"-DSYSCONFDIR=${EPREFIX}/etc"
+		"-DGVM_RUN_DIR=${EPREFIX}/var/lib/gvm"
+		"-DBUILD_TESTS=$(usex test)"
+		"-DBUILD_WITH_RADIUS=$(usex radius)"
+		"-DBUILD_WITH_LDAP=$(usex ldap)"
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	if use doc; then
+		cmake_build -C "${BUILD_DIR}" doc
+		cmake_build doc-full -C "${BUILD_DIR}" doc
+	fi
+	cmake_build rebuild_cache
+	if use test; then
+		cmake_build tests
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${BUILD_DIR}"/doc/generated/html/. )
+	fi
+	cmake_src_install
+
+	# Set proper permissions on required files/directories
+	keepdir /var/lib/gvm
+	fowners -R gvm:gvm /var/lib/gvm
+}