version bump (bug #195970)

(Portage version: 2.1.3.9)

3 files changed, 103 insertions, 1 deletions

diff --git a/app-emulation/vice/ChangeLog b/app-emulation/vice/ChangeLog
index 53a4b8116e2d..a37cbc175ee6 100644
--- a/app-emulation/vice/ChangeLog
+++ b/app-emulation/vice/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/vice
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/vice/ChangeLog,v 1.51 2007/06/16 16:22:18 nyhm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/vice/ChangeLog,v 1.52 2007/10/15 20:58:37 mr_bones_ Exp $
+
+*vice-1.22 (15 Oct 2007)
+
+  15 Oct 2007; Michael Sterrett <mr_bones_@gentoo.org> +vice-1.22.ebuild:
+  version bump (bug #195970)
 
 *vice-1.21-r1 (16 Jun 2007)
 
diff --git a/app-emulation/vice/files/digest-vice-1.22 b/app-emulation/vice/files/digest-vice-1.22
new file mode 100644
index 000000000000..bd91ba08536e
--- /dev/null
+++ b/app-emulation/vice/files/digest-vice-1.22
@@ -0,0 +1,3 @@
+MD5 33204acbb74bafb12594d39b55888626 vice-1.22.tar.gz 6088483
+RMD160 ca93fc424e617e38f27e288ebcdfbab2aa3659db vice-1.22.tar.gz 6088483
+SHA256 cd45ce3eea98ce70ae03002a4d02bb3188c982ee7fb7435ac8777bc8a780ef01 vice-1.22.tar.gz 6088483
diff --git a/app-emulation/vice/vice-1.22.ebuild b/app-emulation/vice/vice-1.22.ebuild
new file mode 100644
index 000000000000..2428ded281d0
--- /dev/null
+++ b/app-emulation/vice/vice-1.22.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/vice/vice-1.22.ebuild,v 1.1 2007/10/15 20:58:37 mr_bones_ Exp $
+
+inherit eutils games
+
+DESCRIPTION="The Versatile Commodore 8-bit Emulator"
+HOMEPAGE="http://www.viceteam.org/"
+SRC_URI="http://www.zimmers.net/anonftp/pub/cbm/crossplatform/emulators/VICE/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="Xaw3d alsa arts esd ffmpeg gnome nls png readline resid sdl"
+
+RDEPEND="media-libs/giflib
+	media-libs/jpeg
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXpm
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libXt
+	x11-libs/libXv
+	x11-libs/libXxf86dga
+	x11-libs/libXxf86vm
+	x11-apps/xset
+	Xaw3d? ( x11-libs/Xaw3d )
+	!Xaw3d? ( x11-libs/libXaw )
+	alsa? ( media-libs/alsa-lib )
+	arts? ( kde-base/arts )
+	esd? ( media-sound/esound )
+	ffmpeg? (
+		media-video/ffmpeg
+		media-sound/lame
+	)
+	gnome? ( gnome-base/libgnomeui )
+	nls? ( virtual/libintl )
+	png? ( media-libs/libpng )
+	readline? ( sys-libs/readline )
+	resid? ( media-libs/resid )
+	sdl? ( media-libs/libsdl )"
+DEPEND="${RDEPEND}
+	x11-apps/bdftopcf
+	x11-apps/mkfontdir
+	x11-proto/xproto
+	x11-proto/xf86vidmodeproto
+	x11-proto/xextproto
+	x11-proto/xf86dgaproto
+	x11-proto/videoproto
+	nls? ( sys-devel/gettext )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i \
+		-e '/^gnulocaledir/s:$(prefix):/usr:' \
+		po/Makefile.in.in \
+		|| die "sed Makefile.in.in failed"
+	sed -i \
+		-e 's/getline/intlpo_getline/' \
+		po/intl2po.c \
+		|| die "sed intl2po.c failed"
+	sed -i \
+		-e 's:\<SYNC\>:OPENGL_SYNC:g' \
+		configure src/arch/unix/x11/Makefile.in \
+		|| die "sed configure failed"
+}
+
+src_compile() {
+	egamesconf \
+		--disable-dependency-tracking \
+		--enable-fullscreen \
+		--without-midas \
+		$(use_enable ffmpeg) \
+		$(use_enable gnome gnomeui) \
+		$(use_enable nls) \
+		$(use_with Xaw3d xaw3d) \
+		$(use_with alsa) \
+		$(use_with arts) \
+		$(use_with esd) \
+		$(use_with png) \
+		$(use_with readline) \
+		$(use_with resid) \
+		$(use_with sdl) \
+		|| die
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog FEEDBACK README
+	prepgamesdirs
+}