Version bump.

Package-Manager: portage-2.2.0_alpha101/cvs/Linux x86_64

12 files changed, 328 insertions, 6 deletions

diff --git a/xfce-base/thunar/ChangeLog b/xfce-base/thunar/ChangeLog
index 60a8b942e40d..c8690529de1c 100644
--- a/xfce-base/thunar/ChangeLog
+++ b/xfce-base/thunar/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for xfce-base/thunar
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/ChangeLog,v 1.139 2012/04/21 11:06:37 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/ChangeLog,v 1.140 2012/04/29 10:13:48 ssuominen Exp $
+
+*thunar-1.4.0 (29 Apr 2012)
+
+  29 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> +thunar-1.4.0.ebuild:
+  Version bump.
 
   21 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> thunar-1.3.2.ebuild:
   Force recent enough desktop-file-utils to validate XFCE in Categories.
diff --git a/xfce-base/thunar/thunar-1.4.0.ebuild b/xfce-base/thunar/thunar-1.4.0.ebuild
new file mode 100644
index 000000000000..c8e35e52a1b1
--- /dev/null
+++ b/xfce-base/thunar/thunar-1.4.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/thunar-1.4.0.ebuild,v 1.1 2012/04/29 10:13:48 ssuominen Exp $
+
+EAPI=4
+inherit virtualx xfconf
+
+MY_P=${P/t/T}
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/ http://thunar.xfce.org/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbus debug exif libnotify pcre startup-notification test +xfce_plugins_trash udev"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.10.1"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.24
+	>=x11-libs/gtk+-2.20:2
+	>=xfce-base/exo-0.8
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/libxfce4util-4.10
+	dbus? ( >=dev-libs/dbus-glib-0.98 )
+	exif? ( >=media-libs/libexif-0.6.19 )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	pcre? ( >=dev-libs/libpcre-6 )
+	startup-notification? ( x11-libs/startup-notification )
+	udev? ( || ( >=sys-fs/udev-171-r5[gudev] <sys-fs/udev-171[extras] ) )
+	xfce_plugins_trash? ( >=xfce-base/xfce4-panel-4.10 )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	dbus? ( ${GVFS_DEPEND} )
+	udev? ( ${GVFS_DEPEND}[gdu,udev] )
+	xfce_plugins_trash? ( ${GVFS_DEPEND} )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	sys-devel/gettext"
+REQUIRED_USE="xfce_plugins_trash? ( dbus )"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable dbus)
+		$(use_enable startup-notification)
+		$(use_enable udev gudev)
+		$(use_enable libnotify notifications)
+		$(xfconf_use_debug)
+		$(use_enable exif)
+		$(use_enable pcre)
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	use xfce_plugins_trash || XFCONF+=( --disable-tpa-plugin )
+
+	DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+}
+
+src_test() {
+	Xemake check
+}
diff --git a/xfce-base/xfce4-appfinder/ChangeLog b/xfce-base/xfce4-appfinder/ChangeLog
index 6690db3f5256..f8a373b272d3 100644
--- a/xfce-base/xfce4-appfinder/ChangeLog
+++ b/xfce-base/xfce4-appfinder/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/xfce4-appfinder
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-appfinder/ChangeLog,v 1.3 2012/04/20 20:23:17 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-appfinder/ChangeLog,v 1.4 2012/04/29 10:18:27 ssuominen Exp $
+
+*xfce4-appfinder-4.10.0 (29 Apr 2012)
+
+  29 Apr 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +xfce4-appfinder-4.10.0.ebuild:
+  Version bump.
 
   20 Apr 2012; Samuli Suominen <ssuominen@gentoo.org>
   -xfce4-appfinder-4.9.4.ebuild:
