version bump wrt #364145. Drop old stable. Thanks to Opportunist for reporting.

(Portage version: 2.1.9.46/cvs/Linux x86_64)

3 files changed, 221 insertions, 84 deletions

diff --git a/app-admin/rsyslog/ChangeLog b/app-admin/rsyslog/ChangeLog
index 814573b72925..7d5a819fdc34 100644
--- a/app-admin/rsyslog/ChangeLog
+++ b/app-admin/rsyslog/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-admin/rsyslog
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v 1.43 2011/04/19 09:32:05 tomka Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/ChangeLog,v 1.44 2011/04/26 07:33:03 ultrabug Exp $
+
+*rsyslog-5.8.0 (26 Apr 2011)
+
+  26 Apr 2011; Ultrabug <ultrabug@gentoo.org> -rsyslog-3.20.4.ebuild,
+  +rsyslog-5.8.0.ebuild:
+  version bump wrt #364145. Drop old stable. Thanks to Opportunist for
+  reporting.
 
   19 Apr 2011; Thomas Kahle <tomka@gentoo.org> rsyslog-5.6.4.ebuild:
   x86 stable per bug 359765
diff --git a/app-admin/rsyslog/rsyslog-3.20.4.ebuild b/app-admin/rsyslog/rsyslog-3.20.4.ebuild
deleted file mode 100644
index 5031c02557d0..000000000000
--- a/app-admin/rsyslog/rsyslog-3.20.4.ebuild
+++ /dev/null
@@ -1,83 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-3.20.4.ebuild,v 1.4 2011/04/07 07:50:20 ultrabug Exp $
-
-inherit versionator
-
-DESCRIPTION="An enhanced multi-threaded syslogd with database support and more."
-HOMEPAGE="http://www.rsyslog.com/"
-SRC_URI="http://download.rsyslog.com/${PN}/${P}.tar.gz"
-LICENSE="GPL-3 LGPL-3"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="debug kerberos dbi gnutls mysql postgres relp snmp zlib"
-
-DEPEND="kerberos? ( virtual/krb5 )
-	dbi? ( dev-db/libdbi )
-	gnutls? ( net-libs/gnutls )
-	mysql? ( virtual/mysql )
-	postgres? ( dev-db/postgresql-base )
-	relp? ( >=dev-libs/librelp-0.1.1 )
-	snmp? ( net-analyzer/net-snmp )
-	zlib? ( sys-libs/zlib )"
-RDEPEND="${DEPEND}"
-
-BRANCH="3-stable"
-
-src_compile() {
-	# Maintainer notes:
-	# * rsyslog-3 doesn't support single threading anymore
-	# * rfc3195 needs a library and development of that library
-	#   is suspended
-	econf \
-		--enable-largefile \
-		--enable-regexp \
-		$(use_enable zlib) \
-		$(use_enable kerberos gssapi-krb5) \
-		--enable-pthreads \
-		--enable-klog \
-		--enable-unix \
-		--enable-inet \
-		--enable-fsstnd \
-		$(use_enable debug) \
-		$(use_enable debug rtinst) \
-		$(use_enable debug valgrind) \
-		$(use_enable mysql) \
-		$(use_enable postgres pgsql) \
-		$(use_enable dbi libdbi) \
-		$(use_enable snmp) \
-		$(use_enable gnutls) \
-		--enable-rsyslogrt \
-		--enable-rsyslogd \
-		--enable-mail \
-		$(use_enable relp) \
-		--disable-rfc3195 \
-		--enable-imfile \
-		--disable-imtemplate
-	emake || die "emake failed"
-}
-
-src_install() {
-	emake DESTDIR="${D}" install || die "emake install failed"
-
-	insinto /usr/share/doc/${PF}/scripts/mysql
-	doins plugins/ommysql/{createDB.sql,contrib/delete_mysql}
-
-	insinto /usr/share/doc/${PF}/scripts/pgsql
-	doins plugins/ompgsql/createDB.sql
-
-	elog "SQL scripts to create the tables for MySQL or PostgreSQL have been installed to:"
-	elog "  /usr/share/doc/${PF}/scripts"
-
-	dodoc AUTHORS ChangeLog doc/rsyslog-example.conf
-	dohtml doc/*
-
-	insinto /etc
-	newins "${FILESDIR}/${BRANCH}/rsyslog-gentoo.conf" rsyslog.conf
-
-	insinto /etc/logrotate.d/
-	newins "${FILESDIR}/${BRANCH}/rsyslog.logrotate" rsyslog
-
-	newconfd "${FILESDIR}/${BRANCH}/rsyslog.conf" rsyslog
-	newinitd "${FILESDIR}/${BRANCH}/rsyslog.init" rsyslog
-}
diff --git a/app-admin/rsyslog/rsyslog-5.8.0.ebuild b/app-admin/rsyslog/rsyslog-5.8.0.ebuild
new file mode 100644
index 000000000000..a62c80c158ad
--- /dev/null
+++ b/app-admin/rsyslog/rsyslog-5.8.0.ebuild
@@ -0,0 +1,213 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/rsyslog/rsyslog-5.8.0.ebuild,v 1.1 2011/04/26 07:33:03 ultrabug Exp $
+
+EAPI=3
+
+DESCRIPTION="An enhanced multi-threaded syslogd with database support and more."
+HOMEPAGE="http://www.rsyslog.com/"
+SRC_URI="http://www.rsyslog.com/files/download/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3 LGPL-3"
+KEYWORDS="~amd64 ~arm ~hppa ~sparc ~x86"
+SLOT="0"
+IUSE="dbi debug doc extras gnutls kerberos mysql oracle postgres relp snmp static-libs zlib"
+
+DEPEND="dbi? ( dev-db/libdbi )
+	extras? ( net-libs/libnet )
+	gnutls? ( net-libs/gnutls )
+	kerberos? ( virtual/krb5 )
+	mysql? ( virtual/mysql )
+	postgres? ( dev-db/postgresql-base )
+	oracle? ( dev-db/oracle-instantclient-basic )
+	relp? ( >=dev-libs/librelp-0.1.3 )
+	snmp? ( net-analyzer/net-snmp )
+	zlib? ( sys-libs/zlib )"
+RDEPEND="${DEPEND}"
+
+BRANCH="5-stable"
+
+# need access to certain device nodes
+RESTRICT="test"
+
+src_configure() {
+	# Maintainer notes:
+	# * rfc3195 needs a library and development of that library
+	#   is suspended, so we disable it
+	# * About the java GUI:
+	#   The maintainer says there is no real installation support
+	#   for the java GUI, so we disable it for now.
+	econf \
+		--disable-gui \
+		--disable-rfc3195 \
+		--enable-largefile \
+		--enable-unlimited-select \
+		--enable-imdiag \
+		--enable-imfile \
+		--enable-imtemplate \
+		--enable-imptcp \
+		--enable-mail \
+		--enable-omprog \
+		--enable-omstdout \
+		--enable-omtemplate \
+		--enable-omdbalerting \
+		--enable-omuxsock \
+		--enable-pmlastmsg \
+		--enable-pmrfc3164sd \
+		$(use_enable extras omudpspoof) \
+		$(use_enable zlib) \
+		$(use_enable mysql) \
+		$(use_enable dbi libdbi) \
+		$(use_enable postgres pgsql) \
+		$(use_enable oracle oracle) \
+		$(use_enable gnutls) \
+		$(use_enable kerberos gssapi-krb5) \
+		$(use_enable relp) \
+		$(use_enable snmp) \
+		$(use_enable debug) \
+		$(use_enable debug rtinst) \
+		$(use_enable debug diagtools) \
+		$(use_enable debug memcheck) \
+		$(use_enable debug valgrind) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	dodoc AUTHORS ChangeLog doc/rsyslog-example.conf || die
+	use doc && dohtml -r doc/*
+
+	insinto /etc
+	newins "${FILESDIR}/${BRANCH}/rsyslog-gentoo.conf" rsyslog.conf || die
+	newconfd "${FILESDIR}/${BRANCH}/rsyslog.confd" rsyslog || die
+	newinitd "${FILESDIR}/${BRANCH}/rsyslog.initd" rsyslog || die
+	keepdir /var/spool/rsyslog
+	keepdir /etc/ssl/rsyslog
+	keepdir /etc/rsyslog.d
+
+	if use mysql; then
+		insinto /usr/share/doc/${PF}/scripts/mysql
+		doins plugins/ommysql/{createDB.sql,contrib/delete_mysql} || die
+	fi
+
+	if use postgres; then
+		insinto /usr/share/doc/${PF}/scripts/pgsql
+		doins plugins/ompgsql/createDB.sql || die
+	fi
+
+	insinto /etc/logrotate.d/
+	newins "${FILESDIR}/${BRANCH}/rsyslog.logrotate" rsyslog || die
+}
+
+pkg_postinst() {
+	if use mysql || use postgres; then
+		echo
+		elog "Sample SQL scripts for MySQL & PostgreSQL have been installed to:"
+		elog "  /usr/share/doc/${PF}/scripts"
+	fi
+
+	if use gnutls; then
+		echo
+		elog "To create a default CA and certificates for your server and clients, run:"
+		elog "  emerge --config =${PF}"
+		elog "on your logging server. You can run it several times,"
+		elog "once for each logging client. The client certificates will be signed"
+		elog "using the CA certificate generated during the first run."
+	fi
+}
+
+pkg_config() {
+	if ! use gnutls ; then
+		einfo "There is nothing to configure for rsyslog unless you"
+		einfo "used USE=gnutls to build it."
+		return 0
+	fi
+
+	# Make sure the certificates directory exists
+	CERTDIR="${ROOT}/etc/ssl/${PN}"
+	if [ ! -d "${CERTDIR}" ]; then
+		mkdir "${CERTDIR}" || die
+	fi
+	einfo "Your certificates will be stored in ${CERTDIR}"
+
+	# Create a default CA if needed
+	if [ ! -f "${CERTDIR}/${PN}_ca.cert.pem" ]; then
+		einfo "No CA key and certificate found in ${CERTDIR}, creating them for you..."
+		certtool --generate-privkey \
+			--outfile "${CERTDIR}/${PN}_ca.privkey.pem" &>/dev/null
+		chmod 400 "${CERTDIR}/${PN}_ca.privkey.pem"
+
+		cat > "${T}/${PF}.$$" <<_EOF
+		cn = Portage automated CA
+		ca
+		cert_signing_key
+		expiration_days = 3650
+_EOF
+
+		certtool --generate-self-signed \
+			--load-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
+			--outfile "${CERTDIR}/${PN}_ca.cert.pem" \
+			--template "${T}/${PF}.$$" &>/dev/null
+		chmod 400 "${CERTDIR}/${PN}_ca.privkey.pem"
+
+		# Create the server certificate
+		echo
+		einfon "Please type the Common Name of the SERVER you wish to create a certificate for: "
+		read -r CN
+
+		einfo "Creating private key and certificate for server ${CN}..."
+		certtool --generate-privkey \
+			--outfile "${CERTDIR}/${PN}_${CN}.key.pem" &>/dev/null
+		chmod 400 "${CERTDIR}/${PN}_${CN}.key.pem"
+
+		cat > "${T}/${PF}.$$" <<_EOF
+		cn = ${CN}
+		tls_www_server
+		dns_name = ${CN}
+		expiration_days = 3650
+_EOF
+
+		certtool --generate-certificate \
+			--outfile "${CERTDIR}/${PN}_${CN}.cert.pem" \
+			--load-privkey "${CERTDIR}/${PN}_${CN}.key.pem" \
+			--load-ca-certificate "${CERTDIR}/${PN}_ca.cert.pem" \
+			--load-ca-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
+			--template "${T}/${PF}.$$" &>/dev/null
+		chmod 400 "${CERTDIR}/${PN}_${CN}.cert.pem"
+
+	else
+		einfo "Found existing ${CERTDIR}/${PN}_ca.cert.pem, skipping CA and SERVER creation."
+	fi
+
+	# Create a client certificate
+	echo
+	einfon "Please type the Common Name of the CLIENT you wish to create a certificate for: "
+	read -r CN
+
+	einfo "Creating private key and certificate for client ${CN}..."
+	certtool --generate-privkey \
+		--outfile "${CERTDIR}/${PN}_${CN}.key.pem" &>/dev/null
+	chmod 400 "${CERTDIR}/${PN}_${CN}.key.pem"
+
+	cat > "${T}/${PF}.$$" <<_EOF
+	cn = ${CN}
+	tls_www_client
+	dns_name = ${CN}
+	expiration_days = 3650
+_EOF
+
+	certtool --generate-certificate \
+		--outfile "${CERTDIR}/${PN}_${CN}.cert.pem" \
+		--load-privkey "${CERTDIR}/${PN}_${CN}.key.pem" \
+		--load-ca-certificate "${CERTDIR}/${PN}_ca.cert.pem" \
+		--load-ca-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
+		--template "${T}/${PF}.$$" &>/dev/null
+	chmod 400 "${CERTDIR}/${PN}_${CN}.cert.pem"
+
+	rm -f "${T}/${PF}.$$"
+
+	echo
+	einfo "Here is the documentation on how to encrypt your log traffic:"
+	einfo " http://www.rsyslog.com/doc/rsyslog_tls.html"
+}