# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

inherit flag-o-matic toolchain-funcs multilib-minimal

DESCRIPTION="The Fast Lexical Analyzer"
HOMEPAGE="http://flex.sourceforge.net/"
SRC_URI="mirror://sourceforge/flex/${P}.tar.xz"

LICENSE="FLEX"
SLOT="0"
KEYWORDS="~amd64"
IUSE="nls static test"

# We want bison explicitly and not yacc in general #381273
RDEPEND="sys-devel/m4"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	nls? ( sys-devel/gettext[${MULTILIB_USEDEP}] )
	test? ( sys-devel/bison )"

DOCS="AUTHORS ChangeLog NEWS ONEWS README* THANKS TODO"

src_configure() {
	# Do not instal shared libs #503522
	use static && append-ldflags -static
	multilib-minimal_src_configure --disable-shared
}

multilib_src_configure() {
	ECONF_SOURCE="${S}" econf \
		$(use_enable nls) \
		--docdir="${EPREFIX}"/usr/share/doc/${PF}
}

multilib_src_install_all() {
	rm "${ED}"/usr/share/doc/${PF}/{COPYING,flex.pdf} || die
	einstalldocs
	dosym flex /usr/bin/lex
}