Version bump

(Portage version: 2.2_rc67/cvs/Linux x86_64)

2 files changed, 75 insertions, 2 deletions

diff --git a/dev-python/chaco/ChangeLog b/dev-python/chaco/ChangeLog
index 329c553c37cc..896f6fd59797 100644
--- a/dev-python/chaco/ChangeLog
+++ b/dev-python/chaco/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/chaco
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/chaco/ChangeLog,v 1.4 2009/09/05 23:23:12 arfrever Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/chaco/ChangeLog,v 1.5 2010/03/23 05:19:01 bicatali Exp $
+
+*chaco-3.3.0 (21 Mar 2010)
+
+  21 Mar 2010; Sébastien Fabbro <bicatali@gentoo.org> +chaco-3.3.0.ebuild:
+  Version bump
 
 *chaco-3.2.0 (05 Sep 2009)
 
diff --git a/dev-python/chaco/chaco-3.3.0.ebuild b/dev-python/chaco/chaco-3.3.0.ebuild
new file mode 100644
index 000000000000..a996b5989a42
--- /dev/null
+++ b/dev-python/chaco/chaco-3.3.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/chaco/chaco-3.3.0.ebuild,v 1.1 2010/03/23 05:19:01 bicatali Exp $
+
+EAPI="2"
+PYTHON_DEPEND="2"
+SUPPORT_PYTHON_ABIS="1"
+
+inherit distutils
+
+MY_PN="Chaco"
+MY_P="${MY_PN}-${PV}"
+DESCRIPTION="Interactive plotting toolkit"
+HOMEPAGE="http://code.enthought.com/projects/chaco"
+SRC_URI="http://www.enthought.com/repo/ETS/${MY_P}.tar.gz"
+
+IUSE="doc examples test"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+LICENSE="BSD"
+
+RDEPEND=">=dev-python/enable-3.3.0"
+DEPEND="dev-python/setuptools
+	dev-python/numpy
+	doc? ( dev-python/setupdocs )
+	test? ( >=dev-python/nose-0.10.3
+			dev-python/coverage
+			>=dev-python/enable-3.3.0
+			>=dev-python/enthoughtbase-3.0.4 )"
+RESTRICT_PYTHON_ABIS="3.*"
+
+S="${WORKDIR}/${MY_P}"
+
+PYTHON_MODNAME="enthought"
+
+src_prepare() {
+	sed -i \
+		-e "s/self.run_command('build_docs')/pass/" \
+		-e "s/setupdocs>=1.0//" \
+		setup.py || die
+}
+
+src_compile() {
+	distutils_src_compile
+	if use doc; then
+		"$(PYTHON -f)" setup.py build_docs --formats=html,pdf || die "Generation of documentation failed"
+	fi
+}
+
+src_test() {
+	testing() {
+		PYTHONPATH="$(ls -d build-${PYTHON_ABI}/lib*)" "$(PYTHON)" setup.py build -b "build-${PYTHON_ABI}" test
+	}
+	python_execute_function testing
+}
+
+src_install() {
+	find "${S}" -name \*LICENSE.txt -delete
+	distutils_src_install
+	dodoc docs/*.txt
+	insinto /usr/share/doc/${PF}
+	if use doc; then
+		doins -r build/docs/html build/docs/latex/*.pdf || die
+	fi
+	if use examples; then
+		doins -r examples || die
+	fi
+}