diff --git a/xfce-base/xfce4-appfinder/xfce4-appfinder-4.10.0.ebuild b/xfce-base/xfce4-appfinder/xfce4-appfinder-4.10.0.ebuild
new file mode 100644
index 000000000000..4375b7dbd811
--- /dev/null
+++ b/xfce-base/xfce4-appfinder/xfce4-appfinder-4.10.0.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-appfinder/xfce4-appfinder-4.10.0.ebuild,v 1.1 2012/04/29 10:18:27 ssuominen Exp $
+
+EAPI=4
+inherit xfconf
+
+DESCRIPTION="A tool to find and launch installed applications for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug"
+
+RDEPEND=">=dev-libs/dbus-glib-0.98
+	>=dev-libs/glib-2.24
+	>=x11-libs/gtk+-2.20:2
+	>=xfce-base/garcon-0.2
+	>=xfce-base/libxfce4util-4.10
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/xfconf-4.10
+	!xfce-base/xfce-utils"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	sys-devel/gettext"
+
+pkg_setup() {
+	XFCONF=( $(xfconf_use_debug) )
+	DOCS=( AUTHORS ChangeLog NEWS )
+}
diff --git a/xfce-base/xfce4-meta/ChangeLog b/xfce-base/xfce4-meta/ChangeLog
index d0aec217a173..7b9d849f08c4 100644
--- a/xfce-base/xfce4-meta/ChangeLog
+++ b/xfce-base/xfce4-meta/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for xfce-base/xfce4-meta
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-meta/ChangeLog,v 1.31 2012/04/20 20:34:39 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-meta/ChangeLog,v 1.32 2012/04/29 10:26:19 ssuominen Exp $
+
+*xfce4-meta-4.10 (29 Apr 2012)
+
+  29 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> +xfce4-meta-4.10.ebuild:
+  Version bump.
 
   20 Apr 2012; Samuli Suominen <ssuominen@gentoo.org>
   xfce4-meta-4.10_pre.ebuild:
diff --git a/xfce-base/xfce4-meta/xfce4-meta-4.10.ebuild b/xfce-base/xfce4-meta/xfce4-meta-4.10.ebuild
new file mode 100644
index 000000000000..0800d794bf7b
--- /dev/null
+++ b/xfce-base/xfce4-meta/xfce4-meta-4.10.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-meta/xfce4-meta-4.10.ebuild,v 1.1 2012/04/29 10:26:19 ssuominen Exp $
+
+EAPI=4
+
+DESCRIPTION="The Xfce Desktop Environment (meta package)"
+HOMEPAGE="http://www.xfce.org/"
+SRC_URI=""
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux"
+IUSE="minimal +svg"
+
+RDEPEND=">=x11-themes/gtk-engines-xfce-3:0
+	x11-themes/hicolor-icon-theme
+	>=xfce-base/xfce4-appfinder-4.10
+	>=xfce-base/xfce4-panel-4.10
+	>=xfce-base/xfce4-session-4.10
+	>=xfce-base/xfce4-settings-4.10
+	>=xfce-base/xfdesktop-4.10
+	>=xfce-base/xfwm4-4.10
+	!minimal? (
+		media-fonts/dejavu
+		virtual/freedesktop-icon-theme
+		)
+	svg? ( gnome-base/librsvg )"
diff --git a/xfce-base/xfce4-session/ChangeLog b/xfce-base/xfce4-session/ChangeLog
index 3fb4e72961ce..6f9487c86c21 100644
--- a/xfce-base/xfce4-session/ChangeLog
+++ b/xfce-base/xfce4-session/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for xfce-base/xfce4-session
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.158 2012/04/20 20:19:04 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.159 2012/04/29 10:24:28 ssuominen Exp $
+
+*xfce4-session-4.10.0 (29 Apr 2012)
+
+  29 Apr 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +xfce4-session-4.10.0.ebuild:
+  Version bump.
 
   20 Apr 2012; Samuli Suominen <ssuominen@gentoo.org>
   -xfce4-session-4.8.3.ebuild, -xfce4-session-4.9.0-r1.ebuild,
diff --git a/xfce-base/xfce4-session/xfce4-session-4.10.0.ebuild b/xfce-base/xfce4-session/xfce4-session-4.10.0.ebuild
new file mode 100644
index 000000000000..26db603d7696
--- /dev/null
+++ b/xfce-base/xfce4-session/xfce4-session-4.10.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/xfce4-session-4.10.0.ebuild,v 1.1 2012/04/29 10:24:28 ssuominen Exp $
+
+EAPI=4
+inherit xfconf
+
+DESCRIPTION="A session manager for the Xfce desktop environment"
+HOMEPAGE="http://docs.xfce.org/xfce/xfce4-session/start"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="consolekit debug gnome-keyring policykit udev +xscreensaver"
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.98
+	x11-apps/iceauth
+	x11-libs/libSM
+	>=x11-libs/libwnck-2.30:1
+	x11-libs/libX11
+	>=xfce-base/libxfce4util-4.10
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/xfconf-4.10
+	gnome-keyring? ( >=gnome-base/libgnome-keyring-2.22 )
+	!xfce-base/xfce-utils"
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xrdb
+	x11-misc/xdg-user-dirs
+	consolekit? ( || ( sys-auth/consolekit >=sys-apps/systemd-40 ) )
+	policykit? ( >=sys-auth/polkit-0.104-r1 )
+	udev? ( >=sys-power/upower-0.9.15 )
+	xscreensaver? ( || (
+		>=x11-misc/xscreensaver-5.15
+		gnome-extra/gnome-screensaver
+		>=x11-misc/xlockmore-5.38
+		>=x11-misc/slock-1
+		) )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	sys-devel/gettext"
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable gnome-keyring libgnome-keyring)
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS BUGS ChangeLog NEWS README TODO )
+}
+
+src_install() {
+	xfconf_src_install
+
+	local sessiondir=/etc/X11/Sessions
+	echo startxfce4 > "${T}"/Xfce4
+	exeinto ${sessiondir}
+	doexe "${T}"/Xfce4
+	dosym Xfce4 ${sessiondir}/Xfce
+}
diff --git a/xfce-base/xfdesktop/ChangeLog b/xfce-base/xfdesktop/ChangeLog
index 83d1493b47fe..eaf54f7b5f2f 100644
--- a/xfce-base/xfdesktop/ChangeLog
+++ b/xfce-base/xfdesktop/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for xfce-base/xfdesktop
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfdesktop/ChangeLog,v 1.212 2012/04/22 18:34:57 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfdesktop/ChangeLog,v 1.213 2012/04/29 10:16:24 ssuominen Exp $
+
+*xfdesktop-4.10.0 (29 Apr 2012)
+
+  29 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> +xfdesktop-4.10.0.ebuild:
+  Version bump.
 
   22 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> -xfdesktop-4.8.1.ebuild:
   old
