Version Bump, fixes #476762 (python3 support) and #538038 (Uneeded dependency on db support in django)

(Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

3 files changed, 81 insertions, 11 deletions

diff --git a/dev-python/django-extensions/ChangeLog b/dev-python/django-extensions/ChangeLog
index e6d3644e8a11..85a2f1c9d3d5 100644
--- a/dev-python/django-extensions/ChangeLog
+++ b/dev-python/django-extensions/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/django-extensions
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/django-extensions/ChangeLog,v 1.11 2014/11/28 10:14:07 pacho Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/django-extensions/ChangeLog,v 1.12 2015/02/27 16:33:07 jlec Exp $
+
+*django-extensions-1.5.0 (27 Feb 2015)
+
+  27 Feb 2015; Justin Lecher <jlec@gentoo.org> +django-extensions-1.5.0.ebuild,
+  metadata.xml:
+  Version Bump, fixes #476762 (python3 support) and #538038 (Uneeded dependency
+  on db support in django)
 
   28 Nov 2014; Pacho Ramos <pacho@gentoo.org> django-extensions-1.4.0.ebuild:
   Support python 3.4
diff --git a/dev-python/django-extensions/django-extensions-1.5.0.ebuild b/dev-python/django-extensions/django-extensions-1.5.0.ebuild
new file mode 100644
index 000000000000..8a3aad8618ab
--- /dev/null
+++ b/dev-python/django-extensions/django-extensions-1.5.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/django-extensions/django-extensions-1.5.0.ebuild,v 1.1 2015/02/27 16:33:07 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} )
+
+inherit distutils-r1 eutils
+
+GIT_HASH_TAG="d39ecfd"
+
+DESCRIPTION="Django Command Extensions"
+HOMEPAGE="http://github.com/django-extensions/django-extensions http://django-extensions.readthedocs.org"
+SRC_URI="http://github.com/django-extensions/django-extensions/tarball/${PV}/${P}.tgz"
+
+LICENSE="BSD || ( MIT GPL-2 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+# Req'd for tests
+DISTUTILS_IN_SOURCE_BUILD=1
+
+RDEPEND="
+	>=dev-python/django-1.5.4[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		>=dev-python/django-1.5.4[${PYTHON_USEDEP}]
+		dev-python/shortuuid[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/tox[${PYTHON_USEDEP}]
+		)"
+
+S="${WORKDIR}/${PN}-${PN}-${GIT_HASH_TAG}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	"${PYTHON}" run_tests.py || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	echo ""
+	elog "Further enhancements can be achieved by installing the following packages:"
+	echo ""
+	optfeature "Use ipython in shell_plus" dev-python/ipython
+	optfeature "Use ptpython in shell_plus" dev-python/ptpython
+	optfeature "Renders a graphical overview of your project or specified apps." dev-python/pygraphviz
+	optfeature "sync your MEDIA_ROOT and STATIC_ROOT folders to S3" dev-python/boto
+	optfeature "RunServerPlus-typical runserver with Werkzeug debugger baked in" dev-python/werkzeug dev-python/watchdog
+}
diff --git a/dev-python/django-extensions/metadata.xml b/dev-python/django-extensions/metadata.xml
index 9378169b8e74..f5bd5b72ff20 100644
--- a/dev-python/django-extensions/metadata.xml
+++ b/dev-python/django-extensions/metadata.xml
@@ -1,13 +1,13 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-	<maintainer>
-		<email>dev-zero@gentoo.org</email>
-		<name>Tiziano Müller</name>
-	</maintainer>
-	<use>
-		<flag name="graphviz">Create a diagram of your database entity relationships using <pkg>dev-python/pygraphviz</pkg>.</flag>
-		<flag name="s3">Upload your media files to S3.</flag>
-		<flag name="vcard">Export your users email addresses to the vcard format.</flag>
-	</use>
+  <maintainer>
+    <email>dev-zero@gentoo.org</email>
+    <name>Tiziano Müller</name>
+  </maintainer>
+  <use>
+    <flag name="graphviz">Create a diagram of your database entity relationships using <pkg>dev-python/pygraphviz</pkg>.</flag>
+    <flag name="s3">Upload your media files to S3.</flag>
+    <flag name="vcard">Export your users email addresses to the vcard format.</flag>
+  </use>
 </pkgmetadata>