From 547cde6897aabd5b93d974dc6529eaea1585daeb Mon Sep 17 00:00:00 2001
From: Alfredo Tupone <tupone@gentoo.org>
Date: Mon, 24 Apr 2023 11:16:45 +0200
Subject: dev-ada/gpr-unit-provider: respect ADAFLAGS

Closes: https://bugs.gentoo.org/902537
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>
---
 .../gpr-unit-provider-23.0.0-r2.ebuild             | 59 ----------------------
 .../gpr-unit-provider-23.0.0-r3.ebuild             | 54 ++++++++++++++++++++
 2 files changed, 54 insertions(+), 59 deletions(-)
 delete mode 100644 dev-ada/gpr-unit-provider/gpr-unit-provider-23.0.0-r2.ebuild
 create mode 100644 dev-ada/gpr-unit-provider/gpr-unit-provider-23.0.0-r3.ebuild

(limited to 'dev-ada/gpr-unit-provider')

diff --git a/dev-ada/gpr-unit-provider/gpr-unit-provider-23.0.0-r2.ebuild b/dev-ada/gpr-unit-provider/gpr-unit-provider-23.0.0-r2.ebuild
deleted file mode 100644
index 2e1af4e2ac0d..000000000000
--- a/dev-ada/gpr-unit-provider/gpr-unit-provider-23.0.0-r2.ebuild
+++ /dev/null
@@ -1,59 +0,0 @@
-# Copyright 2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ADA_COMPAT=( gnat_2021 gcc_12 )
-inherit ada multiprocessing
-
-DESCRIPTION="GPR Unit Provider"
-HOMEPAGE="https://github.com/AdaCore/gpr-unit-provider"
-SRC_URI="https://github.com/AdaCore/${PN}/archive/refs/tags/v${PV}.tar.gz
-	-> ${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="+shared static-libs static-pic"
-
-RDEPEND="${ADA_DEPS}
-	dev-ada/gpr:=[${ADA_USEDEP},shared?]
-	dev-ada/libadalang:=[${ADA_USEDEP},static-libs?,static-pic?]"
-DEPEND="${RDEPEND}"
-BDEPEND="dev-ada/gprbuild[${ADA_USEDEP}]"
-REQUIRED_USE="${ADA_REQUIRED_USE}
-	|| ( shared static-libs static-pic )"
-
-src_compile() {
-	if use static-libs; then
-		emake PROCESSORS=$(makeopts_jobs) \
-			GPRBUILD_OPTIONS=-v \
-			build-static
-	fi
-	if use shared; then
-		emake PROCESSORS=$(makeopts_jobs) \
-			GPRBUILD_OPTIONS=-v \
-			build-relocatable
-	fi
-	if use static-pic; then
-		emake PROCESSORS=$(makeopts_jobs) \
-			GPRBUILD_OPTIONS=-v \
-			build-static-pic
-	fi
-}
-
-src_install() {
-	if use static-libs; then
-		emake prefix="${D}"/usr \
-			install-static
-	fi
-	if use shared; then
-		emake prefix="${D}"/usr \
-			install-relocatable
-	fi
-	if use static-pic; then
-		emake prefix="${D}"/usr \
-			install-static-pic
-	fi
-	einstalldocs
-}
diff --git a/dev-ada/gpr-unit-provider/gpr-unit-provider-23.0.0-r3.ebuild b/dev-ada/gpr-unit-provider/gpr-unit-provider-23.0.0-r3.ebuild
new file mode 100644
index 000000000000..409b5d59236e
--- /dev/null
+++ b/dev-ada/gpr-unit-provider/gpr-unit-provider-23.0.0-r3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ADA_COMPAT=( gnat_2021 gcc_12 )
+inherit ada multiprocessing
+
+DESCRIPTION="GPR Unit Provider"
+HOMEPAGE="https://github.com/AdaCore/gpr-unit-provider"
+SRC_URI="https://github.com/AdaCore/${PN}/archive/refs/tags/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+shared static-libs static-pic"
+
+RDEPEND="${ADA_DEPS}
+	dev-ada/gpr:=[${ADA_USEDEP},shared?]
+	dev-ada/libadalang:=[${ADA_USEDEP},static-libs?,static-pic?]"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-ada/gprbuild[${ADA_USEDEP}]"
+REQUIRED_USE="${ADA_REQUIRED_USE}
+	|| ( shared static-libs static-pic )"
+
+src_compile() {
+	build () {
+		gprbuild -j$(makeopts_jobs) -m -p -v -XLIBRARY_TYPE=$1 \
+		-XGPR_UNIT_PROVIDER_BUILD=release -XXMLADA_BUILD=$1 \
+		-P gpr_unit_provider.gpr \
+		-largs ${LDFLAGS} \
+		-cargs ${ADAFLAGS} || die "gprbuild failed"
+	}
+	use static-libs && build static
+	use shared && build relocatable
+	use static-pic && build static-pic
+}
+
+src_install() {
+	if use static-libs; then
+		emake prefix="${D}"/usr \
+			install-static
+	fi
+	if use shared; then
+		emake prefix="${D}"/usr \
+			install-relocatable
+	fi
+	if use static-pic; then
+		emake prefix="${D}"/usr \
+			install-static-pic
+	fi
+	einstalldocs
+}
-- 
cgit v1.2.3-65-gdbad