From 7b1b900ad6015e97bc47f63511db53a3b637a787 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sun, 13 Sep 2020 04:23:02 +0000
Subject: net-misc/mulk: bump to EAPI 7

Closes: https://bugs.gentoo.org/742137
Closes: https://bugs.gentoo.org/717984
Closes: https://bugs.gentoo.org/725140
Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Sam James <sam@gentoo.org>
---
 net-misc/mulk/files/mulk-0.7.0-musl-locale.patch | 12 +++++
 net-misc/mulk/mulk-0.7.0-r1.ebuild               | 58 ++++++++++++++++++++++++
 net-misc/mulk/mulk-0.7.0.ebuild                  | 39 ----------------
 3 files changed, 70 insertions(+), 39 deletions(-)
 create mode 100644 net-misc/mulk/files/mulk-0.7.0-musl-locale.patch
 create mode 100644 net-misc/mulk/mulk-0.7.0-r1.ebuild
 delete mode 100644 net-misc/mulk/mulk-0.7.0.ebuild

(limited to 'net-misc/mulk')

diff --git a/net-misc/mulk/files/mulk-0.7.0-musl-locale.patch b/net-misc/mulk/files/mulk-0.7.0-musl-locale.patch
new file mode 100644
index 000000000000..4aadd59dec94
--- /dev/null
+++ b/net-misc/mulk/files/mulk-0.7.0-musl-locale.patch
@@ -0,0 +1,12 @@
+diff --git a/lib/mulk.c b/lib/mulk.c
+index 9342032..21e5ccb 100644
+--- a/lib/mulk.c
++++ b/lib/mulk.c
+@@ -30,6 +30,7 @@
+  * files in the program, then also delete it here.
+  *---------------------------------------------------------------------------*/
+ 
++#include <locale.h>
+ #include "m_malloc.h"
+ #include "buffer_array.h"
+ #include "url_list.h"
diff --git a/net-misc/mulk/mulk-0.7.0-r1.ebuild b/net-misc/mulk/mulk-0.7.0-r1.ebuild
new file mode 100644
index 000000000000..7aba3f1bc448
--- /dev/null
+++ b/net-misc/mulk/mulk-0.7.0-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PV=${PV/_beta/}
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Download agent similar to wget/curl"
+HOMEPAGE="http://mulk.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="checksum debug metalink"
+REQUIRED_USE="checksum? ( metalink )"
+
+DEPEND="
+	app-text/htmltidy
+	dev-libs/uriparser
+	net-misc/curl
+	sys-devel/gettext
+	virtual/libiconv
+	virtual/libintl
+	metalink? (
+		media-libs/libmetalink
+		checksum? ( dev-libs/openssl )
+	)
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.7.0-musl-locale.patch"
+)
+
+src_configure() {
+	local checksum=
+
+	if use metalink && use checksum ; then
+		checksum="--enable-checksum"
+	fi
+
+	econf \
+		$(use_enable debug) \
+		$(use_enable metalink) \
+		"${checksum}"
+}
+
+src_install() {
+	default
+
+	# Remove static libraries
+	find "${ED}" -name '*.a' -delete || die
+	# and libtool archives
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/net-misc/mulk/mulk-0.7.0.ebuild b/net-misc/mulk/mulk-0.7.0.ebuild
deleted file mode 100644
index c6f3842a1e6d..000000000000
--- a/net-misc/mulk/mulk-0.7.0.ebuild
+++ /dev/null
@@ -1,39 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="4"
-
-inherit base
-
-MY_PV=${PV/_beta/}
-MY_P="${PN}-${MY_PV}"
-
-DESCRIPTION="Download agent similar to wget/curl"
-HOMEPAGE="http://mulk.sourceforge.net/"
-SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="checksum debug metalink"
-
-DEPEND="net-misc/curl
-	app-text/htmltidy
-	dev-libs/uriparser
-	metalink? (
-		media-libs/libmetalink
-		checksum? ( dev-libs/openssl )
-	)"
-
-REQUIRED_USE="checksum? ( metalink )"
-
-RDEPEND="${DEPEND}"
-
-S="${WORKDIR}/${MY_P}"
-
-src_configure() {
-	econf \
-		$(use_enable debug) \
-		$(use_enable metalink) \
-		$(use metalink && use checksum && echo --enable-checksum)
-}
-- 
cgit v1.2.3-65-gdbad