From 19b9ca7f6e13e223304ac84c7e24f03619b990d3 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sun, 4 Apr 2021 00:49:15 +0000
Subject: games-rpg/coe2: port to EAPI 7, games.eclass--

Signed-off-by: Sam James <sam@gentoo.org>
---
 games-rpg/coe2/coe2-2007-r1.ebuild | 55 ---------------------------------
 games-rpg/coe2/coe2-2007-r2.ebuild | 63 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+), 55 deletions(-)
 delete mode 100644 games-rpg/coe2/coe2-2007-r1.ebuild
 create mode 100644 games-rpg/coe2/coe2-2007-r2.ebuild

(limited to 'games-rpg')

diff --git a/games-rpg/coe2/coe2-2007-r1.ebuild b/games-rpg/coe2/coe2-2007-r1.ebuild
deleted file mode 100644
index 99a3f1b823f2..000000000000
--- a/games-rpg/coe2/coe2-2007-r1.ebuild
+++ /dev/null
@@ -1,55 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-inherit eutils games
-
-DESCRIPTION="Precursor to the Dominions series"
-HOMEPAGE="https://www.shrapnelgames.com/Our_Games/Free_Games.html"
-SRC_URI="https://download.shrapnelgames.com/downloads/${PN}_${PV}.zip"
-
-LICENSE="all-rights-reserved"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-RESTRICT="mirror bindist"
-
-RDEPEND="media-libs/libsdl[sound,video]"
-DEPEND="${RDEPEND}
-	app-arch/unzip"
-
-S=${WORKDIR}/coe
-
-# bug #430026
-QA_PREBUILT="${GAMES_PREFIX_OPT}/coe2/coe_linux"
-
-src_prepare() {
-	rm -r *.{dll,exe} old || die
-	if use amd64 ; then
-		mv -f coe_linux64bit coe_linux || die
-	fi
-}
-
-src_install() {
-	insinto "${GAMES_PREFIX_OPT}/${PN}"
-	doins *.{bgm,smp,trp,trs,wrl}
-	dodoc history.txt manual.txt readme.txt
-	exeinto "${GAMES_PREFIX_OPT}/${PN}"
-	doexe coe_linux
-
-	games_make_wrapper ${PN} "./coe_linux" "${GAMES_PREFIX_OPT}/${PN}"
-	make_desktop_entry ${PN} "Conquest of Elysium 2"
-
-	# Slots for saved games.
-	# The game shows e.g. "EMPTY SLOT 0?", but it works.
-	local f slot state_dir=${GAMES_STATEDIR}/${PN}
-	dodir "${state_dir}"
-	for slot in {0..4} ; do
-		f=save${slot}
-		dosym "${state_dir}/save${slot}" "${GAMES_PREFIX_OPT}/${PN}/${f}"
-		echo "empty slot ${slot}" > "${D}${state_dir}/${f}" || die
-		fperms 660 "${state_dir}/${f}"
-	done
-
-	prepgamesdirs
-}
diff --git a/games-rpg/coe2/coe2-2007-r2.ebuild b/games-rpg/coe2/coe2-2007-r2.ebuild
new file mode 100644
index 000000000000..3ac7358ce27a
--- /dev/null
+++ b/games-rpg/coe2/coe2-2007-r2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop wrapper
+
+DESCRIPTION="Precursor to the Dominions series"
+HOMEPAGE="https://www.shrapnelgames.com/Our_Games/Free_Games.html"
+SRC_URI="https://download.shrapnelgames.com/downloads/${PN}_${PV}.zip"
+S="${WORKDIR}"/coe
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="mirror bindist"
+
+DEPEND="media-libs/libsdl[sound,video]"
+RDEPEND="
+	${DEPEND}
+	acct-group/gamestat
+"
+BDEPEND="app-arch/unzip"
+
+# bug #430026
+QA_PREBUILT="opt/coe2/coe_linux"
+
+src_prepare() {
+	default
+
+	rm -r *.{dll,exe} old || die
+	if use amd64 ; then
+		mv -f coe_linux64bit coe_linux || die
+	fi
+}
+
+src_install() {
+	insinto /opt/${PN}
+	doins *.{bgm,smp,trp,trs,wrl}
+	dodoc history.txt manual.txt readme.txt
+	exeinto /opt/${PN}
+	doexe coe_linux
+
+	make_wrapper ${PN} "./coe_linux" "/opt/${PN}"
+	make_desktop_entry ${PN} "Conquest of Elysium 2"
+
+	# Slots for saved games.
+	# The game shows e.g. "EMPTY SLOT 0?", but it works.
+	local state_dir=/var/lib/${PN}
+	dodir ${state_dir}
+
+	local f slot
+	for slot in {0..4} ; do
+		f=save${slot}
+
+		dosym ${state_dir}/save${slot} /opt/${PN}/${f}
+		echo "empty slot ${slot}" > "${ED}"/${state_dir}/${f} || die
+		fperms 660 ${state_dir}/${f}
+	done
+
+	fowners -R root:gamestat /var/lib/${PN}/
+	fperms g+s /opt/${PN}/coe_linux
+}
-- 
cgit v1.2.3-65-gdbad