From 30bb3c1680ce5a480efd80dc1dc3bea57c44a154 Mon Sep 17 00:00:00 2001
From: Sergei Trofimovich <slyfox@gentoo.org>
Date: Tue, 26 May 2020 22:44:11 +0100
Subject: dev-libs/libpfm: respect AR

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
---
 dev-libs/libpfm/libpfm-4.10.1-r1.ebuild | 38 +++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)
 create mode 100644 dev-libs/libpfm/libpfm-4.10.1-r1.ebuild

(limited to 'dev-libs/libpfm')

diff --git a/dev-libs/libpfm/libpfm-4.10.1-r1.ebuild b/dev-libs/libpfm/libpfm-4.10.1-r1.ebuild
new file mode 100644
index 000000000000..99cd8b0c3d91
--- /dev/null
+++ b/dev-libs/libpfm/libpfm-4.10.1-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib toolchain-funcs
+
+DESCRIPTION="Hardware-based performance monitoring interface for Linux"
+HOMEPAGE="http://perfmon2.sourceforge.net"
+SRC_URI="mirror://sourceforge/perfmon2/${PN}4/${P}.tar.gz"
+
+LICENSE="GPL-2 MIT"
+SLOT="0/4"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="static-libs"
+
+DEPEND=""
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+
+	sed -e "s:SLDFLAGS=:SLDFLAGS=\$(LDFLAGS) :g" \
+		-i lib/Makefile || die
+	sed -e "s:LIBDIR=\$(PREFIX)/lib:LIBDIR=\$(PREFIX)/$(get_libdir):g" \
+		-i config.mk || die
+}
+
+src_compile() {
+	# 'DBG=' unsets '-Werror' and other optional flags, bug #664294
+	emake AR=$(tc-getAR) CC=$(tc-getCC) DBG=
+}
+
+src_install() {
+	emake DESTDIR="${D}" LDCONFIG=true PREFIX="${EPREFIX}/usr"  install
+	use static-libs || find "${ED}" -name '*.a' -exec rm -f '{}' +
+	dodoc README
+}
-- 
cgit v1.2.3-65-gdbad