add setuptools dependence

Bug #531874 indicated there was a missing build dependence on setuptools.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 11A8217C!)

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-python/pyhamcrest/pyhamcrest-1.8.1-r1.ebuild b/dev-python/pyhamcrest/pyhamcrest-1.8.1-r1.ebuild
new file mode 100644
index 000000000000..573dd3060afb
--- /dev/null
+++ b/dev-python/pyhamcrest/pyhamcrest-1.8.1-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyhamcrest/pyhamcrest-1.8.1-r1.ebuild,v 1.1 2015/01/18 03:25:29 alunduil Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python3_3 python3_4 pypy )
+
+inherit distutils-r1
+
+MY_PN="PyHamcrest"
+
+DESCRIPTION="Hamcrest framework for matcher objects"
+HOMEPAGE="https://github.com/hamcrest/PyHamcrest"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc examples numpy test"
+
+CDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'numpy? ( dev-python/numpy[${PYTHON_USEDEP}] )' 'python*')
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${CDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}"
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	py.test -v || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+
+	distutils-r1_python_install_all
+}