Version bump.

(Portage version: 2.1.10.44/cvs/Linux x86_64)

2 files changed, 62 insertions, 1 deletions

diff --git a/dev-java/commons-daemon/ChangeLog b/dev-java/commons-daemon/ChangeLog
index 3fe5e6982ca8..b260e7ffc21f 100644
--- a/dev-java/commons-daemon/ChangeLog
+++ b/dev-java/commons-daemon/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-java/commons-daemon
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/commons-daemon/ChangeLog,v 1.47 2012/01/28 19:35:41 sera Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/commons-daemon/ChangeLog,v 1.48 2012/01/28 19:46:10 sera Exp $
+
+*commons-daemon-1.0.8 (28 Jan 2012)
+
+  28 Jan 2012; Ralph Sennhauser <sera@gentoo.org> +commons-daemon-1.0.8.ebuild:
+  Version bump.
 
   28 Jan 2012; Ralph Sennhauser <sera@gentoo.org> commons-daemon-1.0.7.ebuild:
   Add missing dep on sys-libs/libcap. Thanks to ago@gentoo.org for pointing it
diff --git a/dev-java/commons-daemon/commons-daemon-1.0.8.ebuild b/dev-java/commons-daemon/commons-daemon-1.0.8.ebuild
new file mode 100644
index 000000000000..228209dc7115
--- /dev/null
+++ b/dev-java/commons-daemon/commons-daemon-1.0.8.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/commons-daemon/commons-daemon-1.0.8.ebuild,v 1.1 2012/01/28 19:46:10 sera Exp $
+
+EAPI="4"
+
+WANT_AUTOCONF=2.5
+JAVA_PKG_IUSE="doc examples source"
+
+inherit eutils autotools java-pkg-2 java-ant-2
+
+DESCRIPTION="Tools to allow Java programs to run as UNIX daemons"
+SRC_URI="mirror://apache/commons/daemon/source/${P}-src.tar.gz"
+HOMEPAGE="http://commons.apache.org/daemon/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="kernel_linux"
+
+COMMON_DEP="
+	kernel_linux? ( sys-libs/libcap )"
+DEPEND="${COMMON_DEP}
+	>=virtual/jdk-1.4"
+RDEPEND="${COMMON_DEP}
+	>=virtual/jre-1.4"
+
+S="${WORKDIR}/${P}-src"
+
+java_prepare() {
+	cd "${S}/src/native/unix" || die
+	sed -i "s/powerpc/powerpc|powerpc64/g" support/apsupport.m4 || die
+	eautoconf
+}
+
+src_configure() {
+	java-ant-2_src_configure
+	cd "${S}/src/native/unix" || die
+	default
+}
+
+src_compile() {
+	java-pkg-2_src_compile
+	cd "${S}/src/native/unix" || die
+	default
+}
+
+src_install() {
+	dobin src/native/unix/jsvc
+	java-pkg_newjar dist/*.jar
+
+	dodoc README RELEASE-NOTES.txt *.html src/native/unix/CHANGES.txt
+	use doc && java-pkg_dohtml -r dist/docs/*
+	use examples && java-pkg_doexamples src/samples
+	use source && java-pkg_dosrc src/java/* src/native/unix/native
+}