diff --git a/xfce-base/xfdesktop/xfdesktop-4.10.0.ebuild b/xfce-base/xfdesktop/xfdesktop-4.10.0.ebuild
new file mode 100644
index 000000000000..03955cd2cf0e
--- /dev/null
+++ b/xfce-base/xfdesktop/xfdesktop-4.10.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfdesktop/xfdesktop-4.10.0.ebuild,v 1.1 2012/04/29 10:16:24 ssuominen Exp $
+
+EAPI=4
+inherit xfconf
+
+DESCRIPTION="Desktop manager for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug libnotify thunar"
+
+RDEPEND=">=dev-libs/glib-2.20
+	>=x11-libs/gtk+-2.24:2
+	x11-libs/libSM
+	>=x11-libs/libwnck-2.30:1
+	x11-libs/libX11
+	>=xfce-base/exo-0.8
+	>=xfce-base/garcon-0.2
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/libxfce4util-4.10
+	>=xfce-base/xfconf-4.10
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	thunar? (
+		>=xfce-base/thunar-1.4[dbus]
+		>=dev-libs/dbus-glib-0.98
+		)"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	sys-devel/gettext"
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable thunar file-icons)
+		$(use_enable thunar thunarx)
+		$(use_enable libnotify notifications)
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS ChangeLog NEWS README TODO )
+}
diff --git a/xfce-base/xfwm4/ChangeLog b/xfce-base/xfwm4/ChangeLog
index 936b3b53eb8d..e62aa7663000 100644
--- a/xfce-base/xfwm4/ChangeLog
+++ b/xfce-base/xfwm4/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for xfce-base/xfwm4
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfwm4/ChangeLog,v 1.191 2012/04/22 18:35:12 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfwm4/ChangeLog,v 1.192 2012/04/29 10:20:54 ssuominen Exp $
+
+*xfwm4-4.10.0 (29 Apr 2012)
+
+  29 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> +xfwm4-4.10.0.ebuild:
+  Version bump.
 
   22 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> -xfwm4-4.8.2.ebuild:
   old
diff --git a/xfce-base/xfwm4/xfwm4-4.10.0.ebuild b/xfce-base/xfwm4/xfwm4-4.10.0.ebuild
new file mode 100644
index 000000000000..50b5dda3fcc3
--- /dev/null
+++ b/xfce-base/xfwm4/xfwm4-4.10.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfwm4/xfwm4-4.10.0.ebuild,v 1.1 2012/04/29 10:20:54 ssuominen Exp $
+
+EAPI=4
+inherit xfconf
+
+DESCRIPTION="Window manager for the Xfce desktop environment"
+HOMEPAGE="http://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug startup-notification +xcomposite"
+
+RDEPEND=">=dev-libs/glib-2.20
+	>=x11-libs/gtk+-2.24:2
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/pango
+	>=x11-libs/libwnck-2.30:1
+	>=xfce-base/libxfce4util-4.10
+	>=xfce-base/libxfce4ui-4.10
+	>=xfce-base/xfconf-4.10
+	startup-notification? ( x11-libs/startup-notification )
+	xcomposite? (
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXfixes
+		)"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	sys-devel/gettext"
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable startup-notification)
+		--enable-xsync
+		--enable-render
+		--enable-randr
+		$(use_enable xcomposite compositor)
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS ChangeLog COMPOSITOR NEWS README TODO )
+}