Restore ebuild of latest released version.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

3 files changed, 69 insertions, 3 deletions

diff --git a/app-emacs/wanderlust/ChangeLog b/app-emacs/wanderlust/ChangeLog
index 3665c08f0689..0596e7ad95b6 100644
--- a/app-emacs/wanderlust/ChangeLog
+++ b/app-emacs/wanderlust/ChangeLog
@@ -1,6 +1,9 @@
 # ChangeLog for app-emacs/wanderlust
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emacs/wanderlust/ChangeLog,v 1.99 2015/06/05 12:41:43 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/wanderlust/ChangeLog,v 1.100 2015/06/05 14:18:56 ulm Exp $
+
+  05 Jun 2015; Ulrich Müller <ulm@gentoo.org> +wanderlust-2.14.0-r6.ebuild:
+  Restore ebuild of latest released version.
 
   05 Jun 2015; Justin Lecher <jlec@gentoo.org> -wanderlust-2.14.0-r6.ebuild:
   Drop old; deprecated EAPI
diff --git a/app-emacs/wanderlust/wanderlust-2.14.0-r6.ebuild b/app-emacs/wanderlust/wanderlust-2.14.0-r6.ebuild
new file mode 100644
index 000000000000..d7d6d9ebba88
--- /dev/null
+++ b/app-emacs/wanderlust/wanderlust-2.14.0-r6.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/wanderlust/wanderlust-2.14.0-r6.ebuild,v 1.11 2015/06/05 14:18:56 ulm Exp $
+
+EAPI=5
+
+inherit elisp
+
+MY_P="wl-${PV/_/}"
+DESCRIPTION="Yet Another Message Interface on Emacsen"
+HOMEPAGE="http://www.gohome.org/wl/"
+SRC_URI="ftp://ftp.gohome.org/wl/stable/${MY_P}.tar.gz
+	ftp://ftp.gohome.org/wl/beta/${MY_P}.tar.gz
+	mirror://gentoo/${P}-20050405.patch.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="bbdb ssl linguas_ja"
+
+DEPEND=">=app-emacs/apel-10.6
+	virtual/emacs-flim
+	app-emacs/semi
+	bbdb? ( app-emacs/bbdb )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+ELISP_PATCHES="${P}-20050405.patch
+	${P}-smtp-end-of-line.patch
+	${P}-texinfo-garbage.patch"
+SITEFILE="50${PN}-gentoo.el"
+
+src_configure() {
+	local lang="\"en\""
+	use linguas_ja && lang="${lang} \"ja\""
+	echo "(setq wl-info-lang '(${lang}) wl-news-lang '(${lang}))" >>WL-CFG
+	use ssl && echo "(setq wl-install-utils t)" >>WL-CFG
+}
+
+src_compile() {
+	emake
+	emake info
+}
+
+src_install() {
+	emake \
+		LISPDIR="${ED}${SITELISP}" \
+		PIXMAPDIR="${ED}${SITEETC}/wl/icons" \
+		install
+
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}" wl
+
+	insinto "${SITEETC}/wl/samples/en"
+	doins samples/en/*
+	doinfo doc/wl*.info
+	dodoc BUGS ChangeLog INSTALL NEWS README
+
+	if use linguas_ja; then
+		insinto "${SITEETC}/wl/samples/ja"
+		doins samples/ja/*
+		dodoc BUGS.ja INSTALL.ja NEWS.ja README.ja
+	fi
+}
diff --git a/app-emacs/wanderlust/wanderlust-2.15.9_p20130619.ebuild b/app-emacs/wanderlust/wanderlust-2.15.9_p20130619.ebuild
index 55a2fbf48c4f..85705ecf28c6 100644
--- a/app-emacs/wanderlust/wanderlust-2.15.9_p20130619.ebuild
+++ b/app-emacs/wanderlust/wanderlust-2.15.9_p20130619.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emacs/wanderlust/wanderlust-2.15.9_p20130619.ebuild,v 1.7 2015/03/02 09:31:28 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/wanderlust/wanderlust-2.15.9_p20130619.ebuild,v 1.8 2015/06/05 14:18:56 ulm Exp $
 
 EAPI=5
 
@@ -43,7 +43,7 @@ src_install() {
 		PIXMAPDIR="${ED}${SITEETC}/wl/icons" \
 		install
 
-	elisp-site-file-install "${FILESDIR}/${SITEFILE}" wl || die
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}" wl
 
 	insinto "${SITEETC}/wl/samples/en"
 	doins samples/en/*