From f74ea242bd2da1ffd5edfd01730528547b0422fd Mon Sep 17 00:00:00 2001
From: Christopher Byrne <salah.coronya@gmail.com>
Date: Sat, 23 Apr 2022 14:34:18 -0500
Subject: app-crypt/tpm2-tools: Add sublot operator to app-crypt/tpm2-tss dep

Signed-off-by: Christopher Byrne <salah.coronya@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>
---
 app-crypt/tpm2-tools/tpm2-tools-5.2-r1.ebuild | 68 +++++++++++++++++++++++++++
 app-crypt/tpm2-tools/tpm2-tools-5.2.ebuild    | 68 ---------------------------
 2 files changed, 68 insertions(+), 68 deletions(-)
 create mode 100644 app-crypt/tpm2-tools/tpm2-tools-5.2-r1.ebuild
 delete mode 100644 app-crypt/tpm2-tools/tpm2-tools-5.2.ebuild

(limited to 'app-crypt/tpm2-tools')

diff --git a/app-crypt/tpm2-tools/tpm2-tools-5.2-r1.ebuild b/app-crypt/tpm2-tools/tpm2-tools-5.2-r1.ebuild
new file mode 100644
index 000000000000..5b29e8bbade6
--- /dev/null
+++ b/app-crypt/tpm2-tools/tpm2-tools-5.2-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit autotools bash-completion-r1 python-single-r1
+
+DESCRIPTION="Tools for the TPM 2.0 TSS"
+HOMEPAGE="https://github.com/tpm2-software/tpm2-tools"
+SRC_URI="https://github.com/tpm2-software/tpm2-tools/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="+fapi test"
+
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND=">=app-crypt/tpm2-tss-3.0.1:=[fapi?]
+	dev-libs/openssl:=
+	net-misc/curl
+	sys-libs/efivar:=
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	test? (
+		app-crypt/swtpm
+		app-crypt/tpm2-abrmd
+		dev-util/cmocka
+	)"
+BDEPEND="virtual/pkgconfig
+	sys-devel/autoconf-archive
+	test? (
+		app-editors/vim-core
+		dev-tcltk/expect
+		$(python_gen_cond_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	)
+	${PYTHON_DEPS}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.1.1-no-efivar-automagic.patch"
+	"${FILESDIR}/${PN}-5.2-testparms-fix-condition-for-negative-test.patch"
+)
+
+src_prepare() {
+	default
+	sed -i \
+	"s/m4_esyscmd_s(\[git describe --tags --always --dirty\])/${PV}/" \
+		"configure.ac" || die
+	"./scripts/utils/man_to_bashcompletion.sh" || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable fapi) \
+		$(use_enable test unit) \
+		--with-bashcompdir=$(get_bashcompdir) \
+		--enable-hardening
+}
+
+src_install() {
+	default
+	mv "${ED}"/$(get_bashcompdir)/tpm2{_completion.bash,} || die
+	local utils=( "${ED}"/usr/bin/tpm2_* )
+	bashcomp_alias tpm2 "${utils[@]##*/}"
+}
diff --git a/app-crypt/tpm2-tools/tpm2-tools-5.2.ebuild b/app-crypt/tpm2-tools/tpm2-tools-5.2.ebuild
deleted file mode 100644
index 9b7629c2cc9a..000000000000
--- a/app-crypt/tpm2-tools/tpm2-tools-5.2.ebuild
+++ /dev/null
@@ -1,68 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} )
-inherit autotools bash-completion-r1 python-single-r1
-
-DESCRIPTION="Tools for the TPM 2.0 TSS"
-HOMEPAGE="https://github.com/tpm2-software/tpm2-tools"
-SRC_URI="https://github.com/tpm2-software/tpm2-tools/releases/download/${PV}/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
-IUSE="+fapi test"
-
-RESTRICT="!test? ( test )"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-RDEPEND=">=app-crypt/tpm2-tss-3.0.1[fapi?]
-	dev-libs/openssl:=
-	net-misc/curl
-	sys-libs/efivar:=
-	${PYTHON_DEPS}"
-DEPEND="${RDEPEND}
-	test? (
-		app-crypt/swtpm
-		app-crypt/tpm2-abrmd
-		dev-util/cmocka
-	)"
-BDEPEND="virtual/pkgconfig
-	sys-devel/autoconf-archive
-	test? (
-		app-editors/vim-core
-		dev-tcltk/expect
-		$(python_gen_cond_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
-	)
-	${PYTHON_DEPS}"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-5.1.1-no-efivar-automagic.patch"
-	"${FILESDIR}/${PN}-5.2-testparms-fix-condition-for-negative-test.patch"
-)
-
-src_prepare() {
-	default
-	sed -i \
-	"s/m4_esyscmd_s(\[git describe --tags --always --dirty\])/${PV}/" \
-		"configure.ac" || die
-	"./scripts/utils/man_to_bashcompletion.sh" || die
-	eautoreconf
-}
-
-src_configure() {
-	econf \
-		$(use_enable fapi) \
-		$(use_enable test unit) \
-		--with-bashcompdir=$(get_bashcompdir) \
-		--enable-hardening
-}
-
-src_install() {
-	default
-	mv "${ED}"/$(get_bashcompdir)/tpm2{_completion.bash,} || die
-	local utils=( "${ED}"/usr/bin/tpm2_* )
-	bashcomp_alias tpm2 "${utils[@]##*/}"
-}
-- 
cgit v1.2.3-65-gdbad