From f64107b0737660884cc4a606025c4f34474e8bbb Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Tue, 13 May 2014 19:15:52 +0000
Subject: Enable multilib support, bug #499382.

Package-Manager: portage-2.2.10/cvs/Linux x86_64
Manifest-Sign-Key: 0xEFB4464E!
---
 dev-libs/libevent/libevent-2.1.4-r1.ebuild | 58 ++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-libs/libevent/libevent-2.1.4-r1.ebuild

(limited to 'dev-libs/libevent/libevent-2.1.4-r1.ebuild')

diff --git a/dev-libs/libevent/libevent-2.1.4-r1.ebuild b/dev-libs/libevent/libevent-2.1.4-r1.ebuild
new file mode 100644
index 000000000000..78d0daa11049
--- /dev/null
+++ b/dev-libs/libevent/libevent-2.1.4-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libevent/libevent-2.1.4-r1.ebuild,v 1.1 2014/05/13 19:15:50 mgorny Exp $
+
+EAPI=5
+inherit eutils libtool multilib-minimal
+
+MY_P="${P}-alpha"
+
+DESCRIPTION="A library to execute a function when a specific event occurs on a file descriptor"
+HOMEPAGE="http://libevent.org/"
+SRC_URI="mirror://sourceforge/levent/files/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS=""
+IUSE="+ssl static-libs test"
+
+DEPEND="ssl? ( dev-libs/openssl[${MULTILIB_USEDEP}] )"
+RDEPEND="
+	${DEPEND}
+	!<=dev-libs/9libs-1.0
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/event2/event-config.h
+)
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	elibtoolize
+	sed -i -e '/^all:/s|tests||g' Makefile.nmake || die
+}
+
+multilib_src_configure() {
+	# fix out-of-source builds
+	mkdir -p test || die
+
+	ECONF_SOURCE="${S}" \
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable ssl openssl)
+}
+
+src_test() {
+	# The test suite doesn't quite work (see bug #406801 for the latest
+	# installment in a riveting series of reports).
+	:
+	# emake -C test check | tee "${T}"/tests
+}
+
+DOCS=( ChangeLog{,-1.4,-2.0} )
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}
-- 
cgit v1.2.3-65-gdbad