From de29ffbf0822d0f53bf6fcb10b91e4c036fa172b Mon Sep 17 00:00:00 2001
From: James Le Cuirot <chewi@gentoo.org>
Date: Sun, 20 Jan 2019 15:17:12 +0000
Subject: media-tv/tvheadend: Version bump to 4.2.8, loosen ffmpeg dependency

It builds against ffmpeg 4 now.

Closes: https://bugs.gentoo.org/673062
Package-Manager: Portage-2.3.56, Repoman-2.3.12
Signed-off-by: James Le Cuirot <chewi@gentoo.org>
---
 media-tv/tvheadend/Manifest               |   1 +
 media-tv/tvheadend/tvheadend-4.2.8.ebuild | 120 ++++++++++++++++++++++++++++++
 media-tv/tvheadend/tvheadend-9999.ebuild  |   2 +-
 3 files changed, 122 insertions(+), 1 deletion(-)
 create mode 100644 media-tv/tvheadend/tvheadend-4.2.8.ebuild

(limited to 'media-tv/tvheadend')

diff --git a/media-tv/tvheadend/Manifest b/media-tv/tvheadend/Manifest
index 7026baf3a261..f1516f1c434c 100644
--- a/media-tv/tvheadend/Manifest
+++ b/media-tv/tvheadend/Manifest
@@ -1 +1,2 @@
 DIST tvheadend-4.2.7.tar.gz 21815613 BLAKE2B 2a90801189901c8129209d9157fbca826e5e46c2641aa08676a44f3076f4dd82c7732e188e87835ce22b19aedea96b8c816733998241a213904c9f9aff1a2537 SHA512 14dd4f452a785359614e2dfe3c210543e0bddf011b8bb994a282cfcff3f3e2573e48636e4c778c7fea39c01318053211e674911fcec3ad5f7b536bdd9e5f5aa9
+DIST tvheadend-4.2.8.tar.gz 21875281 BLAKE2B fdd99ca6aff56f8daa073394f9c58e9cba4ea988a2884e24c2288fd4870dd0460624fb700838ba92867a57473cc4133fed5fbd56f0e40f02a0878ffcd0642c00 SHA512 e629ffe1802e76b5121d5c22d11be86640f17816a5e902ed4842b2fd21df506d00d9caebafd931d71995e9d9049cb675c032478c9bed4f1ce82fc3f255f6166f
diff --git a/media-tv/tvheadend/tvheadend-4.2.8.ebuild b/media-tv/tvheadend/tvheadend-4.2.8.ebuild
new file mode 100644
index 000000000000..0673c7bc7a39
--- /dev/null
+++ b/media-tv/tvheadend/tvheadend-4.2.8.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit linux-info systemd toolchain-funcs user
+
+DESCRIPTION="Tvheadend is a TV streaming server and digital video recorder"
+HOMEPAGE="https://tvheadend.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+IUSE="+capmt +constcw +cwc dbus debug dvbcsa dvben50221 +dvb +ffmpeg hdhomerun +imagecache +inotify iptv libressl satip systemd +timeshift uriparser xmltv zeroconf zlib"
+
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+RDEPEND="
+	virtual/libiconv
+	dbus? ( sys-apps/dbus )
+	dvbcsa? ( media-libs/libdvbcsa )
+	dvben50221? ( media-tv/linuxtv-dvb-apps )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	hdhomerun? ( media-libs/libhdhomerun )
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:= )
+	uriparser? ( dev-libs/uriparser )
+	zeroconf? ( net-dns/avahi )
+	zlib? ( sys-libs/zlib )"
+
+DEPEND="
+	${RDEPEND}
+	dvb? ( virtual/linuxtv-dvb-headers )"
+
+RDEPEND+="
+	dvb? ( media-tv/dtv-scan-tables )
+	xmltv? ( media-tv/xmltv )"
+
+REQUIRED_USE="dvbcsa? ( || ( capmt constcw cwc dvben50221 ) )"
+
+# Some patches from:
+# https://github.com/rpmfusion/tvheadend
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0.9-use_system_queue.patch
+	"${FILESDIR}"/${PN}-4.2.1-hdhomerun.patch
+	"${FILESDIR}"/${PN}-4.2.2-dtv_scan_tables.patch
+)
+
+DOCS=( README.md )
+
+pkg_setup() {
+	use inotify &&
+		CONFIG_CHECK="~INOTIFY_USER" linux-info_pkg_setup
+
+	enewuser tvheadend -1 -1 /etc/tvheadend video
+}
+
+src_configure() {
+	CC="$(tc-getCC)" \
+	PKG_CONFIG="${CHOST}-pkg-config" \
+	econf \
+		--disable-bundle \
+		--disable-ccache \
+		--disable-dvbscan \
+		--disable-ffmpeg_static \
+		--disable-hdhomerun_static \
+		--nowerror \
+		$(use_enable capmt) \
+		$(use_enable constcw) \
+		$(use_enable cwc) \
+		$(use_enable dbus dbus_1) \
+		$(use_enable debug trace) \
+		$(use_enable dvb linuxdvb) \
+		$(use_enable dvbcsa) \
+		$(use_enable dvben50221) \
+		$(use_enable ffmpeg libav) \
+		$(use_enable hdhomerun hdhomerun_client) \
+		$(use_enable imagecache) \
+		$(use_enable inotify) \
+		$(use_enable iptv) \
+		$(use_enable satip satip_server) \
+		$(use_enable satip satip_client) \
+		$(use_enable systemd libsystemd_daemon) \
+		$(use_enable timeshift) \
+		$(use_enable uriparser) \
+		$(use_enable zeroconf avahi) \
+		$(use_enable zlib)
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}"/tvheadend.initd tvheadend
+	newconfd "${FILESDIR}"/tvheadend.confd tvheadend
+
+	use systemd &&
+		systemd_dounit "${FILESDIR}"/tvheadend.service
+
+	dodir /etc/tvheadend
+	fperms 0700 /etc/tvheadend
+	fowners tvheadend:video /etc/tvheadend
+}
+
+pkg_postinst() {
+	elog "The Tvheadend web interface can be reached at:"
+	elog "http://localhost:9981/"
+	elog
+	elog "Make sure that you change the default username"
+	elog "and password via the Configuration / Access control"
+	elog "tab in the web interface."
+}
diff --git a/media-tv/tvheadend/tvheadend-9999.ebuild b/media-tv/tvheadend/tvheadend-9999.ebuild
index 8aa2d256431d..700a7cc5a1d5 100644
--- a/media-tv/tvheadend/tvheadend-9999.ebuild
+++ b/media-tv/tvheadend/tvheadend-9999.ebuild
@@ -23,7 +23,7 @@ RDEPEND="
 	virtual/libiconv
 	dbus? ( sys-apps/dbus )
 	dvbcsa? ( media-libs/libdvbcsa )
-	ffmpeg? ( media-video/ffmpeg:0/55.57.57[opus?,vpx?,x264?,x265?] )
+	ffmpeg? ( media-video/ffmpeg:0=[opus?,vpx?,x264?,x265?] )
 	hdhomerun? ( media-libs/libhdhomerun )
 	!libressl? ( dev-libs/openssl:0= )
 	libressl? ( dev-libs/libressl:= )
-- 
cgit v1.2.3-65-gdbad