bump; drop py2.6 add py3.4 support

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 55 insertions, 1 deletions

diff --git a/dev-python/llvmpy/ChangeLog b/dev-python/llvmpy/ChangeLog
index 18085f659014..494bd1969e5a 100644
--- a/dev-python/llvmpy/ChangeLog
+++ b/dev-python/llvmpy/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/llvmpy
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/llvmpy/ChangeLog,v 1.6 2014/05/03 07:24:32 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/llvmpy/ChangeLog,v 1.7 2014/06/16 08:58:07 idella4 Exp $
+
+*llvmpy-0.12.6 (16 Jun 2014)
+
+  16 Jun 2014; Ian Delaney <idella4@gentoo.org> +llvmpy-0.12.6.ebuild:
+  bump; drop py2.6 add py3.4 support
 
 *llvmpy-0.12.5 (03 May 2014)
 
diff --git a/dev-python/llvmpy/llvmpy-0.12.6.ebuild b/dev-python/llvmpy/llvmpy-0.12.6.ebuild
new file mode 100644
index 000000000000..305a5a078f14
--- /dev/null
+++ b/dev-python/llvmpy/llvmpy-0.12.6.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/llvmpy/llvmpy-0.12.6.ebuild,v 1.1 2014/06/16 08:58:07 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python wrapper around the llvm C++ library"
+HOMEPAGE="http://llvmpy.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc"
+
+# fails with llvm-3.4
+RDEPEND="=sys-devel/llvm-3.3*:=[multitarget]"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+# Usual; req'd for tests
+DISTUTILS_IN_SOURCE_BUILD=1
+
+PATCHES=( "${FILESDIR}"/${PN}-0.12.2-return-type.patch )
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS="${CFLAGS} -fno-strict-aliasing"
+		export CFLAGS
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib* || die
+	${PYTHON} -c "import llvm; llvm.test()" || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html )
+	distutils-r1_python_install_all
+}