Convert to distutils-r1.

(Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

3 files changed, 59 insertions, 31 deletions

diff --git a/app-portage/metagen/ChangeLog b/app-portage/metagen/ChangeLog
index 385c6be4e2f3..5ffc9ca515f4 100644
--- a/app-portage/metagen/ChangeLog
+++ b/app-portage/metagen/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-portage/metagen
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/metagen/ChangeLog,v 1.36 2012/02/07 16:19:50 jer Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-portage/metagen/ChangeLog,v 1.37 2014/01/20 03:46:53 floppym Exp $
+
+*metagen-0.6.2-r1 (20 Jan 2014)
+
+  20 Jan 2014; Mike Gilbert <floppym@gentoo.org> +metagen-0.6.2-r1.ebuild,
+  metagen-9999.ebuild:
+  Convert to distutils-r1.
 
   07 Feb 2012; Jeroen Roovers <jer@gentoo.org> metagen-0.6.2.ebuild:
   Stable for HPPA (bug #399949).
@@ -136,4 +142,3 @@
 
   22 Aug 2004; Rob Cakebread <pythonhead@gentoo.org> +metagen-0.1.ebuild:
   Initial commit
-
diff --git a/app-portage/metagen/metagen-0.6.2-r1.ebuild b/app-portage/metagen/metagen-0.6.2-r1.ebuild
new file mode 100644
index 000000000000..60000c158f54
--- /dev/null
+++ b/app-portage/metagen/metagen-0.6.2-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-portage/metagen/metagen-0.6.2-r1.ebuild,v 1.1 2014/01/20 03:46:53 floppym Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_6,2_7} pypy2_0 )
+
+inherit distutils-r1
+
+DESCRIPTION="metadata.xml generator for ebuilds"
+HOMEPAGE="http://git.overlays.gentoo.org/gitweb/?p=proj/metagen.git;a=summary"
+SRC_URI="http://dev.gentoo.org/~neurogeek/metagen_releases/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~x86"
+
+IUSE=""
+DEPEND=">=dev-python/jaxml-3.01[${PYTHON_USEDEP}]
+	>=sys-apps/portage-2.1.9.42[${PYTHON_USEDEP}]"
+RDEPEND="${DEPEND}"
+
+python_install() {
+	distutils-r1_python_install
+	python_newscript metagen/main.py metagen
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	doman docs/metagen.1
+}
+
+python_test() {
+	"${PYTHON}" -c "from metagen import metagenerator; metagenerator.do_tests()" || die
+}
diff --git a/app-portage/metagen/metagen-9999.ebuild b/app-portage/metagen/metagen-9999.ebuild
index ba3a9cf7b446..e6403e495597 100644
--- a/app-portage/metagen/metagen-9999.ebuild
+++ b/app-portage/metagen/metagen-9999.ebuild
@@ -1,13 +1,11 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/metagen/metagen-9999.ebuild,v 1.4 2011/09/25 14:31:01 neurogeek Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/metagen/metagen-9999.ebuild,v 1.5 2014/01/20 03:46:53 floppym Exp $
 
-EAPI="3"
-PYTHON_DEPEND="2"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="3.*"
+EAPI="5"
+PYTHON_COMPAT=( python{2_6,2_7} pypy2_0 )
 
-inherit distutils git-2
+inherit distutils-r1 git-r3
 
 DESCRIPTION="metadata.xml generator for ebuilds"
 HOMEPAGE="http://git.overlays.gentoo.org/gitweb/?p=proj/metagen.git;a=summary"
@@ -19,30 +17,20 @@ SLOT="0"
 KEYWORDS=""
 
 IUSE=""
-DEPEND=">=dev-python/jaxml-3.01
-		>=sys-apps/portage-2.1.9.42"
+DEPEND=">=dev-python/jaxml-3.01[${PYTHON_USEDEP}]
+	>=sys-apps/portage-2.1.9.42[${PYTHON_USEDEP}]"
 RDEPEND="${DEPEND}"
 
-src_install() {
-	distutils_src_install
-
-	metagen_install() {
-		local METAGEN_MOD="$(python_get_sitedir)/${PN}/main.py"
-		fperms 755 ${METAGEN_MOD}
-		dosym  "${D}"${METAGEN_MOD} "/usr/bin/${PN}-${PYTHON_ABI}"
-	}
-	python_execute_function metagen_install
-
-	python_generate_wrapper_scripts "${ED}usr/bin/${PN}"
+python_install() {
+	distutils-r1_python_install
+	python_newscript metagen/main.py metagen
+}
 
-	doman "docs/metagen.1"
+python_install_all() {
+	distutils-r1_python_install_all
+	doman docs/metagen.1
 }
 
-src_test() {
-	einfo "Starting tests..."
-	testing() {
-		$(PYTHON) -c "from metagen import metagenerator; metagenerator.do_tests()"
-	}
-	python_execute_function testing
-	einfo "Tests completed."
+python_test() {
+	"${PYTHON}" -c "from metagen import metagenerator; metagenerator.do_tests()" || die
 }