Version bump and revision update

Package-Manager: portage-2.1.8.3/cvs/Linux x86_64

9 files changed, 575 insertions, 18 deletions

diff --git a/sys-kernel/dracut/ChangeLog b/sys-kernel/dracut/ChangeLog
index 657625213e27..8ff30a7eaaaf 100644
--- a/sys-kernel/dracut/ChangeLog
+++ b/sys-kernel/dracut/ChangeLog
@@ -1,6 +1,19 @@
 # ChangeLog for sys-kernel/dracut
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/ChangeLog,v 1.5 2010/07/07 05:32:16 ramereth Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/ChangeLog,v 1.6 2010/08/17 18:23:40 ramereth Exp $
+
+*dracut-007 (17 Aug 2010)
+*dracut-006-r1 (17 Aug 2010)
+
+  17 Aug 2010; Lance Albertson <ramereth@gentoo.org> +dracut-006-r1.ebuild,
+  +files/dracut-006-console_init-not-necessary.patch,
+  +files/dracut-006-dm-udev-rules.patch, +dracut-007.ebuild,
+  +files/dracut-007-dm-udev-rules.patch,
+  +files/dracut-007-multipath-udev-rules.patch, metadata.xml:
+  Version bump and revision update
+
+  Update 006 with patches from #329003, bump to 007 to resolve #331903.
+  Thanks to Amadeusz Żołnowski for contributing the ebuilds and patches.
 
 *dracut-006 (07 Jul 2010)
 
diff --git a/sys-kernel/dracut/Manifest b/sys-kernel/dracut/Manifest
index 6aca9b94bbc3..ba9347a62006 100644
--- a/sys-kernel/dracut/Manifest
+++ b/sys-kernel/dracut/Manifest
@@ -7,22 +7,29 @@ AUX dracut-002-dir-symlinks.patch 3223 RMD160 0783bfd8172d1e27c0ef79a3973bb69e8c
 AUX dracut-002-gencmdline-check-for-keyboard-i18n-files.patch 795 RMD160 9f41b536a51a14cfb31e4ad9f9c1c8eae3c14d99 SHA1 c145d1fc5ee99dd1226c62f3dd15c55c482ef58a SHA256 5e19deded988923ac4fe79e525d7964ae8052bb9578fe67847fd873aefaedfe5
 AUX dracut-002-makefile-add-with_switch_root.patch 1517 RMD160 5b936eb43fc6a7248c30d94185907d3b551668b6 SHA1 cb1c1552563ad03c94c96e99c558522931f238f2 SHA256 2f7389c3f869f396b4d3dd0f872314a9f490eea74c95725f8c2909d22789e15c
 AUX dracut-002-unmount.patch 1222 RMD160 4a1ca39fdb84b538047e96963524af9b7ad565c6 SHA1 ce07c883eda5086ce5f9427334276d5c87c517a5 SHA256 6b27f01342b595c19d1324b647b1800d7f0ce4f2bd89da6ee5b14d87ab272f5e
+AUX dracut-006-console_init-not-necessary.patch 937 RMD160 a1f630e7acf2ca7caf5a883621a4fac613484492 SHA1 e8d8179fbd1d46a6c069d7ff55ad31470c76af5c SHA256 dc166a211295dc71fb7a9df59ea606559310c8d64aaedd71d018ca73245bb3dd
 AUX dracut-006-dhcp6.patch 544 RMD160 16f030b7c6184fa7c649aec5e81b2c32f264cb5a SHA1 377138f04c03901cc4499525f5035542d71c61ed SHA256 bec6cdf1a85a3e4df2527ac1d8a2d29a73373bbb878dc93123a6a9711fe3bbbf
+AUX dracut-006-dm-udev-rules.patch 2050 RMD160 6b4a964ac1b2688f2a74694f31b6f02bbb648c53 SHA1 e95ab808d79f093197d729c9c838a2fec42b4a9d SHA256 8d87aa6fc091db9aae03dbfab530d732991879486fb2f777e8f2387bbdedb5f1
 AUX dracut-006-lc-all-c.patch 527 RMD160 8f0edd1dc093cec98ed8e57d8cbff528ea97e6d2 SHA1 aa85bd1df4c25e7a48f35162bcefa1aec981ade5 SHA256 588cff03ef0e1a6e519f3e15626b21a500ba1bc13b0d7493baa544033bd34361
