media-gfx/shotwell: Version BUmp and fix deps, #491732; thanks Mark R. Pariente for the patch

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

3 files changed, 118 insertions, 5 deletions

diff --git a/media-gfx/shotwell/ChangeLog b/media-gfx/shotwell/ChangeLog
index deb110fb13ca..467bd91818ee 100644
--- a/media-gfx/shotwell/ChangeLog
+++ b/media-gfx/shotwell/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/shotwell
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/shotwell/ChangeLog,v 1.62 2013/10/26 13:59:35 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/shotwell/ChangeLog,v 1.63 2013/11/20 11:24:36 jlec Exp $
+
+*shotwell-0.15.1 (20 Nov 2013)
+
+  20 Nov 2013; Justin Lecher <jlec@gentoo.org> shotwell-0.15.0.ebuild,
+  +shotwell-0.15.1.ebuild:
+  Version BUmp and fix deps, #491732; thanks Mark R. Pariente for the patch
 
   26 Oct 2013; Justin Lecher <jlec@gentoo.org> shotwell-0.15.0.ebuild:
   Update deps, thanks Mao PU for the patch; #489464
diff --git a/media-gfx/shotwell/shotwell-0.15.0.ebuild b/media-gfx/shotwell/shotwell-0.15.0.ebuild
index 1c1bd53c98b7..ae84734d13b8 100644
--- a/media-gfx/shotwell/shotwell-0.15.0.ebuild
+++ b/media-gfx/shotwell/shotwell-0.15.0.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/shotwell/shotwell-0.15.0.ebuild,v 1.2 2013/10/26 13:59:36 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/shotwell/shotwell-0.15.0.ebuild,v 1.3 2013/11/20 11:24:36 jlec Exp $
 
 EAPI=5
 
@@ -37,13 +37,13 @@ done
 RDEPEND="
 	>=dev-db/sqlite-3.5.9:3
 	>=dev-libs/dbus-glib-0.80
-	>=dev-libs/glib-2.33.0:2
+	>=dev-libs/glib-2.30.0:2
 	>=dev-libs/json-glib-0.7.6
-	>=dev-libs/libgee-0.8.0:0.8
+	>=dev-libs/libgee-0.8.5:0.8
 	>=dev-libs/libxml2-2.6.32:2
 	>=dev-util/desktop-file-utils-0.13
 	gnome-base/dconf
-	>=media-libs/gexiv2-0.5
+	>=media-libs/gexiv2-0.4.90
 	media-libs/gst-plugins-base:1.0
 	media-libs/gst-plugins-good:1.0
 	media-libs/gstreamer:1.0
diff --git a/media-gfx/shotwell/shotwell-0.15.1.ebuild b/media-gfx/shotwell/shotwell-0.15.1.ebuild
new file mode 100644
index 000000000000..e79d8864e195
--- /dev/null
+++ b/media-gfx/shotwell/shotwell-0.15.1.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/shotwell/shotwell-0.15.1.ebuild,v 1.1 2013/11/20 11:24:36 jlec Exp $
+
+EAPI=5
+
+GCONF_DEBUG="no"
+VALA_MIN_API_VERSION="0.20"
+VALA_MAX_API_VERSION="0.22"
+
+inherit eutils gnome2 multilib toolchain-funcs vala versionator
+
+MY_PV=$(get_version_component_range 1-2)
+DESCRIPTION="Open source photo manager for GNOME"
+HOMEPAGE="http://yorba.org/shotwell/"
+SRC_URI="http://www.yorba.org/download/${PN}/stable/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+CORE_SUPPORTED_LANGUAGES="
+	ia hi te fr de it es pl et sv sk lv pt bg bn nl da zh_CN
+	el ru pa hu en_GB uk ja fi zh_TW cs nb id th sl hr ar ast ro sr lt gl tr ca ko kk pt_BR
+	eu he mk ta vi or km af as gu kn ml mr af_ZA bn_IN id_ID ky nn_NO ta_IN te_IN "
+
+EXTRAS_SUPPORTED_LANGUAGES="
+	fr de it es pl et sv sk lv pt bg bn nl da zh_CN el ru pa hu en_GB uk
+	ja fi zh_TW cs nb id th sl hr ar ast ro sr lt gl tr ca ko kk pt_BR eu he mk te ta eo or hi
+	as kn ml mr bn_IN gu id_ID nn_NO vi"
+
+for x in ${CORE_SUPPORTED_LANGUAGES} ${EXTRAS_SUPPORTED_LANGUAGES}; do
+	IUSE+="linguas_${x} "
+done
+
+RDEPEND="
+	>=dev-db/sqlite-3.5.9:3
+	>=dev-libs/dbus-glib-0.80
+	>=dev-libs/glib-2.30.0:2
+	>=dev-libs/json-glib-0.7.6
+	>=dev-libs/libgee-0.8.5:0.8
+	>=dev-libs/libxml2-2.6.32:2
+	>=dev-util/desktop-file-utils-0.13
+	gnome-base/dconf
+	>=media-libs/gexiv2-0.4.90
+	media-libs/gst-plugins-base:1.0
+	media-libs/gst-plugins-good:1.0
+	media-libs/gstreamer:1.0
+	media-libs/lcms:2
+	>=media-libs/libexif-0.6.16:=
+	>=media-libs/libgphoto2-2.4.2:=
+	>=media-libs/libraw-0.13.2:=
+	>=net-libs/libsoup-2.26.0:2.4
+	>=net-libs/rest-0.7:0.7
+	>=net-libs/webkit-gtk-1.4:3
+	>=virtual/udev-145[gudev]
+	>=x11-libs/gtk+-3.6.0:3"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	>=sys-devel/m4-1.4.13"
+
+DOCS=( AUTHORS MAINTAINERS NEWS README THANKS )
+
+# This probably comes from libraries that
+# shotwell-video-thumbnailer links to.
+# Nothing we can do at the moment. #435048
+QA_FLAGS_IGNORED="/usr/libexec/${PN}/${PN}-video-thumbnailer"
+
+pkg_setup() {
+	tc-export CC
+	G2CONF="${G2CONF}
+		--disable-schemas-compile
+		--disable-desktop-update
+		--disable-icon-update
+		--prefix=/usr
+		--lib=$(get_libdir)"
+}
+
+src_prepare() {
+	vala_src_prepare
+	sed \
+		-e 's|CFLAGS :|CFLAGS +|g' \
+		-i plugins/Makefile.plugin.mk || die
+	epatch \
+		"${FILESDIR}"/${PN}-0.13.1-ldflags.patch
+}
+
+src_configure() {
+	./configure \
+		${G2CONF} \
+		|| die
+}
+
+src_compile() {
+	local valaver="$(vala_best_api_version)"
+	emake VALAC="$(type -p valac-${valaver})"
+}
+
+src_install() {
+	gnome2_src_install
+	for x in ${LANGS}; do
+		if ! has ${x} ${LINGUAS}; then
+			find "${D}"/usr/share/locale/${x} -type f -exec rm {} \;
+		fi
+	done
+}