Version bump, wrt bug #508786. Thanks to Nikoli <nikoli AT gmx.us> for discovering this issue

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

2 files changed, 68 insertions, 2 deletions

diff --git a/app-text/yagf/ChangeLog b/app-text/yagf/ChangeLog
index 244a3087bb8e..5d69ed875ae7 100644
--- a/app-text/yagf/ChangeLog
+++ b/app-text/yagf/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/yagf
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/yagf/ChangeLog,v 1.20 2013/03/24 15:39:45 hwoarang Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/yagf/ChangeLog,v 1.21 2014/05/08 10:01:37 pinkbyte Exp $
+
+*yagf-0.9.3.2 (08 May 2014)
+
+  08 May 2014; Sergey Popov <pinkbyte@gentoo.org> +yagf-0.9.3.2.ebuild:
+  Version bump, wrt bug #508786. Thanks to Nikoli <nikoli AT gmx.us> for
+  discovering this issue
 
   24 Mar 2013; Markos Chandras <hwoarang@gentoo.org> yagf-0.9.2.ebuild:
   Default to tesseract implementation
diff --git a/app-text/yagf/yagf-0.9.3.2.ebuild b/app-text/yagf/yagf-0.9.3.2.ebuild
new file mode 100644
index 000000000000..e6147a4f5406
--- /dev/null
+++ b/app-text/yagf/yagf-0.9.3.2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/yagf/yagf-0.9.3.2.ebuild,v 1.1 2014/05/08 10:01:37 pinkbyte Exp $
+
+EAPI="5"
+
+PLOCALES="fr ru"
+inherit cmake-utils l10n multilib
+
+DESCRIPTION="Graphical front-end for cuneiform and tesseract OCR tools"
+HOMEPAGE="http://symmetrica.net/cuneiform-linux/yagf-en.html"
+SRC_URI="http://symmetrica.net/cuneiform-linux/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="scanner cuneiform +tesseract pdf"
+
+REQUIRED_USE="|| ( cuneiform tesseract )"
+
+DEPEND="
+	dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	app-text/aspell
+"
+RDEPEND="${DEPEND}
+	cuneiform? ( app-text/cuneiform )
+	tesseract? ( app-text/tesseract )
+	scanner? ( media-gfx/xsane )
+	pdf? ( || ( app-text/poppler[utils] app-text/ghostscript-gpl ) )
+"
+
+DOCS=( AUTHORS ChangeLog DESCRIPTION README )
+
+src_prepare() {
+	# respect CFLAGS and fix translations path
+	sed -i \
+		-e '/add_definitions(-Wall -g)/d' \
+		-e '/-DQML_INSTALL_PATH=/s:${QML_DESTINATION}:/${QML_DESTINATION}:' \
+		CMakeLists.txt || die 'sed on CMakeLists.txt failed'
+
+	l10n_find_plocales_changes "src/translations" "${PN}_" '.ts'
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_PATH_SUFFIX=${libdir#lib}
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	remove_translation() {
+		rm "${ED}/usr/share/yagf/translations/${PN}_${1}.qm" || die "remove '${PN}_${1}.qm' file failed"
+	}
+	cmake-utils_src_install
+	l10n_for_each_disabled_locale_do remove_translation
+}