+AUX dracut-007-dm-udev-rules.patch 2048 RMD160 20bb37d057b58a523a5bc28fb69fc3b9c231370c SHA1 867ada86c0949106d5b18c69b9e52dbd3cf28e97 SHA256 690a85d5623e673cb43d228ecf4c669bb9e231ec4fd197dac8d66f957eaa98f6
+AUX dracut-007-multipath-udev-rules.patch 1327 RMD160 616179d21a205b477e729e15b074380432b1154c SHA1 08e20308f983574cb52f567de7fe85d5df61a1e1 SHA256 2df06515c59fe64a461f63444793ae1af287b46be9ddd61f3310f6a87ad830f0
 DIST dracut-002.tar.bz2 68444 RMD160 9cfd1a29c01506fe36611745cf40a36a71502435 SHA1 dd86eac785486d5aff1d8529a67e4522f5519b54 SHA256 c667fa44b76553c49a463b0c40ac8aa3bb0bd401e18016190158abe85c0d736f
 DIST dracut-003.tar.bz2 82841 RMD160 627ce019f739787a4048d5d1d461619c0b0c51e2 SHA1 2921127f01042d59f5b1d6e2697aad2b0dff0dc9 SHA256 ca1545e48143d059ea82c4de7669e11fbb20f4225a0e63a62b55f27188cbe50b
 DIST dracut-004.tar.bz2 86057 RMD160 13cd737aa2c68fb281af914541c2791de7de8366 SHA1 870f1f32a14a8f8b8ca8b15806dc4f2418fe1577 SHA256 2ce114b861965cadc004e9e7fb34b810b6b823d85521249cb87db302b63e1eea
 DIST dracut-006.tar.bz2 88986 RMD160 e477b3e7d55f450613d4d4b0e7e15816fc943ca1 SHA1 851f8c19a7624e87b2fcae15eba793d0e9b2e101 SHA256 88831d055e1139616a57d5446fecb9f3349dd0edc7c64aa024d7f5ca7e7538fc
+DIST dracut-007.tar.bz2 99629 RMD160 5bb9d1e89e3d7b3a024369eecb594e71a359778d SHA1 38f2e74f127f682eac4dc7da30ee0ea8debfff1f SHA256 6d58778bcf24b46c82cc72c7d6f5cc1e7bac7f3f9c33aa542052583bd00d20e1
 EBUILD dracut-002-r1.ebuild 2828 RMD160 9a920a2ce5f25afc6060798db3a99849668ee028 SHA1 d4d5ea001be7f6255c69abf31ca860e542ecff8e SHA256 7493b47c6208ea371660ef2ec65dd3f4d72d3d0f3dab5668304079fab352acc0
 EBUILD dracut-003.ebuild 2474 RMD160 8f53fe04670209c18ee7e7463b92bcfe911007fd SHA1 0a8312aa9ede22379dfc02a35ff18b5b775688fe SHA256 20073f8170cee6a13a3f4b4187efc5021e820ce08e4b7c9058a2392e4f07975b
 EBUILD dracut-004.ebuild 2474 RMD160 534ac5f5d264da262c8d69c539cdc2845570c986 SHA1 f4d53a1e0d91c343451e2dc813b01dec08910b4a SHA256 1ecdc47c920e83254ef4d03e61963bd55c760907c5bfd024dc8499e66b59a8c1
+EBUILD dracut-006-r1.ebuild 4092 RMD160 41cb36c3a7cd0f04534f5513741ec67ce722909a SHA1 15dec62d62f6cf0342e87fc0ba4b657f6fcf99d8 SHA256 118f5adce4721bdce7f0626b4ebd56f034adb06e0651129d6d6ab08cd2610c45
 EBUILD dracut-006.ebuild 2897 RMD160 d0d0d03c45f0fbeef08be6b423b51316f5b444f8 SHA1 0fffd1d71e15a390348244633ef0ee494d8470ff SHA256 3c6e4e0810b169192c8fb247fb5333c11661d6490dcca2103a97bee38dac4592
-MISC ChangeLog 1848 RMD160 057e79795d560986df12bcce988ba7b03de8fa94 SHA1 507ee4469df86cd8ca1b38bc135f435bba64777c SHA256 3fc4ef9eda273972e1fc19d6d39e951a0cffc15640f8a94e74346affde62fb6d
-MISC metadata.xml 1077 RMD160 97e274c9dcc19ea7b2a306162bc8eaf90fa6027e SHA1 6692f6cc48faa75e102dba0021c023549bf1d98a SHA256 70ecba2084a33f28b5d552a6cd1f8ef484e5dbab9b0fd3d3947d4a3c268f356f
+EBUILD dracut-007.ebuild 5078 RMD160 cd8546562b39dde79aff26b6060e252f4a6e84a9 SHA1 4553f415ad5f4222afad26c6116ceb6ad5f66d88 SHA256 a89f396a5ad4741331851e50feee257ec04581c7bc5982bf0c55bc20aac38597
+MISC ChangeLog 2382 RMD160 ef322380baaffe4558d9ade0cfc8ca091ffb19bc SHA1 69f67d9a93c6d3f0899f3034e49072e450ed4c3c SHA256 b9441b1b46a785eb1e9aeccdbcfd49cb03e26b0503fa7b5da8585977d76bb06b
+MISC metadata.xml 1719 RMD160 02315212a387576ecab8a390e07953eb297a1b83 SHA1 861af2ab0127d120e47c8c4138841c32ac2c9453 SHA256 def34b3d66553100b9da7f1702b0da90a279eafa9fddf460b4e35f729535f5f8
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.15 (GNU/Linux)
 
