version bumps and clean out old version

(Portage version: 2.1.9.24/cvs/Linux x86_64)

3 files changed, 78 insertions, 2 deletions

diff --git a/app-emulation/kvm-kmod/ChangeLog b/app-emulation/kvm-kmod/ChangeLog
index 8df7835f77ea..36818b427e23 100644
--- a/app-emulation/kvm-kmod/ChangeLog
+++ b/app-emulation/kvm-kmod/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for app-emulation/kvm-kmod
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/kvm-kmod/ChangeLog,v 1.16 2010/09/21 14:49:05 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/kvm-kmod/ChangeLog,v 1.17 2010/11/17 16:08:05 cardoe Exp $
+
+*kvm-kmod-2.6.36 (17 Nov 2010)
+*kvm-kmod-2.6.35.6 (17 Nov 2010)
+
+  17 Nov 2010; Doug Goldstein <cardoe@gentoo.org>
+  -kvm-kmod-2.6.32.16.ebuild, +kvm-kmod-2.6.35.6.ebuild,
+  +kvm-kmod-2.6.36.ebuild:
+  version bumps and clean out old version
 
   21 Sep 2010; Doug Goldstein <cardoe@gentoo.org> kvm-kmod-2.6.32.16.ebuild,
   kvm-kmod-2.6.32.17.ebuild, kvm-kmod-2.6.34.1.ebuild,
diff --git a/app-emulation/kvm-kmod/kvm-kmod-2.6.32.16.ebuild b/app-emulation/kvm-kmod/kvm-kmod-2.6.35.6.ebuild
index b5a36191a471..a375243a3154 100644
--- a/app-emulation/kvm-kmod/kvm-kmod-2.6.32.16.ebuild
+++ b/app-emulation/kvm-kmod/kvm-kmod-2.6.35.6.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/kvm-kmod/kvm-kmod-2.6.32.16.ebuild,v 1.3 2010/09/21 14:49:05 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/kvm-kmod/kvm-kmod-2.6.35.6.ebuild,v 1.1 2010/11/17 16:08:05 cardoe Exp $
 
 EAPI="2"
 
diff --git a/app-emulation/kvm-kmod/kvm-kmod-2.6.36.ebuild b/app-emulation/kvm-kmod/kvm-kmod-2.6.36.ebuild
new file mode 100644
index 000000000000..647da93b9f7c
--- /dev/null
+++ b/app-emulation/kvm-kmod/kvm-kmod-2.6.36.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/kvm-kmod/kvm-kmod-2.6.36.ebuild,v 1.1 2010/11/17 16:08:05 cardoe Exp $
+
+EAPI="2"
+
+inherit eutils linux-mod
+
+SRC_URI="mirror://sourceforge/kvm/${P}.tar.bz2"
+
+DESCRIPTION="Kernel-based Virtual Machine kernel modules"
+HOMEPAGE="http://www.linux-kvm.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE=""
+RESTRICT="test"
+
+RDEPEND=""
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	linux_config_exists || die "Your kernel sources are unconfigured"
+
+	linux-info_pkg_setup
+	if ! linux_chkconfig_present KVM; then
+		eerror "KVM now needs CONFIG_KVM built into your kernel, even"
+		eerror "if you're using the external modules from this package."
+		eerror "Please enable KVM support in your kernel, found at:"
+		eerror
+		eerror "  Virtualization"
+		eerror "    Kernel-based Virtual Machine (KVM) support"
+		eerror
+		die "KVM support not detected!"
+	fi
+	BUILD_TARGETS="all"
+	MODULE_NAMES="kvm(kernel/arch/x86/kvm/:${S}:${S}/x86)"
+	MODULE_NAMES="${MODULE_NAMES} kvm-intel(kernel/arch/x86/kvm/:${S}:${S}/x86)"
+	MODULE_NAMES="${MODULE_NAMES} kvm-amd(kernel/arch/x86/kvm/:${S}:${S}/x86)"
+	linux-mod_pkg_setup
+}
+
+src_configure() {
+	local conf_opts
+
+	conf_opts="--kerneldir=$KV_DIR"
+
+	if has_multilib_profile && [[ "${DEFAULT_ABI}" == "x86" ]] ; then
+		conf_opts="$conf_opts --arch=x86"
+	fi
+
+	./configure ${conf_opts} || die "configure failed"
+}
+
+src_compile() {
+	linux-mod_src_compile
+}
+
+src_install() {
+	linux-mod_src_install
+}
+
+pkg_preinst() {
+	find /lib/modules/${KV_FULL} -name 'kvm*.ko' -type f -delete
+
+	linux-mod_pkg_preinst
+}