Version bump.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

4 files changed, 137 insertions, 6 deletions

diff --git a/app-office/akonadi-server/ChangeLog b/app-office/akonadi-server/ChangeLog
index a87c45019729..0a1ca02ba6ac 100644
--- a/app-office/akonadi-server/ChangeLog
+++ b/app-office/akonadi-server/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-office/akonadi-server
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/ChangeLog,v 1.132 2013/12/22 12:11:02 johu Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/ChangeLog,v 1.133 2014/03/29 19:48:49 johu Exp $
+
+*akonadi-server-1.12.0 (29 Mar 2014)
+
+  29 Mar 2014; Johannes Huber <johu@gentoo.org> +akonadi-server-1.12.0.ebuild,
+  akonadi-server-1.10.3.ebuild, akonadi-server-1.11.0.ebuild:
+  Version bump.
 
   22 Dec 2013; Johannes Huber <johu@gentoo.org> -akonadi-server-1.9.2.ebuild:
   Remove old.
diff --git a/app-office/akonadi-server/akonadi-server-1.10.3.ebuild b/app-office/akonadi-server/akonadi-server-1.10.3.ebuild
index a08b4bfcc479..177a33795eb6 100644
--- a/app-office/akonadi-server/akonadi-server-1.10.3.ebuild
+++ b/app-office/akonadi-server/akonadi-server-1.10.3.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/akonadi-server-1.10.3.ebuild,v 1.6 2013/12/11 20:31:10 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/akonadi-server-1.10.3.ebuild,v 1.7 2014/03/29 19:48:49 johu Exp $
 
 EAPI=5
 
diff --git a/app-office/akonadi-server/akonadi-server-1.11.0.ebuild b/app-office/akonadi-server/akonadi-server-1.11.0.ebuild
index 95e9e3da66c3..1cc832884723 100644
--- a/app-office/akonadi-server/akonadi-server-1.11.0.ebuild
+++ b/app-office/akonadi-server/akonadi-server-1.11.0.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/akonadi-server-1.11.0.ebuild,v 1.1 2013/12/18 18:02:26 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/akonadi-server-1.11.0.ebuild,v 1.2 2014/03/29 19:48:49 johu Exp $
 
 EAPI=5
 
diff --git a/app-office/akonadi-server/akonadi-server-1.12.0.ebuild b/app-office/akonadi-server/akonadi-server-1.12.0.ebuild
new file mode 100644
index 000000000000..696a78258c6b
--- /dev/null
+++ b/app-office/akonadi-server/akonadi-server-1.12.0.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/akonadi-server-1.12.0.ebuild,v 1.1 2014/03/29 19:48:49 johu Exp $
+
+EAPI=5
+
+if [[ $PV = *9999* ]]; then
+	scm_eclass=git-r3
+	EGIT_REPO_URI=( "git://anongit.kde.org/akonadi" )
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="mirror://kde/stable/${PN/-server/}/src/${P/-server/}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${P/-server/}"
+fi
+
+inherit cmake-utils ${scm_eclass}
+
+DESCRIPTION="The server part of Akonadi"
+HOMEPAGE="http://pim.kde.org/akonadi"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="+mysql postgres +qt4 qt5 sqlite test"
+
+REQUIRED_USE="^^ ( qt4 qt5 ) || ( sqlite mysql postgres )"
+
+CDEPEND="
+	dev-libs/boost:=
+	>=dev-libs/soprano-2.6.51
+	x11-misc/shared-mime-info
+	qt4? (
+		>=dev-qt/qtcore-4.8.5:4
+		>=dev-qt/qtdbus-4.8.5:4
+		>=dev-qt/qtgui-4.8.5:4
+		>=dev-qt/qtsql-4.8.5:4[mysql?,postgres?]
+		>=dev-qt/qttest-4.8.5:4
+	)
+	qt5? (
+		>=dev-libs/soprano-2.6.51[-qt4,qt5]
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtsql:5[mysql?,postgres?]
+		dev-qt/qttest:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+	)
+	sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="${CDEPEND}
+	dev-libs/libxslt
+	>=dev-util/automoc-0.9.88
+	test? ( sys-apps/dbus )
+"
+RDEPEND="${CDEPEND}
+	postgres? ( dev-db/postgresql-server )
+"
+
+pkg_setup() {
+	# Set default storage backend in order: MySQL, SQLite PostgreSQL
+	# reverse driver check to keep the order
+	if use postgres; then
+		DRIVER="QPSQL"
+		AVAILABLE+=" ${DRIVER}"
+	fi
+
+	if use sqlite; then
+		DRIVER="QSQLITE3"
+		AVAILABLE+=" ${DRIVER}"
+	fi
+
+	if use mysql; then
+		DRIVER="QMYSQL"
+		AVAILABLE+=" ${DRIVER}"
+	fi
+
+	# Notify about MySQL is recommend by upstream
+	if use sqlite || has_version "<${CATEGORY}/${P}[sqlite]"; then
+		ewarn
+		ewarn "We strongly recommend you change your Akonadi database backend to MySQL in your"
+		ewarn "user configuration. This is the backend recommended by KDE upstream."
+		ewarn "In particular, kde-base/kmail-4.10 does not work properly with the sqlite"
+		ewarn "backend anymore."
+		ewarn "You can select the backend in your ~/.config/akonadi/akonadiserverrc."
+		ewarn "Available drivers are:${AVAILABLE}"
+		ewarn
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_QSQLITE_IN_QT_PREFIX=ON
+		$(cmake-utils_use test AKONADI_BUILD_TESTS)
+		$(cmake-utils_use sqlite AKONADI_BUILD_QSQLITE)
+		$(cmake-utils_use qt5 QT5_BUILD)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	export $(dbus-launch)
+	cmake-utils_src_test
+}
+
+src_install() {
+	# Who knows, maybe it accidentally fixes our permission issues
+	cat <<-EOF > "${T}"/akonadiserverrc
+[%General]
+Driver=${DRIVER}
+EOF
+	insinto /usr/share/config/akonadi
+	doins "${T}"/akonadiserverrc
+
+	cmake-utils_src_install
+}
+
+pkg_postinst() {
+	elog "${DRIVER} has been set as your default akonadi storage backend."
+	elog "You can override it in your ~/.config/akonadi/akonadiserverrc."
+	elog "Available drivers are: ${AVAILABLE}"
+}