Version bump.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 83 insertions, 1 deletions

diff --git a/dev-libs/libpwquality/ChangeLog b/dev-libs/libpwquality/ChangeLog
index 98e47738d7dd..6fbe74c65bc9 100644
--- a/dev-libs/libpwquality/ChangeLog
+++ b/dev-libs/libpwquality/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libpwquality
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpwquality/ChangeLog,v 1.11 2013/03/05 23:17:29 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpwquality/ChangeLog,v 1.12 2013/11/14 22:33:35 eva Exp $
+
+*libpwquality-1.2.3 (15 Nov 2013)
+
+  15 Nov 2013; Gilles Dartiguelongue <eva@gentoo.org>
+  +libpwquality-1.2.3.ebuild:
+  Version bump.
 
   05 Mar 2013; Gilles Dartiguelongue <eva@gentoo.org>
   -libpwquality-1.2.0-r1.ebuild:
diff --git a/dev-libs/libpwquality/libpwquality-1.2.3.ebuild b/dev-libs/libpwquality/libpwquality-1.2.3.ebuild
new file mode 100644
index 000000000000..09367539d3e9
--- /dev/null
+++ b/dev-libs/libpwquality/libpwquality-1.2.3.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpwquality/libpwquality-1.2.3.ebuild,v 1.1 2013/11/14 22:33:35 eva Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils multilib pam python-r1 toolchain-funcs
+
+DESCRIPTION="Library for password quality checking and generating random passwords"
+HOMEPAGE="https://fedorahosted.org/libpwquality/"
+SRC_URI="https://fedorahosted.org/releases/l/i/${PN}/${P}.tar.bz2"
+
+LICENSE="|| ( BSD GPL-2 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="pam python static-libs"
+
+RDEPEND="
+	>=sys-libs/cracklib-2.8:=
+	pam? ( virtual/pam )
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}
+	>=sys-devel/gettext-0.15
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# ensure pkgconfig files go in /usr
+	sed -e 's:\(pkgconfigdir *=\).*:\1 '${EPREFIX}/usr/$(get_libdir)'/pkgconfig:' \
+		-i src/Makefile.{am,in} || die "sed failed"
+	use python && python_copy_sources
+}
+
+src_configure() {
+	# Install library in /lib for pam
+	configuring() {
+		local sitedir
+		econf \
+			--libdir="${EPREFIX}/$(get_libdir)" \
+			$(use_enable pam) \
+			--with-securedir="${EPREFIX}/$(getpam_mod_dir)" \
+			$(use_enable python python-bindings) \
+			$(usex python "--with-pythonsitedir=$(use python && python_get_sitedir)" "") \
+			$(use_enable static-libs static)
+	}
+	if_use_python_python_foreach_impl configuring
+}
+
+src_compile() {
+	if_use_python_python_foreach_impl default
+}
+
+src_test() {
+	if_use_python_python_foreach_impl default
+}
+
+src_install() {
+	if_use_python_python_foreach_impl default
+	if use static-libs; then
+		# Do not install static libs in /lib
+		mkdir -p "${ED}usr/$(get_libdir)"
+		mv "${ED}$(get_libdir)/libpwquality.a" "${ED}/usr/$(get_libdir)/" || die
+		gen_usr_ldscript libpwquality.so
+	fi
+	prune_libtool_files --modules
+}
+
+if_use_python_python_foreach_impl() {
+	if use python; then
+		python_foreach_impl run_in_build_dir "$@"
+	else
+		"$@"
+	fi
+}