Version bump. Switch to EAPI=5 and python-r1 support.

(Portage version: 2.2.0_alpha166/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 73 insertions, 1 deletions

diff --git a/app-text/gnome-doc-utils/ChangeLog b/app-text/gnome-doc-utils/ChangeLog
index 272d342877e1..a5f4c58111ae 100644
--- a/app-text/gnome-doc-utils/ChangeLog
+++ b/app-text/gnome-doc-utils/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/gnome-doc-utils
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/gnome-doc-utils/ChangeLog,v 1.208 2013/03/05 23:03:48 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/gnome-doc-utils/ChangeLog,v 1.209 2013/03/27 21:38:19 eva Exp $
+
+*gnome-doc-utils-0.20.10-r1 (27 Mar 2013)
+
+  27 Mar 2013; Gilles Dartiguelongue <eva@gentoo.org>
+  +gnome-doc-utils-0.20.10-r1.ebuild:
+  Version bump. Switch to EAPI=5 and python-r1 support.
 
   05 Mar 2013; Gilles Dartiguelongue <eva@gentoo.org>
   -gnome-doc-utils-0.20.6.ebuild, -gnome-doc-utils-0.20.9.ebuild:
diff --git a/app-text/gnome-doc-utils/gnome-doc-utils-0.20.10-r1.ebuild b/app-text/gnome-doc-utils/gnome-doc-utils-0.20.10-r1.ebuild
new file mode 100644
index 000000000000..637f19eabd6d
--- /dev/null
+++ b/app-text/gnome-doc-utils/gnome-doc-utils-0.20.10-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/gnome-doc-utils/gnome-doc-utils-0.20.10-r1.ebuild,v 1.1 2013/03/27 21:38:19 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python2_{5,6,7} )
+
+inherit gnome2 multibuild python-r1
+
+DESCRIPTION="A collection of documentation utilities for the Gnome project"
+HOMEPAGE="http://live.gnome.org/GnomeDocUtils"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/libxml2-2.6.12[python,${PYTHON_USEDEP}]
+	>=dev-libs/libxslt-1.1.8
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.4
+	app-text/scrollkeeper-dtd
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/awk
+	virtual/pkgconfig
+"
+# dev-libs/glib needed for eautofoo, bug #255114.
+
+# If there is a need to reintroduce eautomake or eautoreconf, make sure
+# to AT_M4DIR="tools m4", bug #224609 (m4 removes glib build time dep)
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Leave shebang alone
+	sed -e '/s+^#!.*python.*+#/d' \
+		-i xml2po/xml2po/Makefile.{am,in} || die
+
+	python_prepare() {
+		mkdir -p "${BUILD_DIR}"
+	}
+	python_foreach_impl python_prepare
+}
+
+src_configure() {
+	ECONF_SOURCE="${S}" python_foreach_impl run_in_build_dir gnome2_src_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	dodoc AUTHORS ChangeLog NEWS README
+	python_foreach_impl run_in_build_dir gnome2_src_install
+	python_replicate_script "${ED}"/usr/bin/xml2po
+}