Support multilib. Bug #474940, patch by Alexis Ballier.

(Portage version: 2.2.0_alpha194/cvs/Linux x86_64, signed Manifest commit with key 9627F456F9DA7643!)

3 files changed, 96 insertions, 10 deletions

diff --git a/app-arch/xz-utils/ChangeLog b/app-arch/xz-utils/ChangeLog
index 9f65cb3d2318..845346674d91 100644
--- a/app-arch/xz-utils/ChangeLog
+++ b/app-arch/xz-utils/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/xz-utils
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/ChangeLog,v 1.62 2013/06/30 19:26:28 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/ChangeLog,v 1.63 2013/08/07 22:39:51 mgorny Exp $
+
+*xz-utils-5.0.5-r1 (07 Aug 2013)
+
+  07 Aug 2013; Michał Górny <mgorny@gentoo.org> +xz-utils-5.0.5-r1.ebuild,
+  xz-utils-9999.ebuild:
+  Support multilib. Bug #474940, patch by Alexis Ballier.
 
 *xz-utils-5.0.5 (30 Jun 2013)
 
diff --git a/app-arch/xz-utils/xz-utils-5.0.5-r1.ebuild b/app-arch/xz-utils/xz-utils-5.0.5-r1.ebuild
new file mode 100644
index 000000000000..233f0af03228
--- /dev/null
+++ b/app-arch/xz-utils/xz-utils-5.0.5-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/xz-utils-5.0.5-r1.ebuild,v 1.1 2013/08/07 22:39:51 mgorny Exp $
+
+# Remember: we cannot leverage autotools in this ebuild in order
+#           to avoid circular deps with autotools
+
+EAPI="4"
+
+inherit eutils multilib toolchain-funcs libtool multilib-minimal
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="http://git.tukaani.org/xz.git"
+	inherit git-2 autotools
+	SRC_URI=""
+	EXTRA_DEPEND="sys-devel/gettext dev-vcs/cvs >=sys-devel/libtool-2" #272880 286068
+else
+	MY_P="${PN/-utils}-${PV/_}"
+	SRC_URI="http://tukaani.org/xz/${MY_P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	S=${WORKDIR}/${MY_P}
+	EXTRA_DEPEND=
+fi
+
+DESCRIPTION="utils for managing LZMA compressed files"
+HOMEPAGE="http://tukaani.org/xz/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="nls static-libs +threads"
+
+RDEPEND="!<app-arch/lzma-4.63
+	!app-arch/lzma-utils
+	!<app-arch/p7zip-4.57
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20130224-r6
+		!>app-emulation/emul-linux-x86-baselibs-20130224-r6[-abi_x86_32] )"
+DEPEND="${RDEPEND}
+	${EXTRA_DEPEND}"
+
+src_prepare() {
+	if [[ ${PV} == "9999" ]] ; then
+		eautopoint
+		eautoreconf
+	else
+		elibtoolize  # to allow building shared libs on Solaris/x64
+	fi
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable nls) \
+		$(use_enable threads) \
+		$(use_enable static-libs static) \
+		$(multilib_is_native_abi || echo --disable-{xz,xzdec,lzmadec,lzmainfo,lzma-links,scripts})
+}
+
+multilib_src_install() {
+	default
+	multilib_is_native_abi && gen_usr_ldscript -a lzma
+}
+
+multilib_src_install_all() {
+	prune_libtool_files --all
+	rm "${ED}"/usr/share/doc/xz/COPYING* || die
+	mv "${ED}"/usr/share/doc/{xz,${PF}} || die
+}
+
+pkg_preinst() {
+	preserve_old_lib /usr/$(get_libdir)/liblzma$(get_libname 0)
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /usr/$(get_libdir)/liblzma$(get_libname 0)
+}
diff --git a/app-arch/xz-utils/xz-utils-9999.ebuild b/app-arch/xz-utils/xz-utils-9999.ebuild
index e3a22b079834..505a4884ee2e 100644
--- a/app-arch/xz-utils/xz-utils-9999.ebuild
+++ b/app-arch/xz-utils/xz-utils-9999.ebuild
@@ -1,13 +1,13 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/xz-utils-9999.ebuild,v 1.14 2012/12/07 22:15:01 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/xz-utils-9999.ebuild,v 1.15 2013/08/07 22:39:51 mgorny Exp $
 
 # Remember: we cannot leverage autotools in this ebuild in order
 #           to avoid circular deps with autotools
 
 EAPI="4"
 
-inherit eutils multilib toolchain-funcs libtool
+inherit eutils multilib toolchain-funcs libtool multilib-minimal
 
 if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="http://git.tukaani.org/xz.git"
@@ -31,7 +31,9 @@ IUSE="nls static-libs +threads"
 
 RDEPEND="!<app-arch/lzma-4.63
 	!app-arch/lzma-utils
-	!<app-arch/p7zip-4.57"
+	!<app-arch/p7zip-4.57
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20130224-r6
+		!>app-emulation/emul-linux-x86-baselibs-20130224-r6[-abi_x86_32] )"
 DEPEND="${RDEPEND}
 	${EXTRA_DEPEND}"
 
@@ -44,16 +46,20 @@ src_prepare() {
 	fi
 }
 
-src_configure() {
-	econf \
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
 		$(use_enable nls) \
 		$(use_enable threads) \
-		$(use_enable static-libs static)
+		$(use_enable static-libs static) \
+		$(multilib_is_native_abi || echo --disable-{xz,xzdec,lzmadec,lzmainfo,lzma-links,scripts})
 }
 
-src_install() {
+multilib_src_install() {
 	default
-	gen_usr_ldscript -a lzma
+	multilib_is_native_abi && gen_usr_ldscript -a lzma
+}
+
+multilib_src_install_all() {
 	prune_libtool_files --all
 	rm "${ED}"/usr/share/doc/xz/COPYING* || die
 	mv "${ED}"/usr/share/doc/{xz,${PF}} || die