Convert to distutils-r1.

(Portage version: 2.2.1_p7/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 59 insertions, 3 deletions

diff --git a/dev-python/utidylib/ChangeLog b/dev-python/utidylib/ChangeLog
index 19f211f13cb6..16c8e9fb5986 100644
--- a/dev-python/utidylib/ChangeLog
+++ b/dev-python/utidylib/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/utidylib
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/utidylib/ChangeLog,v 1.14 2012/03/01 23:40:55 ranger Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/utidylib/ChangeLog,v 1.15 2013/08/31 16:41:51 mgorny Exp $
+
+*utidylib-0.2-r2 (31 Aug 2013)
+
+  31 Aug 2013; Michał Górny <mgorny@gentoo.org> +utidylib-0.2-r2.ebuild:
+  Convert to distutils-r1.
 
   01 Mar 2012; Brent Baude <ranger@gentoo.org> utidylib-0.2-r1.ebuild:
   Marking utidylib-0.2-r1 ppc for bug 386673
@@ -55,4 +60,3 @@
   +utidylib-0.2.ebuild:
   New ebuild, based on a contribution from Andy Dustman <farcepest@gmail.com>
   (bug #79856).
-
diff --git a/dev-python/utidylib/utidylib-0.2-r2.ebuild b/dev-python/utidylib/utidylib-0.2-r2.ebuild
new file mode 100644
index 000000000000..e05ccfacb918
--- /dev/null
+++ b/dev-python/utidylib/utidylib-0.2-r2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/utidylib/utidylib-0.2-r2.ebuild,v 1.1 2013/08/31 16:41:51 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1
+
+MY_P="uTidylib-${PV}"
+
+DESCRIPTION="TidyLib Python wrapper"
+HOMEPAGE="http://utidylib.berlios.de/"
+SRC_URI="mirror://berlios/${PN}/${MY_P}.zip"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="doc test"
+
+RDEPEND="app-text/htmltidy"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	doc? ( dev-python/epydoc[${PYTHON_USEDEP}] )
+	test? ( dev-python/twisted-core[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}/${P}-no-docs-in-site-packages.patch"
+		"${FILESDIR}/${P}-fix_tests.patch"
+	)
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		"${PYTHON}" gendoc.py || die
+	fi
+}
+
+python_test() {
+	trial tidy || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( apidoc/. )
+	distutils-r1_python_install_all
+}