net-libs/libtelnet: Various ebuild improvements

- Add missing dependency on zlib, and missing BDEPEND on doxygen and
  pkgconfig
- Unify release and 9999 ebuild skeletons
- Update EAPI to 8, which also automatically passes --disable-static to
  econf so we don't need to manually remove static libraries in 0.23
  anymore

Signed-off-by: Jakov Smolić <jsmolic@gentoo.org>

3 files changed, 54 insertions, 34 deletions

diff --git a/net-libs/libtelnet/libtelnet-0.23-r1.ebuild b/net-libs/libtelnet/libtelnet-0.23-r1.ebuild
new file mode 100644
index 000000000000..bf00b8db2d1e
--- /dev/null
+++ b/net-libs/libtelnet/libtelnet-0.23-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/seanmiddleditch/libtelnet.git"
+	inherit git-r3 cmake
+else
+	inherit autotools
+	SRC_URI="https://github.com/seanmiddleditch/libtelnet/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Simple RFC-compliant TELNET implementation as a C library"
+HOMEPAGE="https://github.com/seanmiddleditch/libtelnet"
+
+LICENSE="public-domain"
+SLOT="0"
+
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-doc/doxygen
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	if [[ ${PV} = *9999 ]]; then
+		eapply "${FILESDIR}"/${P}-doc.patch
+		cmake_src_prepare
+	else
+		eautoreconf
+	fi
+}
diff --git a/net-libs/libtelnet/libtelnet-0.23.ebuild b/net-libs/libtelnet/libtelnet-0.23.ebuild
deleted file mode 100644
index 9577f3cce082..000000000000
--- a/net-libs/libtelnet/libtelnet-0.23.ebuild
+++ /dev/null
@@ -1,24 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools
-
-DESCRIPTION="Simple RFC-compliant TELNET implementation as a C library"
-HOMEPAGE="https://github.com/seanmiddleditch/libtelnet"
-SRC_URI="https://github.com/seanmiddleditch/libtelnet/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="public-domain"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-src_prepare() {
-	default
-	eautoreconf
-}
-
-src_install() {
-	default
-	find "${D}" -type f -name '*.a' -delete || die
-}
diff --git a/net-libs/libtelnet/libtelnet-9999.ebuild b/net-libs/libtelnet/libtelnet-9999.ebuild
index 9edf0466d6a4..bf00b8db2d1e 100644
--- a/net-libs/libtelnet/libtelnet-9999.ebuild
+++ b/net-libs/libtelnet/libtelnet-9999.ebuild
@@ -1,14 +1,13 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
-
-inherit cmake
+EAPI=8
 
 if [[ ${PV} == *9999 ]]; then
-	inherit git-r3
 	EGIT_REPO_URI="https://github.com/seanmiddleditch/libtelnet.git"
+	inherit git-r3 cmake
 else
+	inherit autotools
 	SRC_URI="https://github.com/seanmiddleditch/libtelnet/archive/${PV}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~x86"
 fi
@@ -19,10 +18,19 @@ HOMEPAGE="https://github.com/seanmiddleditch/libtelnet"
 LICENSE="public-domain"
 SLOT="0"
 
-# needed unconditionally for man pages
-BDEPEND="app-doc/doxygen"
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-doc/doxygen
+	virtual/pkgconfig
+"
 
-PATCHES=(
-	# https://bugs.gentoo.org/737886
-	"${FILESDIR}/${P}-doc.patch"
-)
+src_prepare() {
+	default
+	if [[ ${PV} = *9999 ]]; then
+		eapply "${FILESDIR}"/${P}-doc.patch
+		cmake_src_prepare
+	else
+		eautoreconf
+	fi
+}