net-im/qtox: version bump to 1.16.3

Bug: https://bugs.gentoo.org/635636
Package-Manager: Portage-2.3.40, Repoman-2.3.9

4 files changed, 91 insertions, 18 deletions

diff --git a/net-im/qtox/Manifest b/net-im/qtox/Manifest
index 03e515e27f1b..2040dc77b88f 100644
--- a/net-im/qtox/Manifest
+++ b/net-im/qtox/Manifest
@@ -1,2 +1,3 @@
+DIST qTox-1.16.3.tar.gz 4256757 BLAKE2B 70103e2d912da86dab63424586c642a73614b4a408a53634b146d1e401d5b328a2b8c81c472a94e0e8804d774f693c1250e7263b263e80abef5e111372f29232 SHA512 a857266ffcf32b1963e3a4428501299ce19f3c087087583115dc01e41934fc31d52ea54d781fa93ec7e21f6e3303b4e22383ecaaa7f1f1dbf32d740db73aca4c
 DIST qtox-1.11.0.tar.lz 2860849 BLAKE2B eedb0720c57afd8a99e48452af67162977df0c4cb889891b082345b0b2d37539cef39d5be16b0e9ce0615561b6628c908e5d3007b96c23026859dc4d42261223 SHA512 3117b5ec9d88f58023f6c2f5e7c37c547ab920588d385e3abe062fb22ad79c49a9b6eb9ca31c6d56f9d03cfea55ef56ddc7e2e53bd43629825ea7b460b31f505
 DIST qtox-1.8.1.tar.gz 3594727 BLAKE2B a1d4191551b082cef21ee211eebf7288aa805bb2401e9c7a48359273fd6520c67eaf826f985843fd01ca0bd4312fab9da1169cbd8b7b61916e282dde06f9dee5 SHA512 9ba32ce43f2d335fe9e07bcca651e0e18ae2f3247e52364918148e400e51f6e2364d1596c7c882674c190bf5438e69cd13e77512eeeec7cba212195e9559a5ae
diff --git a/net-im/qtox/metadata.xml b/net-im/qtox/metadata.xml
index 1ce2420d23bb..aa2232cb4665 100644
--- a/net-im/qtox/metadata.xml
+++ b/net-im/qtox/metadata.xml
@@ -3,7 +3,7 @@
 <pkgmetadata>
 	<!-- maintainer-needed -->
 	<use>
-		<flag name="gtk">Adds support for GTK and Status Notifier tray backends</flag>
+		<flag name="notification">Adds support for GTK Status Notifier tray backends</flag>
 		<flag name="X">Adds support for X11</flag>
 	</use>
 	<upstream>
diff --git a/net-im/qtox/qtox-1.16.3.ebuild b/net-im/qtox/qtox-1.16.3.ebuild
new file mode 100644
index 000000000000..4bd474cc1f42
--- /dev/null
+++ b/net-im/qtox/qtox-1.16.3.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2-utils xdg-utils
+
+MY_P="qTox-${PV}"
+DESCRIPTION="Most feature-rich GUI for net-libs/tox using Qt5"
+HOMEPAGE="https://github.com/qTox/qTox"
+SRC_URI="https://github.com/qTox/qTox/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="notification test X"
+
+S="${WORKDIR}/${MY_P}"
+
+RDEPEND="
+	dev-db/sqlcipher
+	dev-libs/libsodium:=
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5[gif,jpeg,png,xcb]
+	dev-qt/qtnetwork:5
+	dev-qt/qtopengl:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	media-gfx/qrencode:=
+	media-libs/openal
+	>=media-video/ffmpeg-2.6.3:=[webp,v4l]
+	net-libs/tox:0/0.2[av]
+	notification? ( x11-libs/gtk+:2 )
+	X? ( x11-libs/libX11
+		x11-libs/libXScrnSaver )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+	test? ( dev-qt/qttest:5 )
+"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# bug 628574
+	if ! use test; then
+		sed -i CMakeLists.txt -e "/include(Testing)/d" || die
+		sed -i cmake/Dependencies.cmake -e "/find_package(Qt5Test/d" || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_STATUSNOTIFIER=$(usex notification)
+		-DENABLE_GTK_SYSTRAY=$(usex notification)
+		-DPLATFORM_EXTENSIONS=$(usex X)
+		-DUSE_FILTERAUDIO=OFF
+		-DGIT_DESCRIBE="${PV}"
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
diff --git a/net-im/qtox/qtox-9999.ebuild b/net-im/qtox/qtox-9999.ebuild
index c635dfc405d4..3ad3165b1bc9 100644
--- a/net-im/qtox/qtox-9999.ebuild
+++ b/net-im/qtox/qtox-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -13,11 +13,11 @@ EGIT_REPO_URI="https://github.com/qTox/qTox.git"
 LICENSE="GPL-3+"
 SLOT="0"
 KEYWORDS=""
-IUSE="gtk test X"
+IUSE="notification test X"
 
 RDEPEND="
 	dev-db/sqlcipher
-	dev-libs/libsodium
+	dev-libs/libsodium:=
 	dev-qt/qtconcurrent:5
 	dev-qt/qtcore:5
 	dev-qt/qtgui:5[gif,jpeg,png,xcb]
@@ -27,17 +27,11 @@ RDEPEND="
 	dev-qt/qtsvg:5
 	dev-qt/qtwidgets:5
 	dev-qt/qtxml:5
-	media-gfx/qrencode
-	media-libs/libexif
+	media-gfx/qrencode:=
 	media-libs/openal
-	>=media-video/ffmpeg-2.6.3[webp,v4l]
-	gtk? (	dev-libs/atk
-			dev-libs/glib:2
-			x11-libs/gdk-pixbuf[X]
-			x11-libs/gtk+:2
-			x11-libs/cairo[X]
-			x11-libs/pango[X] )
-	net-libs/tox:0/0.1[av]
+	>=media-video/ffmpeg-2.6.3:=[webp,v4l]
+	net-libs/tox:0/0.2[av]
+	notification? ( x11-libs/gtk+:2 )
 	X? ( x11-libs/libX11
 		x11-libs/libXScrnSaver )
 "
@@ -52,15 +46,17 @@ src_prepare() {
 
 	# bug 628574
 	if ! use test; then
-		sed -i CMakeLists.txt -e "/include(Testing)/s/^/#/" || die
-		sed -i cmake/Dependencies.cmake -e "/find_package(Qt5Test/s/^/#/" || die
+		sed -i CMakeLists.txt -e "/include(Testing)/d" || die
+		sed -i cmake/Dependencies.cmake -e "/find_package(Qt5Test/d" || die
 	fi
 }
 
 src_configure() {
 	local mycmakeargs=(
-		-DENABLE_STATUSNOTIFIER=$(usex gtk)
-		-DENABLE_GTK_SYSTRAY=$(usex gtk)
+		-DENABLE_STATUSNOTIFIER=$(usex notification)
+		-DENABLE_GTK_SYSTRAY=$(usex notification)
+		-DPLATFORM_EXTENSIONS=$(usex X)
+		-DUSE_FILTERAUDIO=OFF
 	)
 
 	cmake-utils_src_configure