From 9ab7893bcdd999b078fbe8afd84769dcdaa2463f Mon Sep 17 00:00:00 2001
From: Rick Farina <zerochaos@gentoo.org>
Date: Thu, 23 Jul 2020 12:00:49 -0400
Subject: net-wireless/srslte: re-add 19.09

accidently removed with an overzealous push

Package-Manager: Portage-3.0.0, Repoman-2.3.23
Signed-off-by: Rick Farina <zerochaos@gentoo.org>
---
 net-wireless/srslte/Manifest               |  1 +
 net-wireless/srslte/srslte-19.09-r1.ebuild | 54 ++++++++++++++++++++++++++++++
 2 files changed, 55 insertions(+)
 create mode 100644 net-wireless/srslte/srslte-19.09-r1.ebuild

(limited to 'net-wireless')

diff --git a/net-wireless/srslte/Manifest b/net-wireless/srslte/Manifest
index c9dd17c11a85..8800775f001d 100644
--- a/net-wireless/srslte/Manifest
+++ b/net-wireless/srslte/Manifest
@@ -1 +1,2 @@
+DIST srslte-19.09.tar.gz 2372283 BLAKE2B 8d3b3cdfe777824c30e570f61ffddd1a9b1fd8136b6f67c2d54cbcfe089a1f55cc56d5b02ddb983c8a3e96af4228509b17a3c816b2d5196bc87bae29e14a625f SHA512 3516bb4aa027437420509eeca98e30f8f5c2bc7f8f1a606309587b70b51f2e6712c605155ec76a38868bf4c1f9007641c8c5b986c1cda76486bf3c4788eed888
 DIST srslte-20.04.1.tar.gz 7852357 BLAKE2B 1a9f4064c39fb09d155d0fef7de77f2277528296f749a8cef42624d0dd68a3e957eabceea44d74a1c5a4b28bf6e89f10dbf4b91a4b35ef197e07c36863277167 SHA512 0c55fc5f29a419c74c1bdbf94f63d0296341a1691faac9bf1e862d1b8afd207807907d376efc49513bb0f0e4f8fa6ef16fa8785d203a454824b33652788b5d2f
diff --git a/net-wireless/srslte/srslte-19.09-r1.ebuild b/net-wireless/srslte/srslte-19.09-r1.ebuild
new file mode 100644
index 000000000000..2fbb75471979
--- /dev/null
+++ b/net-wireless/srslte/srslte-19.09-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Open source SDR LTE software suite from Software Radio Systems"
+HOMEPAGE="http://www.softwareradiosystems.com"
+
+if [ "${PV}" = "9999" ]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/srsLTE/srsLTE.git"
+else
+	inherit vcs-snapshot
+	KEYWORDS="~amd64 ~x86"
+	MY_PV=${PV//./_}
+	SRC_URI="https://github.com/srsLTE/srsLTE/archive/release_${MY_PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="bladerf simcard soapysdr uhd zeromq"
+
+DEPEND="
+	dev-libs/boost
+	dev-libs/libconfig
+	net-misc/lksctp-tools
+	net-libs/mbedtls:=
+	sci-libs/fftw:*
+	bladerf? ( net-wireless/bladerf:= )
+	simcard? ( sys-apps/pcsc-lite )
+	soapysdr? ( net-wireless/soapysdr:= )
+	uhd? ( net-wireless/uhd:= )
+	zeromq? ( net-libs/zeromq )
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+src_prepare() {
+	sed -i '/ -Werror"/d' CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DENABLE_UHD="$(usex uhd)"
+		-DENABLE_BLADERF="$(usex bladerf)"
+		-DENABLE_SOAPYSDR="$(usex soapysdr)"
+		-DENABLE_ZEROMQ="$(usex zeromq)"
+		-DENABLE_HARDSIM="$(usex simcard)"
+	)
+	cmake_src_configure
+}
-- 
cgit v1.2.3-65-gdbad