Version bump. Fixes bug #218805.

(Portage version: 2.1.5_rc3)

2 files changed, 77 insertions, 1 deletions

diff --git a/dev-java/gjdoc/ChangeLog b/dev-java/gjdoc/ChangeLog
index 762aee2089dc..02f6c0ca222c 100644
--- a/dev-java/gjdoc/ChangeLog
+++ b/dev-java/gjdoc/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-java/gjdoc
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/gjdoc/ChangeLog,v 1.31 2008/04/22 13:52:03 betelgeuse Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/gjdoc/ChangeLog,v 1.32 2008/04/22 13:57:59 betelgeuse Exp $
+
+*gjdoc-0.7.9 (22 Apr 2008)
+
+  22 Apr 2008; Petteri Räty <betelgeuse@gentoo.org> +gjdoc-0.7.9.ebuild:
+  Version bump. Fixes bug #218805.
 
   22 Apr 2008; Petteri Räty <betelgeuse@gentoo.org> -gjdoc-0.7.7-r1.ebuild:
   Remove old version.
diff --git a/dev-java/gjdoc/gjdoc-0.7.9.ebuild b/dev-java/gjdoc/gjdoc-0.7.9.ebuild
new file mode 100644
index 000000000000..09466f0b990d
--- /dev/null
+++ b/dev-java/gjdoc/gjdoc-0.7.9.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/gjdoc/gjdoc-0.7.9.ebuild,v 1.1 2008/04/22 13:57:59 betelgeuse Exp $
+
+JAVA_PKG_IUSE="source"
+
+inherit eutils autotools java-pkg-2
+
+DESCRIPTION="A javadoc compatible Java source documentation generator."
+HOMEPAGE="http://www.gnu.org/software/cp-tools/"
+SRC_URI="mirror://gnu/classpath/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+
+# Possible USE flags.
+#
+# native: to --enable-native
+# doc:    to generate javadoc
+# debug:  There is a debug doclet installed by default but maybe could
+#         have a wrapper that uses it.
+#
+IUSE="xmldoclet"
+
+# Refused to emerge with sun-jdk-1.3* complaining about wanting a bigger stack size
+DEPEND=">=dev-java/antlr-2.7.1
+		>=virtual/jdk-1.4"
+
+RDEPEND=">=virtual/jre-1.4
+		>=dev-java/antlr-2.7.1"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${PN}-0.7.7-gcp.patch"
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_compile() {
+	# I think that configure will do --enable-native if it finds gcj
+	# so we'll disable it explicitly
+	local myc="--with-antlr-jar=$(java-pkg_getjar antlr antlr.jar) --disable-native"
+	myc="${myc} --disable-dependency-tracking"
+
+	# Does not work with gcc 3.* and without these it tries to use gij
+	# see bug #116804 for details
+
+	# TODO ideally, would respect JAVACFLAGS
+	JAVA="java" JAVAC="javac $(java-pkg_javac-args)" \
+		econf ${myc} \
+		$(use_enable xmldoclet) || die "econf failed"
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	local jars="com-sun-tools-doclets-Taglet gnu-classpath-tools-gjdoc com-sun-javadoc"
+	for jar in ${jars}; do
+		java-pkg_newjar ${jar}-${PV}.jar ${jar}.jar
+	done
+
+	dobin "${FILESDIR}"/gjdoc
+	dodoc AUTHORS ChangeLog NEWS README
+
+	cd "${S}"/docs
+	emake DESTDIR="${D}" install || die "Failed to install documentation"
+
+	use source && java-pkg_dosrc "${S}/src"/{com,gnu}
+}