Do not install static library in /lib (bug #449224, thanks to BillWho). Update to python-r1.eclass.

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

3 files changed, 87 insertions, 43 deletions

diff --git a/dev-libs/libpwquality/ChangeLog b/dev-libs/libpwquality/ChangeLog
index c4058c45007a..01da6b2f08b1 100644
--- a/dev-libs/libpwquality/ChangeLog
+++ b/dev-libs/libpwquality/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/libpwquality
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpwquality/ChangeLog,v 1.3 2012/12/05 08:54:27 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpwquality/ChangeLog,v 1.4 2012/12/29 19:29:15 tetromino Exp $
+
+*libpwquality-1.2.0-r2 (29 Dec 2012)
+
+  29 Dec 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  -libpwquality-1.2.0.ebuild, +libpwquality-1.2.0-r2.ebuild:
+  Do not install static library in /lib (bug #449224, thanks to BillWho).
+  Update to python-r1.eclass. Drop old.
 
 *libpwquality-1.2.0-r1 (05 Dec 2012)
 
diff --git a/dev-libs/libpwquality/libpwquality-1.2.0-r2.ebuild b/dev-libs/libpwquality/libpwquality-1.2.0-r2.ebuild
new file mode 100644
index 000000000000..3eb675160b25
--- /dev/null
+++ b/dev-libs/libpwquality/libpwquality-1.2.0-r2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpwquality/libpwquality-1.2.0-r2.ebuild,v 1.1 2012/12/29 19:29:15 tetromino Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils multilib pam python-r1 toolchain-funcs
+
+DESCRIPTION="Library for password quality checking and generating random passwords"
+HOMEPAGE="https://fedorahosted.org/libpwquality/"
+SRC_URI="https://fedorahosted.org/releases/l/i/${PN}/${P}.tar.bz2"
+
+LICENSE="|| ( BSD GPL-2 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="pam python static-libs"
+
+RDEPEND=">=sys-libs/cracklib-2.8:=
+	pam? ( virtual/pam )
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	sys-devel/libtool
+	virtual/pkgconfig"
+
+src_prepare() {
+	# ensure pkgconfig files go in /usr
+	sed -e 's:\(pkgconfigdir *=\).*:\1 '${EPREFIX}/usr/$(get_libdir)'/pkgconfig:' \
+		-i src/Makefile.{am,in} || die "sed failed"
+	use python && python_copy_sources
+}
+
+src_configure() {
+	# Install library in /lib for pam
+	configuring() {
+		local sitedir
+		econf \
+			--libdir="${EPREFIX}/$(get_libdir)" \
+			$(use_enable pam) \
+			--with-securedir="${EPREFIX}/$(getpam_mod_dir)" \
+			$(use_enable python python-bindings) \
+			$(usex python "--with-pythonsitedir=$(use python && python_get_sitedir)" "") \
+			$(use_enable static-libs static)
+	}
+	if_use_python_python_foreach_impl configuring
+}
+
+src_compile() {
+	if_use_python_python_foreach_impl default
+}
+
+src_test() {
+	if_use_python_python_foreach_impl default
+}
+
+src_install() {
+	if_use_python_python_foreach_impl default
+	if use static-libs; then
+		# Do not install static libs in /lib
+		mkdir -p "${ED}usr/$(get_libdir)"
+		mv "${ED}$(get_libdir)/libpwquality.a" "${ED}/usr/$(get_libdir)/" || die
+		gen_usr_ldscript libpwquality.so
+	fi
+	prune_libtool_files --modules
+}
+
+if_use_python_python_foreach_impl() {
+	run_in_build_dir() {
+		pushd "${BUILD_DIR}" > /dev/null || die
+		"$@"
+		popd > /dev/null
+	}
+
+	if use python; then
+		python_foreach_impl run_in_build_dir "$@"
+	else
+		"$@"
+	fi
+}
diff --git a/dev-libs/libpwquality/libpwquality-1.2.0.ebuild b/dev-libs/libpwquality/libpwquality-1.2.0.ebuild
deleted file mode 100644
index 7f99f73ebc67..000000000000
--- a/dev-libs/libpwquality/libpwquality-1.2.0.ebuild
+++ /dev/null
@@ -1,42 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpwquality/libpwquality-1.2.0.ebuild,v 1.2 2012/08/24 22:00:37 tetromino Exp $
-
-EAPI="4"
-PYTHON_DEPEND="python? 2:2.7"
-
-inherit eutils multilib python
-
-DESCRIPTION="Library for password quality checking and generating random passwords"
-HOMEPAGE="https://fedorahosted.org/libpwquality/"
-SRC_URI="https://fedorahosted.org/releases/l/i/${PN}/${P}.tar.bz2"
-
-LICENSE="|| ( BSD GPL-2 )"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="pam python static-libs"
-
-RDEPEND=">=sys-libs/cracklib-2.8
-	pam? ( virtual/pam )"
-DEPEND="${RDEPEND}
-	sys-devel/libtool
-	virtual/pkgconfig"
-
-pkg_setup() {
-	python_set_active_version 2
-	python_pkg_setup
-}
-
-src_configure() {
-	econf \
-		$(use_enable pam) \
-		$(use_enable python python-bindings) \
-		$(use_enable static-libs static)
-}
-
-src_install() {
-	default
-	# prune_libtool_files doesn't remove it...
-	use pam && rm -v "${ED}usr/$(get_libdir)/security/pam_pwquality.la"
-	prune_libtool_files
-}