-iD8DBQFMNBFnQW+hXSf0t0IRApAlAKCqCrSkOxhCUzx0d61a4TFrCETuWwCguTfD
-fUE+SA92uI5CYVeSldBjhyA=
-=u+6R
+iD8DBQFMatOzQW+hXSf0t0IRAg95AJ9NkQTp2l8pK4X/w6GhKMGHxv+efgCff33Q
+JRMrH74IniWTI5bBGqUaetc=
+=po+h
 -----END PGP SIGNATURE-----
diff --git a/sys-kernel/dracut/dracut-006-r1.ebuild b/sys-kernel/dracut/dracut-006-r1.ebuild
new file mode 100644
index 000000000000..2c0a62197c1c
--- /dev/null
+++ b/sys-kernel/dracut/dracut-006-r1.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-006-r1.ebuild,v 1.1 2010/08/17 18:23:40 ramereth Exp $
+
+EAPI=2
+
+inherit eutils mount-boot
+
+DESCRIPTION="Generic initramfs generation tool"
+HOMEPAGE="http://sourceforge.net/projects/dracut/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+COMMON_IUSE="btrfs debug lvm mdraid multipath selinux syslog uswsusp xen"
+NETWORK_IUSE="iscsi nbd nfs"
+DM_IUSE="crypt dmraid dmsquash-live"
+IUSE="${COMMON_IUSE} ${DM_IUSE} ${NETWORK_IUSE}"
+
+# common networking deps
+NETWORK_DEPS="net-misc/bridge-utils >=net-misc/dhcp-3.1.2_p1 sys-apps/iproute2"
+DM_DEPS="|| ( sys-fs/device-mapper >=sys-fs/lvm2-2.02.33 )"
+
+RDEPEND="
+	>=app-shells/bash-4.0
+	>=app-shells/dash-0.5.4.11
+	>=sys-apps/module-init-tools-3.5
+	>=sys-apps/sysvinit-2.87-r3
+	>=sys-apps/util-linux-2.16
+	>=sys-fs/udev-149
+	btrfs? ( sys-fs/btrfs-progs )
+	crypt? ( sys-fs/cryptsetup ${DM_DEPS} )
+	debug? ( dev-util/strace )
+	dmraid? ( sys-fs/dmraid sys-fs/multipath-tools ${DM_DEPS} )
+	dmsquash-live? ( sys-apps/eject ${DM_DEPS} )
+	iscsi? ( sys-block/open-iscsi[utils] ${NETWORK_DEPS} )
+	lvm? ( >=sys-fs/lvm2-2.02.33 )
+	mdraid? ( sys-fs/mdadm )
+	multipath? ( sys-fs/multipath-tools )
+	nbd? ( sys-block/nbd ${NETWORK_DEPS} )
+	nfs? ( net-fs/nfs-utils net-nds/rpcbind ${NETWORK_DEPS} )
+	selinux? ( sys-libs/libselinux sys-libs/libsepol )
+	syslog? ( || ( app-admin/syslog-ng app-admin/rsyslog ) )
+	uswsusp? ( sys-power/suspend )
+	xen? ( app-emulation/xen )
+	"
+DEPEND="${RDEPEND}"
+
+#
+# Helper functions
+#
+
+# Returns true if any of specified modules is enabled by USE flag and false
+# otherwise.
+# $1 = list of modules (which have corresponding USE flags of the same name)
+any_module() {
+	local m modules=" $@ "
+
+	for m in ${modules}; do
+		! use $m && modules=${modules/ $m / }
+	done
+
+	shopt -s extglob
+	modules=${modules%%+( )}
+	shopt -u extglob
+
+	[[ ${modules} ]]
+}
+
+# Removes module from modules.d.
+# $1 = module name
+# Module name can be specified without number prefix.
+rm_module() {
+	local m
+
+	for m in $@; do
+		if [[ $m =~ ^[0-9][0-9][^\ ]*$ ]]; then
+			rm -rf "${modules_dir}"/$m
+		else
+			rm -rf "${modules_dir}"/[0-9][0-9]$m
+		fi
+	done
+}
+
+#
+# ebuild functions
+#
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-dhcp6.patch"
+	epatch "${FILESDIR}/${P}-lc-all-c.patch"
+	epatch "${FILESDIR}/${P}-dm-udev-rules.patch"
+	epatch "${FILESDIR}/${P}-console_init-not-necessary.patch"
+}
+
+src_compile() {
+	emake WITH_SWITCH_ROOT=0 prefix=/usr sysconfdir=/etc || die "emake failed"
+}
+
+src_install() {
+	emake WITH_SWITCH_ROOT=0 \
+		prefix=/usr sysconfdir=/etc \
+		DESTDIR="${D}" install || die "emake install failed"
+
+	dodir /boot/dracut /var/lib/dracut/overlay
+	dodoc HACKING TODO AUTHORS NEWS README*
+
+	#
+	# Modules
+	#
+	local module
+	modules_dir="${D}/usr/share/dracut/modules.d"
+
+	echo "${PF}" > "${modules_dir}"/10rpmversion/dracut-version
+
+	# Disable modules not enabled by USE flags
+	for module in ${IUSE} ; do
+		! use ${module} && rm_module ${module}
+	done
+
+	! any_module ${DM_IUSE} && rm_module 90dm
+	! any_module ${NETWORK_IUSE} && rm_module 45ifcfg 40network
+
+	# Disable S/390 modules which are not tested at all
+	rm_module 95dasd 95dasd_mod 95zfcp 95znet
+
+	# Disable modules which won't work for sure
+	rm_module 01fips 10redhat-i18n 95fcoe
+}
+
+pkg_postinst() {
+	elog 'To generate the initramfs:'
+	elog ' # mount /boot (if necessary)'
+	elog ' # dracut "" <kernel-version>'
+	elog ''
+	elog 'For command line documentation, see:'
+	elog 'http://sourceforge.net/apps/trac/dracut/wiki/commandline'
+	elog ''
+	elog 'Simple example to select root and resume partition:'
+	elog ' root=/dev/???? resume=/dev/????'
+	elog ''
+	elog 'Configuration is in /etc/dracut.conf.'
+	elog 'The default config is very minimal and is highly recommended you'
+	elog 'adjust based on your needs. To include only drivers for this system,'
+	elog 'use the "-H" option.'
+
+	echo
+	ewarn 'dhcp-3 is known to not work with QEMU. You will need dhcp-4 or'
+	ewarn 'later for it.'
+}
diff --git a/sys-kernel/dracut/dracut-007.ebuild b/sys-kernel/dracut/dracut-007.ebuild
new file mode 100644
index 000000000000..8cc69ca1d5d6
--- /dev/null
+++ b/sys-kernel/dracut/dracut-007.ebuild
@@ -0,0 +1,189 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-007.ebuild,v 1.1 2010/08/17 18:23:40 ramereth Exp $
+
+EAPI=2
+
+inherit eutils mount-boot
+
+DESCRIPTION="Generic initramfs generation tool"
+HOMEPAGE="http://sourceforge.net/projects/dracut/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+COMMON_IUSE="bootchart btrfs debug gensplash lvm mdraid multipath selinux
+syslog uswsusp xen"
+NETWORK_IUSE="iscsi nbd nfs"
+DM_IUSE="crypt dmraid dmsquash-live"
+IUSE="${COMMON_IUSE} ${DM_IUSE} ${NETWORK_IUSE}"
+
+NETWORK_DEPS="net-misc/bridge-utils >=net-misc/dhcp-3.1.2_p1 sys-apps/iproute2"
+DM_DEPS="|| ( sys-fs/device-mapper >=sys-fs/lvm2-2.02.33 )"
+
+RDEPEND="
+	>=app-shells/bash-4.0
+	>=app-shells/dash-0.5.4.11
+	>=sys-apps/module-init-tools-3.5
+	>=sys-apps/sysvinit-2.87-r3
+	>=sys-apps/util-linux-2.16
+	>=sys-fs/udev-149
+
+	bootchart? ( app-benchmarks/bootchart )
+	btrfs? ( sys-fs/btrfs-progs )
+	crypt? ( sys-fs/cryptsetup ${DM_DEPS} )
+	debug? ( dev-util/strace )
+	dmraid? ( sys-fs/dmraid sys-fs/multipath-tools ${DM_DEPS} )
+	dmsquash-live? ( sys-apps/eject ${DM_DEPS} )
+	gensplash? ( media-gfx/splashutils )
+	iscsi? ( sys-block/open-iscsi[utils] ${NETWORK_DEPS} )
+	lvm? ( >=sys-fs/lvm2-2.02.33 )
+	mdraid? ( sys-fs/mdadm )
+	multipath? ( sys-fs/multipath-tools )
+	nbd? ( sys-block/nbd ${NETWORK_DEPS} )
+	nfs? ( net-fs/nfs-utils net-nds/rpcbind ${NETWORK_DEPS} )
+	selinux? ( sys-libs/libselinux sys-libs/libsepol )
+	syslog? ( || ( app-admin/syslog-ng app-admin/rsyslog ) )
+	uswsusp? ( sys-power/suspend )
+	xen? ( app-emulation/xen )
+	"
+DEPEND="
+	>=dev-libs/libxslt-1.1.26
+	app-text/docbook-xml-dtd:4.5
+	>=app-text/docbook-xsl-stylesheets-1.75.2
+	"
+
+#
+# Helper functions
+#
+
+# Returns true if any of specified modules is enabled by USE flag and false
+# otherwise.
+# $1 = list of modules (which have corresponding USE flags of the same name)
+any_module() {
+	local m modules=" $@ "
+
+	for m in ${modules}; do
+		! use $m && modules=${modules/ $m / }
+	done
+
+	shopt -s extglob
+	modules=${modules%%+( )}
+	shopt -u extglob
+
+	[[ ${modules} ]]
+}
+
+# Removes module from modules.d.
+# $1 = module name
+# Module name can be specified without number prefix.
+rm_module() {
+	local m
+
+	for m in $@; do
+		if [[ $m =~ ^[0-9][0-9][^\ ]*$ ]]; then
+			rm -rf "${modules_dir}"/$m
+		else
+			rm -rf "${modules_dir}"/[0-9][0-9]$m
+		fi
+	done
+}
+
+# Displays Gentoo Base System major release number
+base_sys_maj_ver() {
+	local line
+
+	read line < /etc/gentoo-release
+	line=${line##* }
+	echo "${line%%.*}"
+}
+
+#
+# ebuild functions
+#
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-multipath-udev-rules.patch"
+	epatch "${FILESDIR}/${P}-dm-udev-rules.patch"
+}
+
+src_compile() {
+	emake WITH_SWITCH_ROOT=0 prefix=/usr sysconfdir=/etc || die "emake failed"
+}
+
+src_install() {
+	emake WITH_SWITCH_ROOT=0 \
+		prefix=/usr sysconfdir=/etc \
+		DESTDIR="${D}" install || die "emake install failed"
+
+	local gen2conf
+
+	dodir /boot/dracut /var/lib/dracut/overlay /etc/dracut.conf.d
+	dodoc HACKING TODO AUTHORS NEWS README*
+
+	case "$(base_sys_maj_ver)" in
+		1) gen2conf=gentoo.conf ;;
+		2) gen2conf=gentoo-openrc.conf ;;
+		*) die "Expected ver. 1 or 2 of Gentoo Base System (/etc/gentoo-release)."
+	esac
+
+	insinto /etc/dracut.conf.d
+	newins dracut.conf.d/${gen2conf}.example ${gen2conf}
+
+	#
+	# Modules
+	#
+	local module
+	modules_dir="${D}/usr/share/dracut/modules.d"
+
+	echo "${PF}" > "${modules_dir}"/10rpmversion/dracut-version
+
+	# Disable modules not enabled by USE flags
+	for module in ${IUSE} ; do
+		! use ${module} && rm_module ${module}
+	done
+
+	! any_module ${DM_IUSE} && rm_module 90dm
+	! any_module ${NETWORK_IUSE} && rm_module 45ifcfg 40network
+
+	# Disable S/390 modules which are not tested at all
+	rm_module 95dasd 95dasd_mod 95zfcp 95znet
+
+	# Disable modules which won't work for sure
+	rm_module 95fcoe # no tools
+
+	# fips module depends on masked app-crypt/hmaccalc
+	rm_module 01fips
+}
+
+pkg_postinst() {
+	elog 'To generate the initramfs:'
+	elog '    # mount /boot (if necessary)'
+	elog '    # dracut "" <kernel-version>'
+	elog ''
+	elog 'For command line documentation see man 7 dracut.kernel.'
+	elog ''
+	elog 'Simple example to select root and resume partition:'
+	elog '    root=/dev/sda1 resume=/dev/sda2'
+	elog ''
+	elog 'The default config (in /etc/dracut.conf) is very minimal and is highly'
+	elog 'recommended you adjust based on your needs. To include only dracut'
+	elog 'modules and kernel drivers for this system, use the "-H" option.'
+	elog 'Some modules need to be explicitly added with "-a" option even if'
+	elog 'required tools are installed.'
+
+	[[ $(base_sys_maj_ver) = 1 ]] && {
+		echo
+		ewarn 'You might encounter following problem during boot time when using'
+		ewarn 'baselayout1:'
+		ewarn '    devpts is already mounted or /dev/pts is busy'
+		ewarn 'See discussion on the Gentoo Forums:'
+		ewarn 'http://forums.gentoo.org/viewtopic-p-6377431.html'
+	}
+
+	echo
+	ewarn 'dhcp-3 is known to not work with QEMU. You will need dhcp-4 or'
+	ewarn 'later for it.'
+}
diff --git a/sys-kernel/dracut/files/dracut-006-console_init-not-necessary.patch b/sys-kernel/dracut/files/dracut-006-console_init-not-necessary.patch
new file mode 100644
index 000000000000..c7221cb42b50
--- /dev/null
+++ b/sys-kernel/dracut/files/dracut-006-console_init-not-necessary.patch
@@ -0,0 +1,26 @@
+From 9d6ec99daf852a429262c46639558823bf937eab Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Amadeusz=20=C5=BBo=C5=82nowski?= <aidecoe@aidecoe.name>
+Date: Sat, 10 Jul 2010 22:54:59 +0200
+Subject: [PATCH] 50plymouth: calling console_init isn't necessary
+
+---
+ modules.d/50plymouth/plymouth-pretrigger.sh |    3 ++-
+ 1 files changed, 2 insertions(+), 1 deletions(-)
+
+diff --git a/modules.d/50plymouth/plymouth-pretrigger.sh b/modules.d/50plymouth/plymouth-pretrigger.sh
+index 8605c61..6bf7f2a 100755
+--- a/modules.d/50plymouth/plymouth-pretrigger.sh
++++ b/modules.d/50plymouth/plymouth-pretrigger.sh
+@@ -15,7 +15,8 @@ if ! getarg rd_NO_PLYMOUTH; then
+ 
+     info "Starting plymouth daemon"
+     [ -x /bin/plymouthd ] && /bin/plymouthd --attach-to-session
+-    /lib/udev/console_init tty0
++    # Workaround for 006.  To be restored in next release.
++    #/lib/udev/console_init tty0
+     /bin/plymouth --show-splash 2>&1 | vinfo
+ fi
+ 
+-- 
+1.7.1
+
diff --git a/sys-kernel/dracut/files/dracut-006-dm-udev-rules.patch b/sys-kernel/dracut/files/dracut-006-dm-udev-rules.patch
new file mode 100644
index 000000000000..5924fdeee1b8
--- /dev/null
+++ b/sys-kernel/dracut/files/dracut-006-dm-udev-rules.patch
@@ -0,0 +1,60 @@
+From 4cd3f9d7e4b8da2cfd5c8b5c4126fe6bd867d56e Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Amadeusz=20=C5=BBo=C5=82nowski?= <aidecoe@aidecoe.name>
+Date: Sun, 4 Jul 2010 21:21:29 +0200
+Subject: [PATCH 16/41] dm, dmraid, lvm: install udev rules file 64-device-mapper.rules
+
+Gentoo ebuild for LVM2 prior to 2.02.63-r1 doesn't install rules:
+  10-dm.rules
+  11-dm-lvm.rules
+  13-dm-disk.rules
+  95-dm-notify.rules
+but provides only 64-device-mapper.rules combining more or less the
+above rules files.
+---
+ modules.d/90dm/install     |    3 +++
+ modules.d/90dmraid/install |    3 +++
+ modules.d/90lvm/install    |    3 +++
+ 3 files changed, 9 insertions(+), 0 deletions(-)
+
+diff --git a/modules.d/90dm/install b/modules.d/90dm/install
+index f77d945..0bc9ced 100755
+--- a/modules.d/90dm/install
++++ b/modules.d/90dm/install
+@@ -7,3 +7,6 @@ inst dmsetup
+ 
+ inst dmeventd
+ inst_rules 10-dm.rules 95-dm-notify.rules
++# Gentoo ebuild for LVM2 prior to 2.02.63-r1 doesn't install above rules
++# files, but provides the one below:
++inst_rules 64-device-mapper.rules
+diff --git a/modules.d/90dmraid/install b/modules.d/90dmraid/install
+index a016e4d..81c63f0 100755
+--- a/modules.d/90dmraid/install
++++ b/modules.d/90dmraid/install
+@@ -15,6 +15,9 @@ done
+ 
+ 
+ inst_rules 10-dm.rules 13-dm-disk.rules 95-dm-notify.rules 
++# Gentoo ebuild for LVM2 prior to 2.02.63-r1 doesn't install above rules
++# files, but provides the one below:
++inst_rules 64-device-mapper.rules
+ 
+ inst "$moddir/dmraid.sh" /sbin/dmraid_scan
+ 
+diff --git a/modules.d/90lvm/install b/modules.d/90lvm/install
+index 0813486..a189a20 100755
+--- a/modules.d/90lvm/install
++++ b/modules.d/90lvm/install
+@@ -13,6 +13,9 @@ if [[ $hostonly ]] || [[ $lvmconf = "yes" ]]; then
+ fi
+ 
+ inst_rules 10-dm.rules 13-dm-disk.rules 95-dm-notify.rules 11-dm-lvm.rules
++# Gentoo ebuild for LVM2 prior to 2.02.63-r1 doesn't install above rules
++# files, but provides the one below:
++inst_rules 64-device-mapper.rules
+ 
+ inst "$moddir/lvm_scan.sh" /sbin/lvm_scan
+ inst_hook cmdline 30 "$moddir/parse-lvm.sh"
+-- 
+1.7.1
+
diff --git a/sys-kernel/dracut/files/dracut-007-dm-udev-rules.patch b/sys-kernel/dracut/files/dracut-007-dm-udev-rules.patch
new file mode 100644
index 000000000000..a9611d2b6268
--- /dev/null
+++ b/sys-kernel/dracut/files/dracut-007-dm-udev-rules.patch
@@ -0,0 +1,60 @@
+From 374c91e07c0996d5aacb25ba71b3aa1fcf83afec Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Amadeusz=20=C5=BBo=C5=82nowski?= <aidecoe@aidecoe.name>
+Date: Sun, 4 Jul 2010 21:21:29 +0200
+Subject: [PATCH 2/2] dm, dmraid, lvm: install udev rules file 64-device-mapper.rules
+
+Gentoo ebuild for LVM2 prior to 2.02.63-r1 doesn't install rules:
+  10-dm.rules
+  11-dm-lvm.rules
+  13-dm-disk.rules
+  95-dm-notify.rules
+but provides only 64-device-mapper.rules combining more or less the
+above rules files.
+---
+ modules.d/90dm/install     |    3 +++
+ modules.d/90dmraid/install |    3 +++
+ modules.d/90lvm/install    |    3 +++
+ 3 files changed, 9 insertions(+), 0 deletions(-)
+
+diff --git a/modules.d/90dm/install b/modules.d/90dm/install
+index f77d945..0bc9ced 100755
+--- a/modules.d/90dm/install
++++ b/modules.d/90dm/install
+@@ -7,3 +7,6 @@ inst dmsetup
+ 
+ inst dmeventd
+ inst_rules 10-dm.rules 95-dm-notify.rules
++# Gentoo ebuild for LVM2 prior to 2.02.63-r1 doesn't install above rules
++# files, but provides the one below:
++inst_rules 64-device-mapper.rules
+diff --git a/modules.d/90dmraid/install b/modules.d/90dmraid/install
+index a016e4d..81c63f0 100755
+--- a/modules.d/90dmraid/install
++++ b/modules.d/90dmraid/install
+@@ -15,6 +15,9 @@ done
+ 
+ 
+ inst_rules 10-dm.rules 13-dm-disk.rules 95-dm-notify.rules 
++# Gentoo ebuild for LVM2 prior to 2.02.63-r1 doesn't install above rules
++# files, but provides the one below:
++inst_rules 64-device-mapper.rules
+ 
+ inst "$moddir/dmraid.sh" /sbin/dmraid_scan
+ 
+diff --git a/modules.d/90lvm/install b/modules.d/90lvm/install
+index 3e20866..461d1a7 100755
+--- a/modules.d/90lvm/install
++++ b/modules.d/90lvm/install
+@@ -13,6 +13,9 @@ if [[ $hostonly ]] || [[ $lvmconf = "yes" ]]; then
+ fi
+ 
+ inst_rules 10-dm.rules 13-dm-disk.rules 95-dm-notify.rules 11-dm-lvm.rules
++# Gentoo ebuild for LVM2 prior to 2.02.63-r1 doesn't install above rules
++# files, but provides the one below:
++inst_rules 64-device-mapper.rules
+ 
+ inst "$moddir/lvm_scan.sh" /sbin/lvm_scan
+ inst_hook cmdline 30 "$moddir/parse-lvm.sh"
+-- 
+1.7.2
+
diff --git a/sys-kernel/dracut/files/dracut-007-multipath-udev-rules.patch b/sys-kernel/dracut/files/dracut-007-multipath-udev-rules.patch
new file mode 100644
index 000000000000..601569cbe683
--- /dev/null
+++ b/sys-kernel/dracut/files/dracut-007-multipath-udev-rules.patch
@@ -0,0 +1,46 @@
+From 303a1e3dc95c2c876a4e775e78482c35c0a40e20 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Amadeusz=20=C5=BBo=C5=82nowski?= <aidecoe@aidecoe.name>
+Date: Mon, 5 Jul 2010 13:09:32 +0200
+Subject: [PATCH 1/2] 90multipath: added kpartx.rules; multipath.rules - different prefix
+
+---
+ modules.d/90multipath/install |   13 ++++++-------
+ 1 files changed, 6 insertions(+), 7 deletions(-)
+
+diff --git a/modules.d/90multipath/install b/modules.d/90multipath/install
+index ed2d698..656b3fd 100755
+--- a/modules.d/90multipath/install
++++ b/modules.d/90multipath/install
+@@ -6,23 +6,22 @@ else
+     LIBDIR="/lib"
+ fi
+ 
++# Last three are for S/390
+ for f in  \
+     /sbin/dmsetup \
+     /sbin/kpartx \
+     /sbin/mpath_wait \
+     /sbin/multipath  \
+     /sbin/multipathd \
+-    /sbin/xdrgetuid \
+-    /sbin/xdrgetprio \
+-    /etc/xdrdevices.conf \
+     /etc/multipath.conf \
+     /etc/multipath/wwids \
+     $(ls $LIBDIR/libmultipath* $LIBDIR/multipath/* 2>/dev/null) \
+-    	;do
+-    [ -e "$f" ] && inst "$f"
++    /sbin/xdrgetuid \
++    /sbin/xdrgetprio \
++    /etc/xdrdevices.conf; do
++        [ -e "$f" ] && inst "$f"
+ done
+ 
+ inst_hook pre-trigger 02 "$moddir/multipathd.sh"
+ inst_hook pre-pivot   02 "$moddir/multipathd-stop.sh"
+-inst_rules 40-multipath.rules
+-
++inst_rules 40-multipath.rules 65-multipath.rules 66-kpartx.rules
+-- 
+1.7.2
+
diff --git a/sys-kernel/dracut/metadata.xml b/sys-kernel/dracut/metadata.xml
index 7146516448d6..5f8c052cc055 100644
--- a/sys-kernel/dracut/metadata.xml
+++ b/sys-kernel/dracut/metadata.xml
@@ -7,18 +7,22 @@
 		<name>Lance Albertson</name>
 	</maintainer>
 	<use>
-		<flag name="dmraid">Add support for dmraid devices, also known as
-		ATA-RAID, or Fake RAID.</flag>
-		<flag name="iscsi">Add support for iSCSI</flag>
-		<flag name="lvm">Add support for the Logical Volume Manager
-		sys-apps/lvm2</flag>
-		<flag name="nbd">Add support for network block devices</flag>
-		<flag name="nfs">Add support for NFS</flag>
-		<flag name="md">Add support for MD devices, also known as software raid devices</flag>
-		<flag name="btrfs">Add support for btrfs</flag>
-		<flag name="multipath">Add support for multipath</flag>
-		<flag name="uswsusp">Add support for userspace software suspend</flag>
-		<flag name="xen">Add support for Xen</flag>
+        <flag name="bootchart">Add support for bootchart (app-benchmarks/bootchart)</flag>
+        <flag name="btrfs">Add support for root on Btrfs</flag>
+        <flag name="crypt">Add support for encrypted partitions with cryptsetup/LUKS</flag>
+        <flag name="debug">Module installing additional tools like strace, file editor, ssh and more</flag>
+        <flag name="dmraid">Add support for dmraid devices, also known as ATA-RAID, or Fake RAID.</flag>
+        <flag name="dmsquash-live">Module which might be used for Live CDs</flag>
+        <flag name="gensplash">Add support for framebuffer splash at boot-time</flag>
+        <flag name="iscsi">Add support for iSCSI</flag>
+        <flag name="lvm">Add support for the Logical Volume Manager (sys-apps/lvm2)</flag>
+        <flag name="md">Add support for MD devices, also known as software RAID devices</flag>
+        <flag name="mdraid">Add support for MD devices, also known as software RAID devices</flag>
+        <flag name="multipath">Add support for Device Mapper multipathing</flag>
+        <flag name="nbd">Add support for network block devices</flag>
+        <flag name="nfs">Add support for NFS</flag>
+        <flag name="uswsusp">Add support for uswsusp (sys-power/suspend)</flag>
+        <flag name="xen">Add support for Xen</flag>
 	</use>
 	<longdescription lang="en">
 	Generic, modular initramfs generation tool that can be used across various