From fd7278ff845595f4e626a4950e8ffe5e00dacf24 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Fri, 16 Jun 2017 21:57:10 +0200
Subject: x11-libs/libxklavier: Bump to 5.4

---
 x11-libs/libxklavier/Manifest               |  1 +
 x11-libs/libxklavier/libxklavier-5.4.ebuild | 57 +++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)
 create mode 100644 x11-libs/libxklavier/libxklavier-5.4.ebuild

(limited to 'x11-libs')

diff --git a/x11-libs/libxklavier/Manifest b/x11-libs/libxklavier/Manifest
index 8f2d0b3f4c1a..13f770efb044 100644
--- a/x11-libs/libxklavier/Manifest
+++ b/x11-libs/libxklavier/Manifest
@@ -1 +1,2 @@
 DIST libxklavier-5.3.tar.xz 315684 SHA256 ebec3bc54b5652838502b96223152fb1cd8fcb14ace5cb02d718fc3276bbd404 SHA512 7bec94aeedbe80aec2c44c9e2a3b7ea170618970fff3c1b5e677f1b292241e208b74eabd825d477eeab25bb0ee1d27f9b55f986a19ea8aacb078651a0c83b289 WHIRLPOOL e9f64343e750397e2ec55311ce8ed650bfb71fb09eccdf3563cd8ac5a83f4203d79d00695978f7d27c0a91a03d67fd29c4842b401fc8b23621121cd9e9b0d84b
+DIST libxklavier-5.4.tar.bz2 390428 SHA256 17a34194df5cbcd3b7bfd0f561d95d1f723aa1c87fca56bc2c209514460a9320 SHA512 e9342d94f6cd67e900e44d9751ee0d8c75bec8e3a7b30989612bd71a5f890be52ff843465162dbbe0bfc9004da76e1d47158a4671b8f915e51c91f9d82f7baae WHIRLPOOL 93e2b73d8035e6ef01c0286c98e36d8f0ad5981238de49c9e93fedd97efc5247feadefa30cfc8fbf924980aa0e95fe6f24d1702b00171e0fdb3f4a430bab1a1f
diff --git a/x11-libs/libxklavier/libxklavier-5.4.ebuild b/x11-libs/libxklavier/libxklavier-5.4.ebuild
new file mode 100644
index 000000000000..bad391397de1
--- /dev/null
+++ b/x11-libs/libxklavier/libxklavier-5.4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit libtool vala xdg-utils
+
+DESCRIPTION="A library for the X Keyboard Extension (high-level API)"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/LibXklavier"
+SRC_URI="https://people.freedesktop.org/~svu/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0/16"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.16:2=
+	dev-libs/libxml2:2=
+	x11-apps/xkbcomp
+	x11-libs/libX11:=
+	>=x11-libs/libXi-1.1.3:=
+	x11-libs/libxkbfile:=
+	>=x11-misc/xkeyboard-config-2.4.1-r3
+	introspection? ( >=dev-libs/gobject-introspection-1.30:= )
+	vala? ( $(vala_depend) )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.4
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	elibtoolize
+	xdg_environment_reset
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--disable-gtk-doc \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		--with-xkb-base="${EPREFIX}"/usr/share/X11/xkb \
+		--with-xkb-bin-base="${EPREFIX}"/usr/bin
+}
+
+src_install() {
+	default
+	dodoc CREDITS
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad