version bump, drop old

(Portage version: 2.1.12.11/cvs/Linux x86_64, signed Manifest commit with key B658FA13)

3 files changed, 52 insertions, 56 deletions

diff --git a/dev-python/flask-pymongo/ChangeLog b/dev-python/flask-pymongo/ChangeLog
index ad7a3ce5fe3d..c0e6bf945e39 100644
--- a/dev-python/flask-pymongo/ChangeLog
+++ b/dev-python/flask-pymongo/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/flask-pymongo
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-pymongo/ChangeLog,v 1.6 2013/06/17 02:32:45 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-pymongo/ChangeLog,v 1.7 2013/07/05 07:07:08 ultrabug Exp $
+
+*flask-pymongo-0.3.0 (05 Jul 2013)
+
+  05 Jul 2013; Ultrabug <ultrabug@gentoo.org> -flask-pymongo-0.1.3.ebuild,
+  +flask-pymongo-0.3.0.ebuild:
+  version bump, drop old
 
   17 Jun 2013; Patrick Lauer <patrick@gentoo.org> flask-pymongo-0.2.1-r1.ebuild:
   Fix python targets as flask was downrated
diff --git a/dev-python/flask-pymongo/flask-pymongo-0.1.3.ebuild b/dev-python/flask-pymongo/flask-pymongo-0.1.3.ebuild
deleted file mode 100644
index 6908795cc8ac..000000000000
--- a/dev-python/flask-pymongo/flask-pymongo-0.1.3.ebuild
+++ /dev/null
@@ -1,55 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-pymongo/flask-pymongo-0.1.3.ebuild,v 1.2 2013/01/18 09:26:28 ultrabug Exp $
-
-EAPI="3"
-PYTHON_DEPEND="2:2.5"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="2.4 3.*"
-DISTUTILS_SRC_TEST="nosetests"
-
-inherit distutils
-
-MY_PN="Flask-PyMongo"
-MY_P="${MY_PN}-${PV}"
-
-DESCRIPTION="PyMongo support for Flask"
-HOMEPAGE="http://pypi.python.org/pypi/Flask-PyMongo"
-SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc examples"
-
-RDEPEND=">=dev-python/flask-0.8
-	>=dev-python/pymongo-2.1"
-DEPEND="${RDEPEND}
-	doc? ( dev-python/sphinx )
-	dev-python/setuptools
-	dev-python/nose"
-
-S="${WORKDIR}/${MY_P}"
-
-src_compile() {
-	distutils_src_compile
-
-	if use doc; then
-		einfo "Generation of documentation"
-		cd docs
-		PYTHONPATH=".." emake html || die "Generation of documentation failed"
-	fi
-}
-
-src_install() {
-	distutils_src_install
-
-	if use doc; then
-		dohtml -r docs/_build/html/* || die "Installation of documentation failed"
-	fi
-
-	if use examples; then
-		insinto /usr/share/doc/${PF}
-		doins -r examples || die "Installation of examples failed"
-	fi
-}
diff --git a/dev-python/flask-pymongo/flask-pymongo-0.3.0.ebuild b/dev-python/flask-pymongo/flask-pymongo-0.3.0.ebuild
new file mode 100644
index 000000000000..0a1296befa25
--- /dev/null
+++ b/dev-python/flask-pymongo/flask-pymongo-0.3.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-pymongo/flask-pymongo-0.3.0.ebuild,v 1.1 2013/07/05 07:07:08 ultrabug Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1
+
+MY_PN="Flask-PyMongo"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="PyMongo support for Flask"
+HOMEPAGE="http://pypi.python.org/pypi/Flask-PyMongo"
+SRC_URI="https://github.com/dcrosta/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+#SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-python/flask-0.8[${PYTHON_USEDEP}]
+	>=dev-python/pymongo-2.4[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/docbuild.patch )
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	# fix me
+	nosetests tests/{test_url_converter.py,test_wrappers.py} || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}